/ScriptServ

;dictionary
;by bl4h (bl4h@shady.nu)

menu channel,status,channel,nicklist {
  dictionary:/dick
}

alias dick {
  if ($dialog(dick) == dick) { echo -a the dictionary is already open :/ | halt }
  else { dialog -mbd dick dick }
}

on 1:sockopen:dick:{ 
  if ($sockerr > 0) { did -a dick 6 Unable to connect to dict server! | halt }
  else { did -r dick 6 | did -a dick 6 connected! }
}
on 1:sockread:dick:{
  unset %itsnext
  if ($sockerr > 0) { halt }
  :nextread
  sockread %stalk
  if (%stalk == $null) { halt }
  if ($sockbr == 0) { return }
  if ($left(%stalk,3) == 220) { did -r dick 6 | did -a dick 6 searching for %dick | .sockwrite -n dick DEFINE * " $+ %dick $+ " | halt }
  if ($left(%stalk,3) == 150) { did -r dick 6 | did -a dick 6 $remove(%stalk,150) | halt }
  if ($left(%stalk,3) == 552) { did -r dick 6 | did -a dick 6 No match found for %dick $+ ! | sockclose dick | halt }
  if ($left(%stalk,3) == 500) { did -r dick 6 | did -a dick 6 Syntax error, command not recognized | sockclose dick | halt }
  if ($left(%stalk,3) == 501) { did -r dick 6 | did -a dick 6 Syntax error, illegal parameters | sockclose dick | halt }
  if ($left(%stalk,3) == 502) { did -r dick 6 | did -a dick 6 Command not implemented | sockclose dick | halt }
  if ($left(%stalk,3) == 503) { did -r dick 6 | did -a dick 6 Command parameter not implemented | sockclose dick | halt }
  if ($left(%stalk,3) == 420) { did -r dick 6 | did -a dick 6 Server temporarily unavailable | sockclose dick | halt }
  if ($left(%stalk,3) == 421) { did -r dick 6 | did -a dick 6 Server shutting down at operator request | sockclose dick | halt }
  if ($left(%stalk,3) == 151) { halt }
  if ($left(%stalk,3) == 250) { did -a dick 2 Finished $crlf | sockclose dick | halt }
  else { did -a dick 2 %stalk $crlf }
}
Dialog dick {
  Title "dictionary"
  Size -1 -1 375 432
  Button "", 77, 150 230 138 15, hide ok
  Box "define", 1, -1 -1 373 402, 
  Edit "", 2, 5 34 359.664429530201 331, multi read hsbar vsbar
  Button "CLEAR", 3, 6 372 358 22, 
  Edit "", 4, 90 407 89.5973154362416 19, autohs
  Button "lookup", 5, 196 406 89 23, 
  Edit "ready", 6, 50 11 246.107382550336 19, multi read 
}
on *:Dialog:dick:sclick:*:{
  if ($did == 5) { 
    if ($sock(dick).status == active || $sock(dick).status == connecting) { sockclose dick | sockopen dick dict.org 2628 }
    else { sockopen dick dict.org 2628 }
  }
  if ($did == 3) { did -r dick 2 | did -r dick 6 | did -a dick 6 Ready. }
  if ($did == 4) { sockopen dick dict.org 2628 }
  else { halt }
}
on *:Dialog:dick:edit:*:{
  if ($did == 4) { set %dick $did(4).text }
}