/ScriptServ

;; devMP3! Search Engine v1.0 Beta
;; created by dephekt (dephekt@yahoo.com)
;; --> ircdev scripting team : http://ircd4mirc.sourceforge.net
;; (c) dephekt [ircdev] 2001


dialog devmp3 {
  title "devMP3! Search Engine - [MP3 Search]"
  option dbu
  size -1 -1 220 122

  tab "MP3 Search", 1, 4 0 210 104
  box "Search", 33, 8 16 202 34, tab 1
  text "Title:", 34, 14 25 12 7, tab 1
  edit "", 35, 29 24 141 10, tab 1 autohs
  text "Artist:", 36, 12 36 13 8, tab 1
  edit "", 37, 29 35 141 10, tab 1 autohs
  list 38, 8 53 202 47, tab 1 size extsel
  button "Clear!", 39, 173 35 33 11, tab 1
  button "Search!", 40, 173 23 33 11, tab 1 default

  tab "MP3 Channels", 2
  list 41, 9 17 200 66, tab 2 size extsel
  button "Add Channel", 42, 50 87 37 12, tab 2
  button "Del Channel", 43, 90 87 37 12, tab 2
  button "Join Chans", 44, 130 87 37 12, tab 2

  tab "Properties", 3
  box "Search Trigger", 45, 149 17 60 79, tab 3
  radio "@locator", 46, 153 29 50 10, tab 3
  radio "@find", 47, 153 40 50 10, tab 3
  radio "@mp3", 48, 153 52 50 10, tab 3
  radio "@search", 49, 153 64 50 10, tab 3
  radio "@whereis", 50, 153 76 50 10, tab 3
  check "Use custom search trigger:", 51, 10 18 75 10, tab 3
  edit "", 52, 84 18 57 10, tab 3 autohs
  check "Open dialog on connect", 53, 10 30 71 10, tab 3
  check "Join MP3 channels on connect", 11, 10 42 125 10, tab 3
  check "Join MP3 channels when devMP3! is opened", 222, 10 54 125 10, tab 3
  check "Ask to open MP3 files when downloading is done", 13, 10 66 125 10, tab 3
  check "Show devMP3! in popups", 6, 10 78 125 10, tab 3

  tab "About", 4
  box "devMP3! Search Engine v1.0", 54, 10 16 198 80, tab 4
  text "ircdev scripting team (http://ircd4mirc.sourceforge.net)", 55, 15 24 128 8, tab 4
  text "created by dephekt (dephekt@yahoo.com)", 56, 21 32 102 7, tab 4
  box "Info", 57, 16 40 185 51, tab 4
  text "devMP3! engine is just a small script that is supposed to make your irc mp3 searching experience much easier :-) just choose your type of trigger, channels where you want to search, and click Search! This is only version 1.0 and is still in beta, so please report all bugs to me.. check out the ircdev website for more cool stuff and of course the elite ircdev script :)", 58, 20 50 176 39, tab 4

  button "OK", 5, 178 107 35 13, ok
  button "Help!", 9, 141 107 35 13
  button "Get File(s)", 10, 104 107 35 13
  button "Save Props.", 12, 67 107 35 13
}
dialog devmp3.error {
  title "devMP3! Search Engine - [Error]"
  option dbu
  size -1 -1 150 50
  text "", 2, 2 2 146 28, return
  button "OK", 1, 55 37 40 12, ok
}
on *:connect: {
  if $ss(connect-open) && $dialog(mp3search) == $null { .timer -m 1 5 mp3search }
  if $ss(connect-join) { .timer -m 1 5 mp3search.joinchans }
}
on *:FILERCVD:*.mp3: {
  mp3search.openmp3 $filename
}
alias -l mp3search.openmp3 {
  var %file = $1-
  if $$?!="You have finished downloading: $+ $crlf $+ ' $+ $nopath(%file) $+ '. $+ $crlf $+ Do you want to run it now?" == $false { return }
  if $2 != $null && $left($1,1) != " { %file = " $+ %file $+ " }
  .run %file
}
on *:dialog:devmp3:*:*: {
  if $devent == init {
    if $server && $ss(open-join) { mp3search.joinchans }
    chan.display
    if $ss(trigger) == $null { ss trigger 1 | did -c $dname 46 }
    else { did -c $dname $calc($ss(trigger) + 45) }
    if $ss(custom-trigger) == $null { ss custom-trigger $false }
    did -a $dname 52 $ss(custom-trigger-value)
    if $ss(custom-trigger) { var %i = 45 | while %i <= 50 { did -b $dname %i | inc %i } | did -c $dname 51 }
    else { did -b $dname 52 }
    if $ss(connect-open) { did -c $dname 53 }
    if $ss(connect-join) { did -c $dname 11 }
    if $ss(open-mp3) { did -c $dname 13 }
    if $ss(open-join) { did -c $dname 222 }
    if $ss(popups) { did -c $dname 6 }
  }
  if $devent == sclick {
    if $did == 44 {
      if $server == $null { return }
      mp3search.joinchans
    }
    if $did == 40 {
      if $did(35) == $null && $did(37) == $null { did -ra $dname 38 Specify artist and song name! | return }
      var %search = $did(37) $did(35) | %search = $replace(%search,$chr(32),*) | %search = * $+ %search $+ *
      did -ra $dname 38 Searching for ' $+ %search $+ ' now - please wait...
      if $ss(custom-trigger) { mp3search.msg $ss(custom-trigger-value) %search | return }
      else { mp3search.msg $did($calc($ss(trigger) + 45)) %search | return }
    }
    if $did == 10 {
      if $gettok($did(38,$did(38,1).sel),1,32) == Searching { return }
      if $did(38,0).sel == 0 { return }
      var %i = 1
      while %i <= $did(38,0).sel { mp3search.msg $did(38,$did(38,%i).sel) | inc %i } | %i = 1
      while %i <= $did(38,0).sel { did -u $dname 38 $did(38,%i).sel | inc %i }
    }
    if $did == 51 { if $did(51).state == 1 { did -e $dname 52 | var %i = 45 | while %i <= 50 { did -b $dname %i | inc %i } } | else { var %i = 45 | while %i <= 50 { did -e $dname %i | inc %i } | did -b $dname 52 } }
    if $did == 39 { did -r $dname 38 }
    if $did == 1 { dialog -t $dname devMP3! Search Engine v1.0 - [MP3 Search]  }
    if $did == 2 { dialog -t $dname devMP3! Search Engine v1.0 - [MP3 Channels] }
    if $did == 3 { dialog -t $dname devMP3! Search Engine v1.0 - [Properties] }
    if $did == 4 { dialog -t $dname devMP3! Search Engine v1.0 - [About...] }
    if $did == 42 { chan.add $$?="Enter #channel to add to the mp3 channels list: " | chan.display | return }
    if $did == 43 { :delete | var %i = 1 | while %i <= $did(41,0).sel { chan.del $did(41,%i) | inc %i } | chan.display }
    if $did == 5 || $did == 12 {
      ss custom-trigger-value $did(52)
      if $did(51).state { ss custom-trigger $true }
      else { ss custom-trigger $false }
      if $did(46).state { ss trigger 1 }
      if $did(47).state { ss trigger 2 }
      if $did(48).state { ss trigger 3 }
      if $did(49).state { ss trigger 4 }
      if $did(50).state { ss trigger 5 }
      if $did(53).state { ss connect-open $true } | else { ss connect-open $false }
      if $did(11).state { ss connect-join $true } | else { ss connect-join $false }
      if $did(13).state { ss open-mp3 $true } | else { ss open-mp3 $false }
      if $did(6).state { ss popups $true } | else { ss popups $false }
      if $did(222).state { ss open-join $true } | else { ss open-join $false }
      mp3search.popups
    }
    if $did == 9 { run $scriptdir $+ README-DEVMP3.txt }
  }
}
alias mp3search.joinchans {
  var %i = 1 , %s = 0 , %lines = $lines($devmp3.inf(channels))
  while %i <= %lines {
    %s = $read -l [ $+ [ %i ] ] $devmp3.inf(channels)
    if $me !ison %s && %s != $null { .timer -m 1 5 join %s }
    inc %i
  }
}
alias -l mp3search.msg {
  var %i = 1, %lines = $lines($devmp3.inf(channels)) , %s = 0
  while %i <= %lines {
    %s = $read -l [ $+ [ %i ] ] $devmp3.inf(channels)
    if %s != $null { msg %s $1- }
    inc %i
  }
}
alias mp3search {
  if $dialog(devmp3) { return }
  dialog -m devmp3 devmp3
}
alias -l chan.add {
  var %channel = $$1
  if $left(%channel,1) != $chr(35) { %channel = $chr(35) $+ %channel }
  if $didwm(devmp3,41,%channel) { error Channel ' $+ %channel $+ ' is already on your mp3 channels list. | return }
  write $devmp3.inf(channels) %channel
  write -l1 $devmp3.inf(channels) $lines($devmp3.inf(channels))
}
alias -l chan.del {
  var %i = 1, %chan = $$1 , %s = 0 , %lines = $lines($devmp3.inf(channels))
  while %i <= %lines {
    %s = $read -l [ $+ [ %i ] ] $devmp3.inf(channels)
    if %s == %chan { write -dl [ $+ [ %i ] ] $devmp3.inf(channels) | write -l1 $devmp3.inf(channels) $lines($devmp3.inf(channels)) | return }
    inc %i
  }
}
alias -l error { 
  if $dialog(devmp3.error) == $null { dialog -m devmp3.error devmp3.error }
  did -ra devmp3.error 2 $$1-
}
alias -l devmp3.inf {
  goto $$1
  :channels | return $scriptdir $+ mp3search-chans.dat
  :settings | return $scriptdir $+ mp3search-settings.dat
}
alias -l chan.display {
  did -r devmp3 41
  var %i = 1, %lines = $lines($devmp3.inf(channels))
  while %i <= %lines { did -i devmp3 41 $calc($did(devmp3,41).lines + 1) $read -l [ $+ [ %i ] ] $devmp3.inf(channels) | inc %i }
}
alias -l ss {
  if $isid { return $readini $devmp3.inf(settings) settings $$1 }
  else { writeini $devmp3.inf(settings) settings $$1 $$2 $3- }
}
on 1:text:*:?: {
  if $dialog(devmp3) == $null { return }
  var %s = $strip($1-)
  if match isin %s && copy isin %s { .auser mp3serv $nick | closemsg $nick | return }
}
on mp3serv:text:*:?: {
  if $dialog(devmp3) == $null { .rlevel mp3serv | return }
  var %string = $strip($1-)
  :recheck
  if $left(%string,1) == $chr(32) { %string = $right(%string,-1) | goto recheck }
  if $left(%string,1) == ! && .mp3 isin %string {
    did -i devmp3 38 $calc($did(devmp3,38).lines + 1) $strip($1-)
    closemsg $nick
  }
  if total isin %string && found isin %string { .ruser mp3serv $nick | closemsg $nick }
  if many isin %string && result isin %string && list isin %string { .ruser mp3serv $nick | closemsg $nick }
  if match isin %s && copy isin %s { closemsg $nick | return } 
}
on *:start: {
  .rlevel mp3serv
  mp3search.popups
  echo -s 1[DEV]2 devMP3! Search Engine v1.0 loaded. [[ type /mp3search to run, or look under popups ]]
}
alias -l mp3search.popups {
  if $ss(popups) == $false { .disable #mp3searchpopups }
  else { .enable #mp3searchpopups }
}
#mp3searchpopups on
menu status,channel,menubar {
  -
  devMP3! Search Engine:mp3search
  -
}
#mp3searchpopups end