/ScriptServ

;/**********************************************************************
; *
; * aIRC
; * Usermode
; *
; **********************************************************************/

ON *:CONNECT:{
  _usermode.devent.refresh
}
ON *:DISCONNECT:{ .timer -o 1 0 _usermode.devent.refresh }
ON *:USERMODE:{ _usermode.devent.refresh }
raw 381:*:{
  _usermode.devent.refresh
  if ($_getnetsetting(modes_on_oper).state) { usermode ? $_getnetsetting(modes_on_oper) $+ $iif(O isincs $usermode,O) $+ $iif(o isincs $usermode,o) }
}
alias _usermode {
  if ($1- == $null) {
    _dialog -m usermode usermode
    _usermode.devent.refresh
    return
  }
  if ($_disconnected) { return }
  if ($1 == ?) { _setmymode $2- }
  else { mode $me $1 }
}
dialog usermode {
  size -1 -1 250 84
  title "Usermode"
  option dbu

  box "Current",1,5 5 65 55

  check "&invisible [+i]",1010,10 15 55 8
  check "&server notices [+s]",1011,10 25 55 8
  check "&wallops [+w]",1012,10 35 55 8
  edit "",1013,10 45 55 10,autohs

  text "",2200,5 65 135 8
  text "",2201,5 75 135 8

  button "&Ok",2400,215 10 30 15,ok
  button "&Cancel",2401,215 28 30 15,cancel
  button "&Apply",2402,215 46 30 15
  button "&Help",2403,215 64 30 15

  list 2500,300 300 300 300.hide
}
alias _usermode.devent.refresh {
  var %d = usermode
  if ($dialog(%d) == $null) { return }
  if ($_connected) {
    did -o %d 2200 1 Server: $server $iif(%.network,$^sbp(%.network))
    did -o %d 2201 1 Known modes: %.usermodes
    did -e %d 1010,1011,1012,1013
    if ($_not($did(%d,2500,1))) { _usermode.devent.refresh2 1010 $usermode }
  }
  else {
    did -o %d 2200 1 Server: [disconnected]
    did -r %d 2201
    did -b %d 1010,1011,1012,1013
  }
}
alias _usermode.devent.refresh2 {
  var %d = usermode
  did $iif(i isincs $2,-c,-u) %d $calc($1 + 0)
  did $iif(s isincs $2,-c,-u) %d $calc($1 + 1)
  did $iif(w isincs $2,-c,-u) %d $calc($1 + 2)
  if ($removecs($2,+,i,s,w) != $null) { did -o %d $calc($1 + 3) 1 $ifmatch }
  else { did -r %d $calc($1 + 3) }
}
ON *:DIALOG:usermode:init:0:{
  _mdx.init $_icofile(usermode.ico)
  did -o $dname 2500 1 0
  did -o $dname 2500 2 0
  did -o $dname 2500 3 0
_dummy $_lang.loaddialog($dname,_usermode,00086969,main.lang,$scriptdir)
}
ON *:DIALOG:usermode:*:1010,1011,1012,1013:{ did -o $dname 2500 1 1 }
ON *:DIALOG:usermode:sclick:2400,2402:{
  did -o $dname 2500 1 0
  did -o $dname 2500 2 0
  did -o $dname 2500 3 0
  if ($_connected) { usermode ? $iif($did(1010).state,i) $+ $iif($did(1011).state,s) $+ $iif($did(1012).state,w) $+ $did(1013) }
  _unloadusermodemrc
}
ON *:DIALOG:usermode:sclick:2401:{ _unloadusermodemrc }
alias -l _unloadusermodemrc { _quickunload usermode $script }