/ScriptServ

alias passdata { return $datdir $+ pass.dat }
alias add_npass {
  if ($1) && ($network) {
    if ($istok($readini($passdata,nick,$network),$+($me,:,$1),32)) { return }
    elseif ($network == undernet) && ($readini($passdata,nick,$network) == $+($1,:,$2)) { return }      
    elseif ($network == quakenet) && ($readini($passdata,nick,$network) == $+($1,:,$2)) { return }  
    else {
      if ($input($+(Would you like Reflex to remember this password ?,$crlf,Reflex can use it to Auto-Identify when you ,$crlf,connect to this network $iif($network,$+($chr(40),$network,$chr(41))),$crlf,if auto-identify is on in the options.),y,Auto-Identify)) {
        if ($network == undernet) { writeini -n $passdata nick $network $+($1,:,$2) }      
        elseif ($network == quakenet) { writeini -n $passdata nick $network $+($1,:,$2) }      
        else { writeini -n $passdata nick $network $addtok($readini($passdata,nick,$network),$+($me,:,$1),32) }
      }
    }
  }
}
on *:connect: {
  if ($data(autoidentify)) && ($readini($passdata,nick,$network))  {
    var %s = $v1 , %i = 1 , %x
    if ($network == undernet) { !MSG X@channels.undernet.org login $gettok(%s,1,58) $gettok(%s,2,58) | mode $me +x }
    elseif ($network == quakenet) { !MSG q@cserve.quakenet.org auth $gettok(%s,1,58) $gettok(%s,2,58) | mode $me +x }
    else {
      while (%i <= $numtok(%s,32)) {
        %x = $gettok(%s,%i,32)
        if ($me == $gettok(%x,1,58)) {
          !MSG nickserv identify $gettok(%x,2,58)
        }
        inc %i
      } 
    }
  }
}
on *:nick: {
  if ($data(autoidentify)) && ($readini($passdata,nick,$network))  {
    var %s = $v1 , %i = 1 , %x
    if ($network == undernet) { return }
    elseif ($network == quakenet) { return }
    else {
      while (%i <= $numtok(%s,32)) {
        %x = $gettok(%s,%i,32)
        if ($newnick == $gettok(%x,1,58)) {
          !MSG nickserv identify $gettok(%x,2,58)
        }
        inc %i
      } 
    }
  }
}
alias auto_insert_msgbit {
  if (!$read($datdir $+ Kte-Dyn.mrc,sn,trigger_autonmsg)) {
    var %s = $read($datdir $+ Kte-Dyn.mrc,s,alias msg) , %i = $calc($readn + 2)
    if (%i) { 
      write -il $+ %i $datdir $+ Kte-Dyn.mrc trigger_autonmsg $!1-
      .reload -rs $datdir $+ Kte-Dyn.mrc
    }
  }
}
/* 
Triggers
*/
alias trigger_autonmsg {
  if ($1 == X@channels.undernet.org) && ($2 == login) && ($network == undernet) { add_npass $3 $4 }
  elseif ($1 == q@cserve.quakenet.org) && ($2 == auth) && ($network == quakenet) { add_npass $3 $4 }
  elseif ($1 == nickserv) && ($2 == identify) { add_npass $3 }
}
alias nickserv { raw -q nickserv $1- | if ($1 == identify) { add_npass $2 } }
alias ns { raw -q ns $1- | if ($1 == identify) { add_npass $2 } }
alias identify { raw -q identify $1- | if ($left($1,1) != $chr(35)) { add_npass $1 } }