/ScriptServ

;;
;;; mIRC-Greets Manager v1.0
;;;; Created By: Ken^neth
;;;;; Do not Rip without Permission 
;;;;;;
//Initialization
on *:LOAD:{
  write gformat.txt <c>10,1( <nick> ) <c> <c>10,1( <channel> ) <c> <c>10,1( <greeting> ) <c>
  write gpopup.txt $ $+ null(greets\add.ico) Add Nick:add.nick
  write gpopup.txt $ $+ null(greets\del.ico) Del Nick:del.nick
  write gpopup.txt $ $+ null(greets\edit.ico) Edit Nick:edit.nick
  write gpopup.txt -
  write gpopup.txt $ $+ null(greets\options.ico) Options:gp
  if ($exist($mircdirmdx\view.mdx) == $false) { echo View.mdx Not Found. Errors may occur. }
  if ($exist($mircdirmdx\dialog.mdx) == $false) { echo dialog.mdx Not Found. Errors may occur. }
  if ($exist($mircdirmdx\mdx.dll) == $false) { echo mdx.dll Not Found. Errors may occur. }
  if ($exist($mircdirmdx\popread.dll) == $false) { echo popread.dll Not Found. Errors may occur. }
  greets
  echo -a Thank you for downloading mIRC-Greets.
  echo -a Right-click in the dialog to access options.
  echo -a Read greadme.txt for more infomation.
}
menu channel,menubar {
  mIRC-Greets
  .dialog:/greets
  .options:/gp
  .uninstall:/gdel
}

//Dialog Tables
dialog greets {
  title "mIRC-Greets"
  size -1 -1 232 113
  option dbu
  list 1, 0 0 232 113, size extsel
  menu "File", 2
  item "Exit", 3, 2, ok
}
dialog goptions {
  title "Options"
  size -1 -1 208 89
  option dbu
  list 1, 3 10 49 61, size
  text "Filter MSGs on:", 2, 4 2 37 8
  button "Add", 3, 3 73 23 12
  button "Delete", 4, 28 73 23 12
  text "Design:", 6, 60 2 25 8
  button "Apply", 10, 160 53 46 12
  button "Ok", 11, 160 67 46 12,ok
  button "preview window", 12, 60 11 146 21, default
  edit "", 7, 60 34 147 10, autohs
  box "Usage", 8, 62 46 94 38
  text "<nick> - Joined Nick                         <channel> - Joined Channel   <greeting> - Nick's Greeting  <b><c><u> - Bold/Colour/Underline", 9, 65 54 88 27
}
//Events
on *:dialog:greets:init:0:{
  mdx SetMircVersion $version
  mdx MarkDialog $dname 
  mdx SetDialog style title sysmenu
  mdx SetControlMDX $dname 1 ListView report sortascending oneclick showsel single rowselect grid > $mircdirmdx $+ \Views.mdx
  did -i $dname 1 1 headerdims 100:1 360:2
  did -i $dname 1 1 headertext NickName $+ $chr(9) $+ Greeting
  update.list
}
on *:dialog:goptions:init:0:{
  mdx SetMircVersion $version
  mdx MarkDialog $dname 
  mdx SetDialog style title sysmenu
  window -ah @gp
  aline @gp 2,15m4,15IR8,15C1,15-Greets Preview Window
  mdx SetControlMDX $dname 12 Window > $mircdirmdx $+ \dialog.mdx
  did -a $dname 12 grab $window(@gp).hwnd @gp
  rline @gp 1 $gview
  update.chan
  did -a $dname 7 $read(gformat.txt,1)
}

on *:dialog:greets:sclick:1:{
  tokenize 32 $did($did,1)
  if ($1 == rclick) { 
    var %q = $dll($mircdirmdx $+ \popread.dll,popread,gpopup.txt?1?20? $+ $mouse.dx $+ ? $+ $mouse.dy)
  }
}
on *:dialog:greets:sclick:4:{
  gp
}
on *:dialog:goptions:sclick:10:{
  remove gformat.txt
  write gformat.txt $did(goptions,7).text
  rline @gp 1 $gview
}
on *:dialog:goptions:sclick:3:{
  var %add.chan $?="Filter Msgs From Channel:"
  if ($check.chan(%add.chan) == $false) && (%add.chan != $null) {
    writeini greets.ini chans $calc(($ini(greets.ini,chans,0))+1) %add.chan
    update.chan
  }
  else { var %z $input(Channel Already Exist or is Invaild,ow,Error) | halt }
}
on *:dialog:goptions:sclick:4:{
  var %q = 1
  while (%q <= $ini(greets.ini,chans,0)) {
    if ($readini(greets.ini,chans,$ini(greets.ini,chans,%q)) == $did(goptions,1).seltext) {
      remini greets.ini chans $ini(greets.ini,chans,%q)
    }
    inc %q
  }
  update.chan
}
on *:dialog:goptions:sclick:11:{
  remove gformat.txt
  write gformat.txt $did(goptions,7).text
}
on *:dialog:greets:dclick:1:{
  tokenize 32 $did($did,1)
  if ($1 == oneclick) { 
    var %q = $dll($mircdirmdx $+ \popread.dll,popread,gpopup.txt?1?20? $+ $mouse.dx $+ ? $+ $mouse.dy)
  }
}
on *:join:#:{
  if ($check.chan($chan) == $true) { halt }
  if ($check.list($nick) == $true) {
    msg $chan $gformat
  }
}
//Aliases
alias gdel { 
  .remove gformat.txt
  .remove gpopup.txt
  .remove greets.ini
  echo mIRC-Greets Uninstalled.
  .unload -rs $script

}
alias mdx { return $dll($mircdirmdx\mdx.dll,$1,$2-) }
alias dmdx { return $dll($mircdirmdx\dialog.mdx,$1,$2-) }
alias greets { if (!$dialog(greets)) dialog -m greets greets }
alias gp { if (!$dialog(goptions)) { dialog -m goptions goptions } }
alias update.list {
  did -r greets 1
  var %q = 1
  while (%q <= $ini(greets.ini,greets,0)) {
    did -a greets 1 $ini(greets.ini,greets,%q) $+ $chr(9) $+ $readini(greets.ini,greets,$ini(greets.ini,greets,%q))
    inc %q
  }
}
alias update.chan {
  did -r goptions 1
  var %q = 1
  while (%q <= $ini(greets.ini,chans,0)) {
    did -a goptions 1 $readini(greets.ini,chans,%q)
    inc %q
  }
}
alias check.list {
  var %q = 1
  while (%q <= $ini(greets.ini,greets,0)) {
    if ($ini(greets.ini,greets,%q) == $1) { return $true }
    inc %q
  }
  return $false
}
alias add.nick {
  var %add.nick $?="Input Nick"
  if ($check.list(%add.nick) == $false) && (%add.nick != $null) {
    writeini greets.ini greets %add.nick $?="Input Greetings"
    update.list
  }
  else { var %z $input(Nick Already Exist or is Invaild,ow,Error) | halt }
}
alias edit.nick {
  if ($calc(($did(greets,1).sel)-1) < 1) || ($did(greets,1).sel == $null) { halt }
  writeini greets.ini greets $ini(greets.ini,greets,$calc(($did(greets,1).sel)-1)) $input(Change greet message to?,eo,Edit Greeting,$readini(greets.ini,greets,$ini(greets.ini,greets,$calc(($did(greets,1).sel)-1))))
  update.list
}
alias del.nick {
  if ($calc(($did(greets,1).sel)-1) < 1) || ($did(greets,1).sel == $null) { halt }
  remini greets.ini greets $ini(greets.ini,greets,$calc(($did(greets,1).sel)-1))
  update.list
}
alias check.chan {
  var %q = 1
  while (%q <= $ini(greets.ini,chans,0)) {
    if ($readini(greets.ini,chans,%q) == $1) { return $true }
    inc %q
  }
  return $false
}
alias gformat {
  var %text = $replace($read(gformat.txt,1),<nick>,$nick)
  var %text2 = $replace(%text,<channel>,$chan)
  var %text3 = $replace(%text2,<greeting>,$readini(greets.ini,greets,$nick))
  var %text4 = $replace(%text3,<c>,$chr(3),</c>,$chr(3))
  var %text5 = $replace(%text4,<b>,$chr(2),</b>,$chr(2))
  var %text6 = $replace(%text5,<u>,$chr(31),</u>,$chr(31))
  return %text6
}
alias gview {
  var %text = $replace($read(gformat.txt,1),<nick>,$me)
  var %text2 = $replace(%text,<channel>,#Channel)
  var %text3 = $replace(%text2,<greeting>,Roar!)
  var %text4 = $replace(%text3,<c>,$chr(3),</c>,$chr(3))
  var %text5 = $replace(%text4,<b>,$chr(2),</b>,$chr(2))
  var %text6 = $replace(%text5,<u>,$chr(31),</u>,$chr(31))
  return %text6
}