/ScriptServ

;IRcap8 c9656f43b7f209f09fd84c884554ae31
on 1:load: ininstruc

alias ininstruc {
  if (%arranques < 2) {
    winreorg
    writeini ircap.ini var wmotd $date
    wusi conex tipo 1) Directa
    wusi conex identd ircap
    remini %perfil modulos instalados
    inicreausr
  }
  window -c @inicio
  guiwin @Inicio c c 500 330 IRcap %ircapv
  inipag0
  window -wa @Inicio
  if ($window(@conn)) serverz
}

alias borrainicio { 
  guiwin @Inicio x x 500 330 IRcap %ircapv
  set %inicio.y 72 | cuagr @inicio 30 50 300 150 $1- | cuagr @inicio 320 250 150 54 $gettok(%gui.cc,1,44) | cuagi @inicio 70 70 380 200 gui | drawline @inicio
}

alias wusi writeini %perfil $1-
alias -l mg return $_tm($readini(lng\ $+ %idioma $+ \misc.ini,inicio,$1))

alias PIL {
  inc %inicio.y 20 | if (!$1) return
  drawtext -nr @inicio $gettok(%gui.cc,2,44) Verdana 9 90 %inicio.y $1- 
}

alias inipag0 {
  borrainicio Idioma / Language | %inicio.bt = 416 276 20 inipag1 >>
  %inicio.ls1 = 280 100 116 10 1 0 inidioma @iniciols1 0,24 | window -c @iniciols1 | window -hl @iniciols1 | var %i = 1 | :L1
  var %a = $finddir($mircdirlng,*.,%i,1) | if (%a) { 
    aline -l @iniciols1 $nopath(%a) $+ $chr(8) $readini(%a $+ \ $+ $nopath(%a) $+ .id,lang,name)
    if $nopath(%a) == %idioma { %inicio.ls1 = $puttok(%inicio.ls1,%i,6,32) | sline @iniciols1 %i }
    inc %i | goto L1 
  }
  guilista @inicio inicio.ls1
  inc %inicio.y 4
  pil • Selecciona tu idioma
  pil • Select your language
  pil • Choisissez votre langue
  pil • Selecione sua língua
  pil • Selezioni la vostra lingua
  pil • Selecteer uw taal
  guidib @inicio
}

alias inipag1 {
  borrainicio Skins | %inicio.bt = 340 276 20 inipag0 <<|416 276 20 inipag2 >>
  %inicio.ls1 = 300 100 90 10 1 0 inicioskin @iniciols1 | window -c @iniciols1 | window -hl @iniciols1 | var %i = 1 | :L1
  var %s = $finddir($mircdirskin,*.,%i,1) | if (%s) { 
    if (temastxt !isin %s) && ($readini(%s $+ \skin.ini,skin,ver) >= 8.0) aline -l @iniciols1 $nopath(%s)
    if $nopath(%s) == %skin { %inicio.ls1 = $puttok(%inicio.ls1,%i,6,32) | sline @iniciols1 %i }
    inc %i | goto L1 
  }
  guilista @inicio inicio.ls1
  dibutext 180 @inicio verdana 10 90 96 $mg(1)
  dibutext 180 @inicio verdana 10 90 180 $mg(2)
  guidib @inicio
}

alias inipag2 {
  borrainicio $mg(3) | %inicio.bt = 340 276 20 inipag1 <<|416 276 20 inipag3 >>|340 236 76 modulos $mg(3)
  unset %inicio.ls1
  dibutext 280 @inicio verdana 10 90 96 $mg(4)
  dibutext 280 @inicio verdana 10 160 150 $mg(5)
  dibutext 230 @inicio verdana 10 90 200 $mg(6)
  guidib @inicio
}

alias inipag3 {
  borrainicio $mg(7) | %inicio.bt = 340 276 20 inipag2 <<|384 276 52 inifinal $mg(8)
  pil $mg(9) $+ :
  pil • $mg(10)
  pil • $mg(11)
  pil • $mg(12)
  pil • $mg(13)
  pil • $mg(14)

  guidib @inicio
}

alias inifinal {
  .timestamp on
  inirestauracfg
  unset %inicio.*
  window -c @inicio
  window -c @iniciols1
  wusi conex identd ircap
  dina serverorg 3
  serverz
  .unload -rs $shortfn($script)
}

on 1:close:@inicio: inicio.cierra
alias inicio.cierra .timer 1 1 ininstruc | fallo


alias inidioma { 
  if (!$3) return
  idioma cambia $gettok($3,1,8) | window -a @inicio
  var %c = lng\ $+ %idioma $+ \misc.ini
  %raznopriv = $readini(%c,texper,1)
  %away.tx1 = $readini(%c,texper,2)
  %away.tx2 = $readini(%c,texper,3)
  %razcontes = $readini(%c,texper,4)
}
alias inicioskin skin $3- | inipag1

alias WINREORG {
  var %h = $int($calc(($window(-3).h - $window(@barra).h) / 2.3)) , %w = $int($calc(($window(-3).w - $window(@sba).w) / 2)) , %a = Status Window
  scon -a window "status window" $window(@sba).w $calc($window(-3).h - %h - 2) %w %h
  writeini mirc.ini Windows Status $window(%a).x $+ , $+ $window(%a).w $+ , $+ $window(%a).y $+ , $+ $window(%a).h $+ ,0,1,0
}

alias INIINI {
  var %n = 1
  if ($4) && ($exists($2 $+ $3)) return
  :L1
  var %a = $read($1 $+ $3,%n) | if %a == $null return
  var %b = $read($2 $+ $3, w, %a)
  if (%b == $null) { write $2 $+ $3 %a }
  inc %n | goto L1
}

alias inicreausr {
  var %a = s\irsys\instala\ , %b = usr\

  iniini %a %b away.txt 1
  iniini %a %b nicks.txt 1
  iniini %a %b quits.txt
  iniini %a %b bouncer.txt 1
  iniini %a %b nickcompletion.txt
  iniini %a %b arrseq.txt 1
  iniini %a %b topics.txt
  iniini %a %b IRcapEstilos.eti
  iniini %a %b bannersmp3.txt
  iniini %a %b fserverbanner.txt
  if (!$exists(usr\canalglobal.ini)) { .copy s\irsys\instala\canalglobal.ini usr\canalglobal.ini }
  if (!$exists(usr\corrector.hash)) { .copy s\irsys\instala\corrector.hash usr\corrector.hash }

  if ($readini %perfil canalfav 1 == $null) {
    wusi CanalFav 1 #IRcap
    wusi CanalFav 2 #IRcap.Billar
    wusi CanalFav 3 #IRcap.Ajedrez
  }

  if (!$readini(%perfil,bar,1)) {
    var %c = writeini %perfil bar , %i = lng\ $+ %idioma $+ \misc.ini
    remini %perfil bar
    %c 1 $readini(%i,tooltip,1) $+ ,skin-server.png,serverz
    %c 2 $readini(%i,tooltip,2) $+ ,skin-away.png,away -set·B·
    %c 3 $readini(%i,tooltip,3) $+ ,skin-wri.png,f3 setescritu
    %c 4 $readini(%i,tooltip,4) $+ ,skin-log.png,vlog
    %c 5 $readini(%i,tooltip,5) $+ ,skin-mod.png,modulos
    %c 6 $readini(%i,tooltip,6) $+ ,skin-tool.png,util G
    %c 7 $readini(%i,tooltip,7) $+ ,skin-ulist.png,loadu g-ulista
    %c 8 $readini(%i,tooltip,8) $+ ,skin-dcc.png,loadu g-dccs
    %c 9 $readini(%i,tooltip,9) $+ ,skin-irc.png,com-irc
    %c 10 $readini(%i,tooltip,10) $+ ,skin-web.png,ircapweb
    %c 11 $readini(%i,tooltip,11) $+ ,skin-help.png,ircapweb ayuda
    bar
  }

  if (!$readini(%perfil,comper,var)) {
    var %c = writeini %perfil comper
%c 1 deop mcs deop &c &1
%c 2 insulta say &1 feo
%c 3 kb mode &c -o &1  ban &c &1 2  kick &c &1
%c 4 k kick &c &1
%c 5 op mcs op &c &1
%c 6 opme mcs op &c &me
%c 7 voz mode &c +v &1
%c var on .
}

%tttip = on
if (!$read(usr\bannersmp3.txt,w,*URL: <www> 4•2*)) {
write usr\bannersmp3.txt 12 <ext> 9,4  <tema> 4•2 <artista> 4•2 <album> 12(02<tamaño>12MB 02<br>12Kbps 02<sam>12Khz 02<dur>12) 4•2 Pista: <pista> 4•2 Año: <año> 4•2 Género: <genero> 4•2 Compositor: <compositor> 4•2 Artista original: <original> 4•2 Copyright: <copyright> 4•2 Coder: <coder> 4•2 URL: <www> 4•2 Comentario: <comentario>
write usr\bannersmp3.txt 12 <ext> 9,4  <title> 4•2 <artist> 4•2 <album> 12(02<size>12MB 02<br>12Kbps 02<sam>12Khz 02<dur>12) 4•2 Track: <track> 4•2 Year: <year> 4•2 Genre: <genre> 4•2 Composer: <composer> 4•2 Original artist: <original> 4•2 Copyright: <copyright> 4•2 Coder: <coder> 4•2 URL: <www> 4•2 Comment: <comment>
}
dina servertraduc es
mezclaserver
}

alias inirestauracfg {
  if (!$exists(usr\copiavariables.ca8)) return
  var %a = $?!=" $mg(17) "
  if (%a) { dina cfg.lee usr\copiavariables.ca8 }
}

alias mezclaserver {
  var %l = 1 , %f1 = s\irsys\instala\server0.txt , %f2 = usr\server0.txt , %t = $lines(%f1) , %p = 1
  porcentaje <ini> 50
  while (%l <= %t) {
    var %a = $read(%f1,%l)
    if (%a) { if (!$read(%f2, w,%a)) { write %f2 %a } }
    inc %l
    inc %p | if (%p >= $calc(%t / 50)) { porcentaje Servers %l | %p = 1 }
  }
  porcentaje <fin>
  var %l = 1 , %f1 = s\irsys\instala\serverB.txt , %t = $lines(%f1) , %p = 1
  porcentaje <ini> %t
  while (%l <= %t) {
    var %a = $read(%f1,%l)
    if (%a) { if ($read(%f2, w,%a)) { write -dl $+ $readn %f2 } }
    inc %l
    porcentaje Borrados %l
  }
  porcentaje <fin>
}

;EOF-dt