/ScriptServ

alias initial {
  if (!$dialog(initial)) { var %s = $dialog(initial,initial) }
  else { dialog -v initial }
}
dialog initial {
  title "Welcome to Reflex"
  size -1 -1 230 154
  option dbu
  icon 1, 0 -1 74 138,  $icodir $+ reflex.png, 1, noborder
  box "", 2, -3 133 240 4
  button "OK", 3, 191 140 37 12, disabled ok
  text "", 6, 73 0 157 136
  text "Welcome to Reflex.", 7, 82 5 142 18
  text You have just loaded Reflex $data(version) $+ ., 8, 82 23 142 11
  text "Before you connect to an irc server mIRC needs to know some information. Fake information can be supplied if you want to remain anonymous.", 9, 82 34 142 22
  text "Nickname", 10, 82 63 35 8, right
  edit "", 11, 120 61 104 11, autohs
  text "Full Name", 12, 82 76 35 8, right
  edit "", 13, 120 74 104 11, autohs
  edit "", 14, 120 87 104 11, autohs
  text "Email Address", 15, 82 89 35 8, right
  text "You may also provide an alternate nickname in case your default nickname is taken.", 16, 82 103 142 14
  edit "reflexuser", 17, 120 120 104 11, autohs
  text "Alt. Nickname", 18, 82 122 35 8, right
}

on *:dialog:initial:init:0: {
  mdx SetMircVersion $version
  mdx MarkDialog $dname
  mdx SetDialog $dname Icon
  var %t = 7,8,9,10,12,15,16,18
  mdx SetColor $dname %t text 0
  mdx SetColor $dname 6, $+ %t textbg 16777215
  mdx SetColor $dname 6, $+ %t background 16777215
  mdx SetFont $dname 7 18 700 Tahoma
  mdx SetBorderStyle 11,13,14,17 clientedge
}
on *:dialog:initial:edit:11,13,14: {
  if ($did($dname,11)) && ($did($dname,13)) && ($did($dname,14)) { did -e $dname 3 }
  else { did -b $dname 3 }
}
on *:dialog:initial:sclick:3: {
  if ($did($dname,11)) { .nick $v1 }
  if ($did($dname,13)) { .fullname $v1 }
  if ($did($dname,14)) { .emailaddr $v1 }
  if ($did($dname,17)) { .anick $v1 }
}