/ScriptServ

;============================|
;bDs Port Scanner v1.0
;
;Created By	bdimag
;Email		bdimag@cox.net
;IRC		irc.DAL.net
;Channels	/whois bdimag
;============================|

alias -l portscan {
  if (!$2) && (!$3) { halt }
  if ($4) {
    set %onportnum $3 | set %totalports $4 | set %portscanhost $2
    set %portscantimeout $right($1,-2)
  }
  .timerportscan. $+ $3 -m 1 $right($1,-2) portscan.close $3
  sockopen portscan. $+ $3 $2-  | inc %onportnum 1
  dialog -t portscan bDs Port Scanner ( $+ $3 $+ ) 
}
alias -l mdx { dll $findfile($mircdir,mdx.dll,1) $1- }
alias -l portscan.close sockclose portscan. $+ $1 | if ($dialog(portscan)) { did -ra portscan 5 $calc($did(portscan,5) + 1) } | if (%onportnum <= %totalports) { portscannext } | else { portscanstop }
alias -l portscanstop { dialog -t portscan bDs Port Scanner | unset %portscantimeout | unset %onportnum | unset %totalports | unset %portscanhost | did -ra portscan 15 START | sockclose portscan.* | .timerportscan.* off }
alias -l port { return $readini(ports.ini,ports,$1) }
alias -l portscannext { portscan -t $+ %portscantimeout %portscanhost %onportnum }
on 1:sockopen:portscan.*:if (!$sockerr) { .timerportscan. $+ $sock($sockname).port off | did -ra portscan 4 $calc($did(portscan,4) + 1) | did -a portscan 1 0 0 0 0 $sock($sockname).port $+ $chr(9) $+ $iif($readini(ports.ini,ports,$sock($sockname).port) != $null,$ifmatch,Undefined) } | sockclose $sockname | if (%onportnum <= %totalports) { portscannext } | else { portscanstop }
on 1:dialog:portscan:*:*:{
  if ($devent == init) {
    did -f $dname 8
    mdx MarkDialog $dname
    mdx SetControlMDX $dname 1 listview rowselect single report > $findfile($mircdir,views.mdx,1)
    did -i $dname 1 1 headerdims 50:1 218:2
    did -i $dname 1 1 headertext Port $+ $chr(9) $+ Description
  }
  if ($devent == close) { sockclose portscan.* | .timerportscan.* off }
  if ($devent == sclick) {
    if ($did == 15) {
      if ($did(15) == START) {
        portscan -t $+ $did(14) $did(8) $did(10) $did(11)
        did -ra $dname 4 0 | did -ra $dname 5 0
        did -r $dname 1
        did -ra $dname 15 STOP
      }
      else { portscanstop }
    }
  }
}
dialog portscan {
  title "bDs Port Scanner"
  size -1 -1 137 121
  option dbu
  icon scanner.ico, 0
  list 1, 0 38 137 83, size
  text "Open Ports:", 2, 1 30 28 8
  text "Timeouts:", 3, 95 30 25 8
  text "", 4, 30 30 16 8, right
  text "", 5, 120 30 16 8, right
  box "", 6, 0 -2 137 30
  text "IP/Host:", 7, 3 5 22 8
  edit "", 8, 24 4 85 10, autohs
  text "Port Range:", 9, 3 17 30 8
  button "START", 15, 110 4 25 10, default
  edit "1", 10, 34 16 18 10, autohs
  edit "2000", 11, 59 16 18 10, autohs
  text "to", 12, 53 17 5 8
  text "Timeout (ms):", 13, 83 17 32 8
  edit "1000", 14, 116 16 18 10, autohs
}
alias portscanner dialog -m portscan portscan
menu menubar {
  Port Scanner:portscanner
}