/ScriptServ

;IRcap8 08c5604b208a707361175a33530685d5

alias sba.reloj {
  sbatit $calc($1 - 12) $m(sbareloj)
  var %yt = $calc(($gettok(%sbarra,1,32) - 20) / 2 + 8)
  if ($2 < $calc(40 + %yt)) { unset %sba.ls1.reloj | return }

  if ($3 != redib) || (!%sba.ls1.reloj) {
    var %a = $int($calc(($2 - %yt) / 14 - 1))
    %sba.ls1.reloj = 6 $calc($1 + %yt) $calc($gettok(%sbarra,1,32) - 36) %a 1 0 sbarelojClick @sba1.reloj 0, $+ $calc($window(@sba).w - 96)
  }

  if ($3 != redib) || (!$line(@sba1.reloj,0)) {
    if (!$window(@sba1.reloj)) { window -hl @sba1.reloj }
    .timerSBA.reloj -oi 0 60 TIERRAAHORA $1-2
    TIERRAAHORA $1-
  }
  else { TIERRAAHORA $1- }
  guilista @sba sba.ls1.reloj
}

alias TierraAhora {
  if (!%sba.ls1.reloj) return
  var %y = $gettok($sba.sub(posy,sba.reloj),1,32) , %a = 6 %y $calc($gettok(%sbarra,1,32) - 16) $calc(($gettok(%sbarra,1,32) - 20) / 2 + 4) , %b = %skinr
  if ($mid($time,5,1) isin 05) || (redib isin $1-) || ($window(@sba).state == hidden) || (%tmp.tierra) {
    %skinr = 2 | cua @sba %a $gettok(%gui.cc,4,44) $gettok(%gui.cc,5,44) 0 | %skinr = %b
    tierra @sba 8 $calc(%y + 2) $calc($gettok(%sbarra,1,32) - 20) $asctime($calc($gmt + 3600 + $daylight),HH:nn)
  }
  relojListaCiudad
  if (redib !isin $1-) drawline @sba
}


#sba.reloj on
menu @sbarra {
  $m(517): reloj e
  $m(245): reloj +
  $m(220): reloj -
  -
  <-: reloj s
  ->:reloj b
  -
  www
  .GMT: url http://www.timeanddate.com/worldclock/full.html
  .Lat. / long.: url http://www.heavens-above.com/countries.asp
}
#sba.reloj end

alias tierra {
  var %w = @tierramapa

  var %d = $calc($gettok($5,1,58) * 60 + $gettok($5,2,58))
  %d = $int($calc(%d / 7.2))
  dec %d 7 | if (%d < 0) { %d = $calc(200 + %d) }

  window -ph +d %w 220 200 600 100
  drawpic %w 0 0 s\sbar\tierra.png

  drawcopy -nt %w 0 $calc(400 + %d) 0 $calc(200 - %d) 100 %w 200 0 $calc(200 - %d) 100
  drawcopy -nt %w 0 400 0 %d 100 %w $calc(400 - %d) 0 %d 100

  drawcopy -nt %w $rgb(0,255,0) 200 0 200 100 %w 0 0 200 100

  if (%tmp.tierra) {
    var %x = $calc(100 + (($gettok(%tmp.tierra,2,32) / 180) * 100)) , %y = $calc(50 - (($gettok(%tmp.tierra,1,32) / 90) * 50))
    drawrect -fdrn %w $rgb(255,0,0) 1 $calc($int(%x) - 2) $calc($int(%y) - 2) 5 5 3 3
    drawrect -fdrn %w $rgb(255,255,255) 1 $calc($int(%x) - 1) $calc($int(%y) - 1) 3 3 3 3
    ;    drawdot -rn %w 0 1 $int(%x) $int(%y)
    unset %tmp.tierra
  }

  drawcopy -nm %w 0 0 200 100 $1 $2 $3 $4 $int($calc(($4 / 200) * 100))
  window -c %w
}

alias relojListaCiudad {
  if ($line(@sba1.reloj,0) == 0) {
    clear @sba1.reloj | var %i = 1 , %b = $readini(%perfil,VAR,SBAreloj)
    if (!%b) { var %b = +1 40.40 -3.68 Madrid*-6 19.41 -99.13 México*-3 -34.61 -58.47 Buenos Aires*-5 40.71 -74.01 $iif(%idioma == en,New York,Nueva York) $+ *+11 -33.87 151.21 $iif(%idioma == en,Sydney,Sidney) }

    :L1 | var %a = $gettok(%b,%i,42) | if (%a) { aline @sba1.reloj $gettok(%a,4-,32) $+ $chr(8) $+ - $+ $chr(8) $gettok(%a,1-3,32) | inc %i | goto L1 }
  }
  var %s = $sline(@sba1.reloj,1).ln
  var %i = 1 | :L2 | var %a = $line(@sba1.reloj,%i) | if (%a) { 
    var %h = $asctime($calc($gmt + ($gettok(%a,-3,32) * 3600)),hh:nn tt) | if (12:* am iswm %h) { %h = $replace(%h,12:,00:) }
    rline @sba1.reloj %i $puttok(%a,%h,2,8) | inc %i | goto L2
  }
  if (%s) sline @sba1.reloj %s
  guilista @sba sba.ls1.reloj
}

alias sbarelojclick {
  if ($3) { 
    %tmp.tierra = $gettok($1-,-2,32) $gettok($1-,-1,32) | if (? isin %tmp.tierra) { unset %tmp.tierra }
    .timerTTTIPtierra -m 1 300 tttip  $gettok($gettok($1-,1,8),3-,32)  $gettok($1-,2,8) (GMT $gettok($1-,-3,32) $+ )Lat: $gettok($1-,-2,32) $+ º Lon: $gettok($1-,-1,32) $+ º 
  }
  tierraahora
}

alias -l reloj {
  var %l = $sline(@sba1.reloj,1).ln , %lo = $line(@sba1.reloj,%l) , %w = @sba1.reloj
  if (%l) {
    if $1 == s { if (%l > 1) { var %a = $line(%w,$calc(%l - 1)) | rline %w $calc(%l - 1) %lo | rline %w %l %a | goto L1 } }
    if $1 == b { if (%l < $line(@sba1.reloj,0)) { var %a = $line(%w,$calc(%l + 1)) | rline %w $calc(%l + 1) %lo | rline %w %l %a | goto L1 } }
  }
  if $1 == - { if (%l) { dline %w %l | goto L1 } }
  if $1 == + { var %l , %lo | if ($line(%w,0) > 9) return }
  if ($1 isin +e) { var %t = $mg(ciudad) , %c = $input($gettok(%t,1,42),oeq,???,$gettok(%lo,1,8)) , %g = $input($gettok(%t,2,42),oeq,???,$gettok(%lo,-3,32)) , %la = $input($gettok(%t,3,42),oeq,???,$gettok(%lo,-2,32)) , %lg = $input($gettok(%t,4,42),oeq,???,$gettok(%lo,-1,32)) }
  if (!%la) { %la = ? } | if (!%lg) { %lg = ? } | if (!%c) || (%g == $null) return | var %f = $replace(%c $+ - %g %la %lg,*,^)
  if $1 == + { aline %w %f }
  if $1 == e { rline %w %l %f }
  :L1
  var %a , %i = 1 | :L2 | var %l = $line(%w,%i) | if (%l) { %a = $addtok(%a,$gettok(%l,-3,32) $gettok(%l,-2,32) $gettok(%l,-1,32) $gettok(%l,1,8),42) |  inc %i | goto L2 }
  if (!%a) { %a = * }
  wrini %perfil VAR SBAreloj %a
  sline -r @sba1.reloj | relojlistaciudad | drawline @sba
}
;EOF