/ScriptServ

On ^*:JOIN:*: { 
  if ($nick == $me) { 
    window -ah +dL $+(@m.notice.,$chan,$cid) 0 0 $calc($window($chan).w - $iif($readini($mircdirmirc.ini,nicklist,$chan),$calc($gettok($readini($mircdirmirc.ini,nicklist,$chan),2,44) + 10),105)) $round($calc(($window($chan).h / 100) * 30),0) 
    dll $scriptdirdlls\WindowFX.dll SetPadding $chan > $round($calc(($window($chan).h / 100) * 30),0) text
    dll $scriptdirdlls\WindowFX.dll SetChild $chan > $+(@m.notice.,$chan,$cid)
    aline -cp $color(join) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) Now talking in $chan
    set -u5 $+(%,$chan,$cid,wait) 1
  }
  else { 
    aline -cp $color(join) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $nick has joined $chan

  }
  haltdef
}
On ^*:Part:*: { aline -cp $color(part) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $nick has left $chan ( $1- ) | haltdef }
On ^*:NOTICE:*:#: {  aline -cp $color(notice) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $+(-,$nick,:,$chan,-) $1- | haltdef }
On ^*:NOTICE:*:?: {
  var %x = 1 
  while (%x <= $comchan($nick,0)) {
    aline -cp $color(notice) $+(@m.notice.,$comchan($nick,%x),$cid) $timestamp $chr(9) $+(-,$nick,-) $1-
    inc %x
  }
  if ($comchan($nick,0) == 0) { echo $color(notice) -s $timestamp $+(-,$nick,-) $1- }
  haltdef
}
on ^*:NICK: { 
  var %x = 1 
  while (%x <= $comchan($newnick,0)) {
    aline -cp $color(nick) $+(@m.notice.,$comchan($newnick,%x),$cid) $timestamp $chr(9) $nick is now known as $newnick
    inc %x
  }
  haltdef
}
On ^*:QUIT: { 
  var %x = 1 
  while (%x <= $comchan($nick,0)) {
    aline -cp $color(quit) $+(@m.notice.,$comchan($nick,%x),$cid) $timestamp $chr(9) $nick Has quit irc ( $1- )
    inc %x
  }
  haltdef
}
on ^*:RAWMODE:#: { aline -cp $color(mode) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $nick sets mode $1- | haltdef } 
on ^*:INVITE:#: { 
  var %x = 1 
  while (%x <= $chan(0)) {
    aline -cp $color(invite) $+(@m.notice.,$chan(%x)) $timestamp $chr(9) $nick invites you to join $chan
    inc %x
  }
  haltdef
}
on ^*:KICK:#: { aline -cp $color(kick) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $knick was kicked by $nick ( $1- ) | haltdef }
raw *:*: { 
  if ($numeric == 305) { showallchan normal You are no longer marked as being away | halt }
  if ($numeric == 306) { showallchan normal You have been marked as being away | halt }
  if ($numeric == 328) { aline -cp $color(join) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $1- | halt }
  if ($numeric == 332) { aline -cp $color(join) $+(@m.notice.,$2,$cid) $timestamp $chr(9) Topic is $+(',$3-,') | halt }
  if ($numeric == 333) { aline -cp $color(join) $+(@m.notice.,$2,$cid) $timestamp $chr(9) Set by $3 on $asctime($4) | halt }
  if ($numeric == 405) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 471) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 473) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 474) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 475) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 477) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 485) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 403) { showallchan normal Cannot kick: $2- | halt }
  if ($numeric == 441) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
  if ($numeric == 482) { aline -cp $color(normal) $+(@m.notice.,$2,$cid) $timestamp $chr(9) $3- | halt }
}
on ^*:TOPIC:#: { aline -cp $color(topic) $+(@m.notice.,$chan,$cid) $timestamp $chr(9) $nick changes topic to $+(',$1-,') | haltdef }
On *:ACTIVE:#: { 
  if (@m.notice.* !iswm $lactive) && (!$($+(%,$chan,$cid,wait),2))  {
    /scid $activecid
    window -ah +dL $+(@m.notice.,$chan,$cid) 0 0 $calc($window($chan).w - $iif($readini($mircdirmirc.ini,nicklist,$chan),$calc($gettok($readini($mircdirmirc.ini,nicklist,$chan),2,44) + 10),105)) $round($calc(($window($chan).h / 100) * 30),0) 
    filter -wwcpz $+(@m.notice.,$chan,$cid) $+(@m.notice.,$chan,$cid) * 
    dll $scriptdirdlls\WindowFX.dll SetPadding $chan > $round($calc(($window($chan).h / 100) * 30),0) text
  }
}
alias hop { .hop }
alias showallchan { 
  var %x = 1 
  while (%x <= $chan(0)) {
    aline -cp $color($1) $+(@m.notice.,$chan(%x)) $timestamp $chr(9) $2-
    inc %x
  }
}
ON *:START: { .timerresize 0 1 resize }
ON *:Load: { 
  echo -a Ty for downloading Channel Splitter. (This is a one time only message)
  echo -a To ensure correct functioning of the script advised is to close all channels before joining a new one since you loaded this addon.
  echo -a If your annoyed that the resizing can take up too 1 second, change the timer in to a high resolution timer running every 100 ms.
  echo -a Any suggestions can be posted on the website you got this from. Now all you need to do is join channels!
}


alias -l resize { 
  /scid $activecid
  if ((%w.w != $window($active).w) || (%w.h != $window($active).h)) { 
    if (#* iswm $active) && (!$($+(%,$chan,$cid,wait),2))  {
      dll $scriptdirdlls\WindowFX.dll SetPadding $active > $round($calc(($window($active).h / 100) * 30),0) text
      window -ah +dL $+(@m.notice.,$active,$cid) 0 0 $calc($window($active).w - $iif($readini($mircdirmirc.ini,nicklist,$active),$calc($gettok($readini($mircdirmirc.ini,nicklist,$active),2,44) + 10),105)) $round($calc(($window($active).h / 100) * 30),0) 
      filter -wwcpz $+(@m.notice.,$active,$cid) $+(@m.notice.,$active,$cid) * 
      set %w.w $window($active).w 
      set %w.h $window($active).h
    }
  }
}