/ScriptServ

;/**********************************************************************
; *
; * aIRC
; * RAW
; *
; **********************************************************************/
;
raw 1:*:{
  writeini " $+ $_tmpdir(session.ini) $+ " script netinit 0
  var %myaddy = $gettok($1-,$0,32)
  if ($_isfullmask(%myaddy)) { %.myaddress = %myaddy }
  else { ._nickhost $me 5 _donothing _donothing }
  _lag
}
raw 2:*:{ %.serversion = $8 }
raw 4:*:{
  unset %.network
  if (i isincs $4) && ((o isincs $4) || (w isincs $4) || (s isincs $4)) {
    %.serversion = $3
    %.usermodes = $4
    %.chanmodes = $5
  }
  else {
    %.usermodes = oiws
    %.chanmodes = abiklmnoprstv
    .quote version
  }
  _network 1
  if (%.network == $null) {
    _network 0
    .timer -o 1 0 _askservice
  }
  else {
    _services.load
    _setserverstuff
  }
}
alias -l _askservice {
  var %win = @__askservice,%net,%tmp = $replace($gettok($server,$_nospaces($calc($numtok($server,46) - 1),-),46),.,_)
  %tmp = $upper($left(%tmp,1)) $+ $right(%tmp,-1)
  %.network = %tmp
  close -@ %win
  window -hls %win
  loadbuf 2-9999999 %win $_usrdir(snets.ini)
  if ($fline(%win,%tmp,0) == 0) { aline %win %tmp }
  %net = $strip($_rparameter($null,1,Network identification,1,%tmp,%win,$null,The script couldn't identify this network<CRLF>Enter the IRC network:))
  if (%net == $null) { %.network = %tmp }
  else {
    %.network = %net
    _setsetup serv2net $server %net
  }
  _services.load
  _setserverstuff
  _onconnect.init-server
}
raw 351:*:{
  var %old = %.serversion
  %.serversion = $2
  if (*. iswm %.serversion) { %.serversion = $left(%.serversion,-1) }
  _network 0
  if (%.serversion != %old) { _setserverstuff }
}
alias _setserverstuff {
  if (u2.* iswm %.serversion) || (bahamut* iswm %.serversion) || (dal* iswm %.serversion) || (chatnet* iswm %.serversion) { %.maxmodes = 6 }
  elseif (2.8* iswm %.serversion) || (*.dal.net iswm $server) { %.maxmodes = 4 }
  else { %.maxmodes = 3 }
  if (%.network = ircnet) { %.maxkicks = 4 }
  else { %.maxkicks = 1 }
  if (2.8/hybrid-6* iswm %.serversion) { %.maxtargs = 1 }
  else { %.maxtargs = 0 }
}
raw 315:*:{
  if ($_address($me,5) != $null) { %.myaddress = $ifmatch }
  if ($istok(%c.reial.c,$2,32)) {
    %c.reial.c = $remtok(%c.reial.c,$2,1,32)
    if (%c.reial.c == $null) { unset %c.reial.c }
    if ($me ison $2) {
      if ($me !isop $2) && ($_getsetup(script,_autologin)) { _bot.use 0 opme $2 }
      if ($_rchini(_scanclones,$2) == 1) { _clones $2 echo }
    }
    halt
  }
}
raw 332:*:{
  if ($3- != $null) { _recent.add topic 20 $replace($3-,$2,<CHAN>) }
}
raw 352:*:{
  if ($istok(%c.reial.c,$2,32)) { halt }
}
raw 354:*:{
  if ($istok(%c.reial.c,$2,32)) { halt }
}
raw 366:*:{
  var %chan = $2
  if ($_rchini(_updateial,%chan) == 1) { _scanial.auto %chan }
  _enforce.topic %chan
  _enforce.modes %chan
  var %bl = $_rchini(_updatebanlist,%chan)
  if (%bl == 1) || ((%bl > 1) && ($me isop %chan)) { _updatebanlist %chan }
}
raw 436:*:{
  if ($2 == $me) { rnick 30 }
}
raw 471:*:{ .timer 1 0 _bot.use 0 inviteme $2 }
raw 473:*:{ .timer 1 0 _bot.use 0 inviteme $2 }
raw 474:*:{
  .timer 1 0 _bot.use 0 inviteme $2
  .timer 1 0 _bot.use 0 unbanme $2
}
raw 475:*:{ .timer 1 0 _bot.use 0 inviteme $2 }
raw 476:*:{ .timer 1 0 _bot.use 0 inviteme $2 }