/ScriptServ

[aliases]
n0=display {
n1=  if ($1 == $null) { disp | return }
n2=  if ($istok(-l -h,$remove($1,b),32)) {
n3=    %_f = $iif($2-,$2-,$iif($remove($1,b) == -h,Terminal,Courier New))
n4=    font $iif(b isin $1,-sb,-s) %_f
n5=    window -h @.font
n6=    %.fsize = , $+ $calc( [ $iif($window(@.font).fontbold,700,400) ] + [ $window(@.font).fontsize ] )
n7=    close -@ @.font
n8=    var %Chan.Num = $chan(0), %Query.Num = $query(0)
n9=    if (%Chan.Num) {
n10=      :chan
n11=      font $iif(b isin $1,-b) $chan(%Chan.Num) %_f
n12=      dec %Chan.Num
n13=      if (%Chan.Num) goto chan
n14=    }
n15=    else _remfonts
n16=    if (%Query.Num) {
n17=      :qwin
n18=      font $iif(b isin $1,-b) $query(%Query.Num) %_f
n19=      dec %Query.Num
n20=      if (%Query.Num) goto qwin
n21=    }
n22=    _set display ascii $iif($remove($1,b) == -h,high,low)
n23=    if ($gettok(%_f,1,32) isnum) {
n24=      _set display fontsize $ifmatch
n25=      _set display font $gettok(%_f,2-,32)
n26=    }
n27=    else _set display font %_f
n28=    %_f = $iif($2 isnum,$3-,%_f) $+ %.fsize
n29=    writeini $_mircini fonts fchannel %_f
n30=    writeini $_mircini fonts fquery %_f
n31=    writeini $_mircini fonts fmessage %_f
n32=    writeini $_mircini fonts fdccs %_f
n33=    writeini $_mircini fonts fdccg %_f
n34=    writeini $_mircini fonts fnotify %_f
n35=    saveini | unset %clone.siteban %ctrlf2 %_f %.fsize
n36=    if ($show) { iecho Now switched to $iif($remove($1,b) == -l,low,high) ascii mode.
n37=    iecho Press F9 to make the fonts bigger. Press Ctrl+F9 to make the fonts smaller. }
n38=  }
n39=  else bhelp DISPLAY
n40=}
n41=drawbox {
n42=  drawrect -nf $1 0 1 $2-
n43=  drawline -n $1 1 1 $2-3 $2 $calc($3 + $5)
n44=  drawline -n $1 1 1 $2-3 $calc($2 + $4) $3
n45=  drawline -nr $1 $rgb(face) 1 $2 $calc(($5 + $3) - 1) $calc(($4 + $2) - 1) $calc(($5 + $3) - 1)
n46=  drawline -nr $1 $rgb(face) 1 $calc(($4 + $2) - 1) $calc($3 + 1) $calc(($4 + $2) - 1) $calc(($5 + $3) - 1)
n47=}
n48=rehash {
n49=  if (($i(colors,n0) == $null) || ($numtok($i(colors,n0),44) < 5)) _set colors n0 10,04,16,11,14
n50=  if ($i(colors,n1) == $null) _set colors n1 default
n51=  if ($i(display,ascii) == $null) _set display ascii high
n52=  _2 display font Terminal
n53=  .display - $+ $left($i(display,ascii),1) $i(display,font)
n54=  _remfonts
n55=  _2 awaysettings logging on | _2 awaysettings pager on | _2 awaysettings autoaway on
n56=  _2 awaysettings automins 10 | _2 awaysettings autosecs 600 | _2 ctcps ignore_time 60
n57=  _2 ctcps adcc 1 | _2 ctcps rejectkick off | _2 ctcps rejectswitch off
n58=  _2 ctcps outgoing active | _2 ctcps incoming active | _2 ctcps ctcp_abuse off
n59=  _2 ctcps ignore_type 2 | _2 spam toggle off | _2 sounds toggle off
n60=  _ autobot off
n61=  _ shownames on
n62=  _ showsynch on
n63=  _ showtopic on
n64=  _ showstats on
n65=  _ botnet_join on
n66=  _ botnet_notice off
n67=  _ botnet_nick on
n68=  _ botnet_public off
n69=  _ maxbotjoin 7
n70=  _ maxbotnick 10
n71=  _ maxbotnotice 10
n72=  _ maxbotpublic 30
n73=  _ maxrepeat 5
n74=  _ maxctcp 5
n75=  _ maxtext 8
n76=  _ maxnick 4
n77=  _ maxnotices 5
n78=  _ maxjoins 9
n79=  _ maxdeop 0
n80=  _ maxkick 0
n81=  _ maxban 0
n82=  _ repeat_time 10
n83=  _ ctcp_time 10
n84=  _ text_time 10
n85=  _ nick_time 10
n86=  _ notices_time 10
n87=  _ joins_time 10
n88=  _ deop_time 15
n89=  _ kick_time 0
n90=  _ ban_time 0
n91=  _ kickonban on
n92=  _ longword off
n93=  _ capskick on
n94=  _ maxcaps 400
n95=  _ clonejoin on
n96=  _ maxclones 7
n97=  _ clonepenalty kban
n98=  _ maxlength 300
n99=  _ sreq off
n100=  _ autosend off
n101=  _ autojoin off
n102=  _ ctcpcloaking off
n103=  _ operview off
n104=  _ nethack 0
n105=  _ defchannum 45
n106=  _ nickregain off
n107=  _ wordkick off
n108=  _ defchanmodes tn
n109=  _ nickkick off
n110=  var %tmp = $readini -n $_mircini ident userid
n111=  .identd on $iif(%tmp,%tmp,bdc)
n112=  if (%split.jump) [ unset % $+ [ $ifmatch ] ]
n113=  unset %allowed.umodes %^* %_* %ibl.* %c.n %z.* %who.win %raw.whoresults %tmp %temp %max.* %ctcp.* %sound
n114=  unset %.* %#*.bots %luser.* %tmp.* %temp?.* %*.tmp %*.temp %*.temp? %=comchan.* %temp.* %who.head
n115=  unset %tmp %split.jump %nc.chan %dns.host %nc.nick %slag 6 %a %b %c %d %e %f %g %h %i %j %k %l %m %n %o %p %q %r %s %t %u %v %w %x %y %z %send2ip.*
n116=  flushini sys\main.ini
n117=}
n118=setawaytime _set awaysettings autosecs $mult($1,60) | _set AwaySettings automins $1
n119=setdisplay if ($1 == IBMPC) display -h 14 IBMPC | elseif ($1 == Courier) display -l 12 Courier New | else display $iif($1 == Fixedsys,-l,-h) 9 $1-
n120=setpager {
n121=  var %pgs = $dir="Select a sound file to be used for pager" $wavedir*.wav;*.mid
n122=  if (%pgs) { _set awaysettings pagersound %pgs | did -o settings 36 1 %pgs }
n123=  dialog -v settings
n124=}
n125=setup if ($dialog(settings) == $null) dialog -m settings settings
n126=showhide {
n127=  var %n = settings
n128=  did $iif($1 == 1,-v,-h) %n 145,251,179
n129=  did $iif($1 == 9,-v,-h) %n 146
n130=  mdid2 $iif($1 == 1,-v,-h) %n 4 18
n131=  mdid2 $iif($1 == 2,-v,-h) %n 19 23
n132=  mdid2 $iif($1 == 3,-v,-h) %n 24 37
n133=  mdid2 $iif($1 == 4,-v,-h) %n 38 43
n134=  mdid2 $iif($1 == 5,-v,-h) %n 44 56
n135=  mdid2 $iif($1 == 6,-v,-h) %n 107 120
n136=  mdid2 $iif($1 == 6,-v,-h) %n 152 175
n137=  mdid2 $iif($1 == 7,-v,-h) %n 121 131
n138=  mdid2 $iif($1 == 8,-v,-h) %n 147 151
n139=  mdid2 $iif($1 == 9,-v,-h) %n 132 144
n140=  mdid2 $iif($1 == 9,-v,-h) %n 176 178
n141=  _set main lastset $1
n142=}
n143=showlast {
n144=  var %n = mdid2 -v settings , %g = goto 10
n145=  goto $1
n146=  :1 | %n 4 18 | did -v settings 145,251,179 | %g
n147=  :2 | %n 19 23 | %g
n148=  :3 | %n 24 37 | %g
n149=  :4 | %n 38 43 | %g
n150=  :5 | %n 44 56 | %g
n151=  :6 | %n 107 120 | %n 152 175 | %g
n152=  :7 | %n 121 131 | %g
n153=  :8 | %n 147 151 | %g
n154=  :9 | %n 132 144 | did -v settings 146,176,177,178 | %g
n155=  :10 | _set main lastset $1
n156=  did -c settings 3 $1
n157=}
n158=_fnig .ignore - $+ $1u $+ $2 *
n159=_wc {
n160=  goto $1
n161=  :122 | return @Clones
n162=  :123 | return @DCC History
n163=  :124 | return @Ban Stats
n164=  :125 | return @Who Results for
n165=  :126 | return display
n166=  :127 | return settings
n167=  :128 | return cset
n168=  :129 | return userlist
n169=  :130 | return lists
n170=  :131 | return @DCC Status
n171=}
n172=about {
n173=  var %w = @About
n174=  window -kp +ft %w $mwin(300,300) 300 300
n175=  titlebar %w Basic
n176=  drawrect -f %w 0 0 0 0 300 300
n177=  bd -h %w 175 240 100 22 Close
n178=  drawrect -n @About 15 5 100 95 43 43
n179=  drawrect -nr %w $rgb(0,128,255) 10 20 20 100 100
n180=  drawrect -nr %w $rgb(180,222,226) 9 130 40 50 50
n181=  drawtext -no %w 2 Arial 100 50 20 b
n182=  drawtext -nro %w $rgb(0,100,200) Arial 100 40 15 b
n183=  drawtext -no %w 1 "Arial Black" 64 140 10 B
n184=  drawtext -no %w 1 "Arial Black" 54 175 10 asic
n185=  drawtext -no %w 1 Arial 38 215 50 3.0
n186=  drawtext -no %w 1 Arial 22 140 95 for mIRC v $+ $version
n187=  drawtext -no %w 1 Arial 20 233 115 $bits $+ bit
n188=  drawrect -n %w 14 1 20 152 255 77
n189=  drawtext -n @About 1 "MS Sans Serif" 11 35 158 Current version: $basic.ver (Not for public release)
n190=  drawtext -n @About 1 "MS Sans Serif" 11 35 173 Release date: 29/9/99
n191=  drawtext -n %w 1 "MS Sans Serif" 11 35 195 Author: blue-elf
n192=  drawtext -n %w 1 "MS Sans Serif" 11 35 210 Email: belf@usa.net
n193=  drawtext -n @About 1 Arial 14 10 250 Copyright © 1998-1999 blue-elf
n194=  if ($_isfile(c:\WINDOWS\MEDIA\The Microsoft Sound.wav)) splay $ifmatch
n195=  drawdot %w 
n196=}
n197=;.timer@About -m 0 50 drawscroll @About 0 -2 20 153 257 76
n198=about² {
n199=  var %a = @about², %font = "Courier New" 15, %y = 0, %w = 0 | window -ph +fd %a $mwin(300,300) 0 0 %a | window -ar %a
n200=  :y | if (%y <= 300) { window %a $mwin(300,300) %w %y | inc %y | inc %w | goto y } | drawrect -f %a 1 0 0 0 300 300 | window -c @About
n201=  var %g = by blue-elf, %h = 10 | :h | inc %h 5
n202=  if (%h <= 155) { .timer.about. $+ %h -m 1 $calc(%h * 40) if ( $!window( %a ) ) drawtext -r %a $rgb(%h,%h,%h) %font 195 180 %g | goto h }
n203=  var %i = 0
n204=  :loop
n205=  inc %i
n206=  if (%i <= 300) {
n207=    var %t = $r(a,z) $r(a,z) $r(a,z) $r(a,z) $r(a,z)
n208=    drawtext -o %a 9 "Courier New" 50 30 97 %t
n209=    drawtext -o %a 1 "Courier New" 50 30 97 %t
n210=    goto loop
n211=  }
n212=  drawtext -o %a 9 "Courier New" 50 30 97 b a s i c
n213=  var %Text = $about.text, %Index = 10
n214=  :Write
n215=  inc %Index 5
n216=  if (%Index <= 155) {
n217=    [ .timer@write $+ [ %Index ] ] -m 1 $mult(%Index,55) if ( $!window( %a ) ) drawtext -r %a $rgb(%Index,%Index,%Index) %font 32 155 %Text $chr(124) else .timer@write* off
n218=    goto Write
n219=  }
n220=  drawrect %a 14 1 270 3 20 20
n221=  drawtext %a 14 Marlett 16 273 6 r
n222=}
n223=about.close .timer@write* off | .timer.about.* off
n224=about.text {
n225=  if (%about.text !isnum 1-4) %about.text = 0
n226=  inc %about.text
n227=  if (%about.text > 4) %about.text = 1
n228=  goto %about.text
n229=  :1 | return crafted to perfection...
n230=  :2 | return digitally remastered...
n231=  :3 | return now with lame graphics...
n232=  :4 | return SFX courtesy of ILM
n233=}
n234=;EOF
[script]
n0=on *:dialog:settings:init:*:{
n1=  mdid² -h $dname 4 89
n2=  mdid² -h $dname 107 235
n3=  mdid² -h $dname 90 102
n4=  did -h $dname 251,238
n5=  var %da = did -a $dname
n6=  didtok $dname 3 46 General.DCC Options.Away Settings.File Locations.Channel Modes.Personal.Floodnet.Windows.Sounds.Titlebar.Nick Completion.Extras
n7=  var %d = did -c $dname
n8=  if ($i(main,autocycle)) %d 235
n9=  if ($i(main,nickhilight)) %d 234
n10=  if ($i(main,recall_last_server)) %d 233
n11=  if ($i(main,IALmax)) %da 178 $ifmatch
n12=  if ($i(main,dnwindow)) %d 179
n13=  if ($i(ctcps,rejectkick) == on) did -c $dname 251
n14=  if ($i(main,ctcpcloaking) == on) %d 4
n15=  if ($i(main,nickregain) == on) %d 5
n16=  if ($i(main,autosend) == on) %d 6
n17=  if ($i(main,nethack)) %d 7
n18=  if ($i(main,operview) == on) %d 8
n19=  if ($i(main,sreq) == on) %d 9
n20=  if ($i(sounds,toggle) == on) { %d 147 | did -e $dname 149,150,151 }
n21=  if ($i(ctcps,ctcp_abuse) == on) %d 145
n22=  if ($istok($i(windows,autoclose),on_chat,32)) %d 11
n23=  if ($istok($i(windows,autoclose),on_quit,32)) %d 12
n24=  if ($istok($i(windows,autoclose),on_unotify,32)) %d 13
n25=  if ($i(main,shownames) == on) %d 15
n26=  if ($i(main,showsynch) == on) %d 16
n27=  if ($i(main,showtopic) == on) %d 17
n28=  if ($i(main,showstats) == on) %d 18
n29=  var %a = $i(ctcps,adcc)
n30=  if (Ignore isin %a) %d 20
n31=  elseif (%a == Strict) %d 21
n32=  elseif (%a == Moderate) %d 22
n33=  elseif (%a == Lenient) %d 23
n34=  did $`($i(awaysettings,autoaway)) $dname 25
n35=  did $`($i(awaysettings,pager)) $dname 28
n36=  did $iif($i(awaysettings,method) == verbose,-c,-u) $dname 32
n37=  did $`($i(awaysettings,logging)) $dname 29
n38=  did $iif($i(awaysettings,method) != verbose,-c,-u) $dname 31
n39=  did $iif($i(awaysettings,method) == verbose,-c,-u) $dname 32
n40=  if ($i(awaysettings,awaylogwin)) did -c $dname 231
n41=  if ($i(awaysettings,antiidle)) did -c $dname 232
n42=  if ($_isfile($i(awaysettings,pagersound))) did -o $dname 36 1 $ifmatch
n43=  if ($i(awaysettings,autosecs) isnum) %da 26 $calc($ifmatch / 60)
n44=  else { _set awaysettings autosecs 600 | _set awaysettings automins 10 | %da 26 $i(awaysettings,automins) }
n45=  if ($i(awaysettings,defaultmsg)) %da 34 $ifmatch
n46=  if ($_isfile($i(apps,mp3player))) did -o $dname 41 1 $shortfn($remove($ifmatch,"))
n47=  if ($_isdir($mp3dir)) did -o $dname 42 1 $shortfn($remove($ifmatch,"))
n48=  if ($_isfile($i(apps,picviewer))) did -o $dname 43 1 $shortfn($remove($ifmatch,"))
n49=  var %dfm = $i(main,defchanmodes), %dfa = psmintkl, %i = 1, %x = 45
n50=  while ($mid(%dfa,%i,1)) { did $iif($ifmatch isin %dfm,-c,-u) $dname %x | inc %x | inc %i }
n51=  if ($i(main,defchankey)) %da 55 $ifmatch
n52=  if ($i(main,defchannum)) %da 56 $ifmatch
n53=  if (k !isin $i(main,defchanmodes)) did -b $dname 55
n54=  if (l !isin $i(main,defchanmodes)) did -b $dname 56
n55=  did $`($i(main,botnet_public)) $dname 108
n56=  did $`($i(main,botnet_notice)) $dname 109
n57=  did $`($i(main,botnet_nick)) $dname 110
n58=  did $`($i(main,botnet_join)) $dname 111
n59=  did $`($i(main,botnet_ctcp)) $dname 152
n60=  did $`($i(main,botnet_invite)) $dname 153
n61=  if ($i(main,maxbotpublic) isnum) %da 112 $ifmatch
n62=  if ($i(main,maxbotnotice) isnum) %da 113 $ifmatch
n63=  if ($i(main,maxbotnick) isnum) %da 114 $ifmatch
n64=  if ($i(main,maxbotjoin) isnum) %da 115 $ifmatch
n65=  if ($i(main,maxbotctcp) isnum) %da 154 $ifmatch
n66=  if ($i(main,maxbotinvite) isnum) %da 155 $ifmatch
n67=  if ($i(main,public.botnetignoretime) isnum) %da 164 $ifmatch
n68=  if ($i(main,notice.botnetignoretime) isnum) %da 165 $ifmatch
n69=  if ($i(main,nick.botnetignoretime) isnum) %da 166 $ifmatch
n70=  if ($i(main,join.botnetignoretime) isnum) %da 167 $ifmatch
n71=  if ($i(main,ctcp.botnetignoretime) isnum) %da 168 $ifmatch
n72=  if ($i(main,invite.botnetignoretime) isnum) %da 169 $ifmatch
n73=  var %x = 122 | while (%x <= 131) { if ($istok($i(windows,desktop),$_wc(%x),44)) did -c $dname %x | inc %x }
n74=  did -c $dname $iif($i(ctcps,incoming) == status,138,137)
n75=  if ($i(ctcps,outgoing) == silent) did -c $dname 135
n76=  elseif ($i(ctcps,outgoing) == active) did -c $dname 133
n77=  elseif ($i(ctcps,outgoing) == status) did -c $dname 134
n78=  if (($i(ctcps,ignore_time) isnum) && ($i(ctcps,ignore_time) >= 0)) did -a $dname 140 $ifmatch
n79=  if ($i(main,permnick)) did -a $dname 143 $ifmatch
n80=  var %m = 0 | while (%m <= 9) { %da 146 $mask(blue-elf!bdc@tm.net.my,%m) | inc %m }
n81=  if ($i(ctcps,ignore_type) !isnum 0-9) _set ctcps ignore_type 3
n82=  did -c $dname 146 $add($i(ctcps,ignore_type),1)
n83=  didtok $dname 149 32 Startup Connect Join Part Nick Quit Kick Op Deop Voice Devoice
n84=  _eventsound.init | _nc.init $dname
n85=  did -c $dname 149 1 | if ($i(sounds,startup)) did -o $dname 150 1 $shortfn($ifmatch) | _pp.init | tbar.init
n86=  showlast $iif($i(main,lastset) isnum 1-12,$i(main,lastset),1)
n87=}
n88=alias -l ` return $iif($1 == on,-c,-u)
n89=alias -l - return $iif($1 == on,-u,-c)
n90=alias -l _ return $iif($1 == on,off,on)
n91=alias -l ^ {
n92=  var %i = $i(windows,autoclose)
n93=  var %n = $sub($numtok(%i,32),1)
n94=  if ($istok(%i,$1,32)) { if (%n) _set windows autoclose $remtok(%i,$1,32) | else _unset windows autoclose }
n95=  else _set windows autoclose $addtok(%i,$1,32)
n96=  did $iif($istok(%i,$1,32),-u,-c) settings $2 | halt
n97=}
n98=alias -l edit if (($_n($1)) && ($did(settings,$1) isnum) && ($did(settings,$1) >= 0)) .timer.did 1 0 _set main $_n($1) $did(settings,$1)
n99=on *:dialog:settings:edit:26:if ($did(26) isnum) .timer.did 1 0 setawaytime $did(26)
n100=on *:dialog:settings:edit:34:if ($did(34)) .timer.did 1 0 _set awaysettings defaultmsg $ifmatch | else .timer.did 1 0 _unset awaysettings defaultmsg
n101=on *:dialog:settings:edit:55:if ($did(55) != $null) .timer.did 1 0 _set main defchankey $did(55) | else .timer.did 1 0 _unset main defchankey
n102=on *:dialog:settings:edit:56:if ($did(56) isnum) .timer.did 1 0 _set main defchannum $did(56) | else .timer.did 1 0 _unset main defchannum
n103=on *:dialog:settings:edit:140:if (($did(140) isnum) && ($did(140) >= 0)) .timer.did 1 0 _set ctcps ignore_time $did(140) | else .timer.did 1 0 _set ctcps ignore_time 60
n104=on *:dialog:settings:edit:143:if ($did(143)) .timer.did 1 0 _set main permnick $ifmatch
n105=on *:dialog:settings:edit:*:edit $did
n106=on *:dialog:settings:sclick:*:{
n107=  var %d = $did, %p = _set main
n108=  if (%d == 250) { if ($did(3,$did(3).sel)) help $replace($ifmatch,$chr(32),_) }
n109=  if (%d == 3) showhide $did(3).sel
n110=  if (%d == 4) %p ctcpcloaking $iif($did(4).state,on,off)
n111=  if (%d == 5) %p nickregain $iif($did(5).state,on,off)
n112=  if (%d == 6) %p autosend $iif($did(6).state,on,off)
n113=  if (%d == 7) %p nethack $did(7).state
n114=  if (%d == 8) %p operview $iif($did(8).state,on,off)
n115=  if (%d == 9) %p sreq $iif($did(9).state,on,off)
n116=  if (%d == 145) _set ctcps ctcp_abuse $iif($did(%d).state,on,off)
n117=  if (%d == 15) %p shownames $iif($did(15).state,on,off)
n118=  if (%d == 16) %p showsynch $iif($did(16).state,on,off)
n119=  if (%d == 17) %p showtopic $iif($did(17).state,on,off)
n120=  if (%d == 18) %p showstats $iif($did(18).state,on,off)
n121=  if (%d == 11) ^ on_chat 11
n122=  if (%d == 12) ^ on_quit 12
n123=  if (%d == 13) ^ on_unotify 13
n124=  if (%d isnum 20-23) _set ctcps adcc $did(%d)
n125=  if (%d == 25) _set awaysettings autoaway $iif($did(%d).state,on,off)
n126=  if (%d == 28) { _set awaysettings pager $iif($did(%d).state,on,off) | $iif($i(awaysettings,pager) == on,.enable,.disable) #awaypager }
n127=  if (%d == 29) _set awaysettings logging $iif($did(%d).state,on,off)
n128=  if (%d == 31) _unset awaysettings method
n129=  if (%d == 32) _set awaysettings method verbose
n130=  if (%d == 37) {
n131=    if (%pager.preview == TRUE) { splay stop | unset %pager.preview }
n132=    elseif ($_isfile($i(awaysettings,pagersound))) { splay $ifmatch | set %pager.preview TRUE }
n133=  }
n134=  if (%d == 36) {
n135=    if ($_isfile($i(awaysettings,pagersound))) { _unset awaysettings pagersound | did -r $dname 36 }
n136=    else .timer 1 0 setpager
n137=  }
n138=  if ((%d isnum 41) || (%d == 43)) {
n139=    var %z = $iif(%d == 41,mp3player,picviewer)
n140=    if ($_isfile($i(apps,%z))) { _unset apps %z | did -r $dname %d }
n141=    else .timer 1 0 _setfileloc $iif(%d == 41,MP3 player,graphic viewer) %z $dname %d
n142=  }
n143=  if (%d == 42) {
n144=    if ($_isdir($mp3dir)) { _unset apps mp3path | did -r $dname 42 }
n145=    else .timer 1 0 _setfileloc² $dname
n146=  }
n147=  if (%d isnum 45-52) > $_m(%d) %d
n148=  if ((%d isnum 108-111) || (%d isnum 152-153)) _onoff %d
n149=  if (%d isnum 121-131) {
n150=    var %.desktop = $i(windows,desktop)
n151=    if ($did($did).state) _set windows desktop $addtok(%.desktop,$_wc($did),44)
n152=    else { if ($sub($numtok(%.desktop,44),1)) _set windows desktop $remtok(%.desktop,$_wc($did),44) | else _unset windows desktop }
n153=  }
n154=  if (%d isnum 133-135) if ($did(%d).state) _set ctcps outgoing $iif(%d == 133,active,$iif(%d == 134,status,silent))
n155=  if (%d isnum 137-138) _set ctcps incoming $iif(%d == 138,status,active)
n156=  if (%d == 146) _set ctcps ignore_type $sub($did(146).sel,1)
n157=  if (%d == 147) { _set sounds toggle $iif($did(147).state,on,off) | mdid² $iif($i(sounds,toggle) == on,-e,-b) $dname 149 151 }
n158=  if (%d == 149) { var %.sf = $i(sounds,$did(149,$did(149).sel)) | did -r $dname 150 | if ($_isfile(%.sf)) did -o $dname 150 1 $shortfn($remove($ifmatch,")) | else _unset sounds $did(149,$did(149).sel) }
n159=  if (%d == 150) { set -u %.sf $did(149,$did(149).sel) | if ($_isfile($i(sounds,%.sf))) { _unset sounds %.sf | did -r $dname 150 } | else .timer -m 1 0 setsound %.sf }
n160=  if (%d == 151) if ($_isfile($did(150))) splay $ifmatch
n161=  if (%d == 251) _set ctcps rejectkick $iif($did(%d).state,on,off)
n162=  if (%d == 179) %p dnwindow $did(%d).state
n163=  if (%d == 88) { if ($_pp(file)) { _unset personal file | did -r settings 88 } | else .timer 1 0 setsound² }
n164=  if (%d == 89) if ($_pp(file)) splay $ifmatch
n165=  if (%d == 231) _set awaysettings awaylogwin $did(%d).state
n166=  if (%d == 232) _set awaysettings antiidle $did(%d).state
n167=  if (%d == 234) _set main nickhilight $did(%d).state
n168=  if (%d == 238) .timer -m 1 1 dialog -m mp3showinfo mp3showinfo
n169=  if (%d == 1) {
n170=    _set main recall_last_server $did(233).state | .ov $iif($did(8).state,on,off)
n171=    _ppgrab | _eventsound.grab | _nc.grab $dname | tbar.grab | _set main autocycle $did(235).state
n172=    .timer 1 0 .unload -rs $script(dialog.ini)
n173=  }
n174=  _eventsound.sclick %d | _nc.click $dname %d
n175=}
n176=alias -l _setfileloc {
n177=  set %tmp $dir="Select [ $1-2 ] " \*.exe
n178=  if (%tmp) { _set apps $3 %tmp | did -o $4-5 1 $shortfn(%tmp) }
n179=  dialog -v $4
n180=}
n181=alias -l _setfileloc² {
n182=  set %tmp $sdir="Select directory for MP3 files" \*.exe
n183=  if (%tmp) { _set apps mp3path %tmp | did -o $1 42 1 $shortfn(%tmp) }
n184=  dialog -v $1
n185=}
n186=alias -l setsound {
n187=  var %s = $dir="Select wav or mid file for $1 event" [ [ [ $wavedir ] $+ ] *.wav;*.mid ]
n188=  if (%s) { _set sounds $1 %s | did -o settings 150 1 $shortfn(%s) }
n189=  dialog -v settings
n190=}
n191=alias -l _m { return $replace($1,45,p,46,s,47,m,48,i,49,n,50,t,51,k,52,l) }
n192=alias -l _onoff { _set main $_btnet($1) $iif($did(settings,$1).state,on,off) }
n193=alias -l _btnet { return botnet_ [ $+ [ $replace($1,108,public,109,notice,110,nick,111,join,152,ctcp,153,invite) ] ] }
n194=alias -l > {
n195=  if ($did(settings,$2).state) {
n196=    if ($1 !isin $i(main,defchanmodes)) _set main defchanmodes $i(main,defchanmodes) $+ $1
n197=    if ($1 isin kl) did -e settings $iif($1 == k,55,56)
n198=  }
n199=  else {
n200=    if ($remove($i(main,defchanmodes),$1,+)) _set main defchanmodes $ifmatch
n201=    else _unset main defchanmodes
n202=    if ($1 isin kl) did -b settings $iif($1 == k,55,56)
n203=  }
n204=}
n205=alias dialog.check {
n206=  if ($script(dialog.ini) == $null) {
n207=    if ($_isfile(sys\dialog.ini)) .load -rs $ifmatch
n208=    else {
n209=      s.err Unable to load dialog.ini. Please reinstall Basic.
n210=      halt
n211=    }
n212=  }
n213=}
n214=alias -l font_check {
n215=  var %f1 = $readini $_mircini fonts fchannel, %f2 = $readini $_mircini fonts fquery, %f3 = $readini $_mircini fonts fmessage, %f4 = $readini $_mircini fonts fdccs, %f5 = $readini $_mircini fonts fdccg, %f6 = $readini $_mircini fonts fnotify
n216=  return $iif((%f1 == $1-) && (%f2 == $1-) && (%f3 == $1-) && (%f4 == $1-) && (%f5 == $1-) && (%f6 == $1-),$true,$false)
n217=}
n218=alias display {
n219=  if ($1 == $null) { disp | return }
n220=  if ($istok(-l -h,$remove($1,b),32)) {
n221=    %_f = $iif($2-,$2-,$iif($remove($1,b) == -h,Terminal,Courier New))
n222=    font $iif(b isin $1,-sb,-s) %_f
n223=    window -h @.font
n224=    %.fsize = , $+ $calc( [ $iif($window(@.font).fontbold,700,400) ] + [ $window(@.font).fontsize ] )
n225=    close -@ @.font
n226=    %ffinal = $iif($2 isnum,$3-,%_f) $+ %.fsize
n227=    var %write = $font_check(%ffinal)
n228=    var %Chan.Num = $chan(0), %Query.Num = $query(0), %Chat.Num = $chat(0)
n229=    if (%Chan.Num) {
n230=      while (%Chan.Num) {
n231=        font $iif(b isin $1,-b) $chan(%Chan.Num) %_f
n232=        dec %Chan.Num
n233=      }
n234=    }
n235=    else _remfonts
n236=    while (%Query.Num) {
n237=      font $iif(b isin $1,-b) $query(%Query.Num) %_f
n238=      dec %Query.Num
n239=    }
n240=    while (%Chat.Num) {
n241=      font $iif(b isin $1,-b) $chat(%Chat.Num) %_f
n242=      dec %Chat.Num
n243=    }
n244=    _set display ascii $iif($remove($1,b) == -h,high,low)
n245=    if ($gettok(%_f,1,32) isnum) { _set display fontsize $ifmatch | _set display font $gettok(%_f,2-,32) } | else _set display font %_f
n246=    %_f = $iif($2 isnum,$3-,%_f) $+ %.fsize
n247=    if (%write == $false) {
n248=      writeini $_mircini fonts fchannel %_f
n249=      writeini $_mircini fonts fquery %_f
n250=      writeini $_mircini fonts fmessage %_f
n251=      writeini $_mircini fonts fdccs %_f
n252=      writeini $_mircini fonts fdccg %_f
n253=      writeini $_mircini fonts fnotify %_f
n254=      saveini
n255=    }
n256=    unset %clone.siteban %ctrlf2 %_f %.fsize
n257=    if (($show) && (%write == $false)) {
n258=      iecho Now switched to $iif($remove($1,b) == -l,low,high) ascii mode.
n259=      iecho $fcom(/font+) $fkey(/font+) to make the fonts bigger. $fcom(/font-) $fkey(/font-) to make the fonts smaller.
n260=    }
n261=  }
n262=  else bhelp DISPLAY
n263=}
n264=alias drawbox drawrect -nf $1 0 1 $2- | drawline -n $1 1 1 $2 $3 $2 $calc($3 + $5) | drawline -n $1 1 1 $2 $3 $calc($2 + $4) $3 | drawline -nr $1 $rgb(face) 1 $2 $calc(($5 + $3) - 1) $calc(($4 + $2) - 1) $calc(($5 + $3) - 1) | drawline -nr $1 $rgb(face) 1 $calc(($4 + $2) - 1) $calc($3 + 1) $calc(($4 + $2) - 1) $calc(($5 + $3) - 1)
n265=;/drawcheckbox <window> x y <on|off>
n266=alias drawcheckbox {
n267=  drawrect -nf $1 0 1 $calc($2 + 2) $calc($3 + 2) 10 10
n268=  drawtext -nr $1 $rgb(shadow) "Marlett" 14 $calc($2 + 1) $calc($3 + 1) e
n269=  drawtext -n $1 1 "Marlett" 14 $2 $3 e
n270=  drawtext -n $1 0 "Marlett" 14 $calc($2 + 1) $calc($3 + 1) f
n271=  drawtext -nr $1 $rgb(face) "Marlett" 14 $2 $3 f
n272=  if ($4 == on) drawtext -n $1 1 Marlett 14 $2 $calc($3 + 2) a
n273=  if (($len($4)) && ($4 != on) && ($4 != off)) var %r = $4- | else var %r = $5-
n274=  if ($len(%r)) drawtext -rn $1 $rgb(text) "MS Sans Serif" 14 $add($2,17) $add($3,2) %r
n275=}
n276=alias setawaytime _set awaysettings autosecs $mult($1,60) | _set AwaySettings automins $1
n277=alias setdisplay if ($1 == IBMPC) display -h 14 IBMPC | elseif ($1 == Courier) display -l 12 Courier New | else display $iif($1 == Fixedsys,-l,-h) 9 $1-
n278=alias setpager var %pgs = $dir="Select a sound file to be used for pager" $wavedir*.wav;*.mid | if (%pgs) { _set awaysettings pagersound %pgs | did -o settings 36 1 %pgs } | dialog -v settings
n279=alias setup dialog.check | ncomp.cprev | if ($dialog(settings) == $null) dialog -m settings settings
n280=alias showhide {
n281=  var %n = settings
n282=  mdid² $iif($1 == 11,-v,-h) %n 191 230
n283=  did $iif($1 == 1,-v,-h) %n 4,145,251,179,233,234,235
n284=  did $iif($1 == 12,-v,-h) %n 146,5
n285=  did $iif($1 == 3,-v,-h) %n 231,232
n286=  mdid² $iif($1 == 1,-v,-h) %n 6 18
n287=  mdid² $iif($1 == 2,-v,-h) %n 19 23
n288=  mdid² $iif($1 == 3,-v,-h) %n 24 37
n289=  mdid² $iif($1 == 4,-v,-h) %n 38 43
n290=  mdid² $iif($1 == 5,-v,-h) %n 44 56
n291=  mdid² $iif($1 == 6,-v,-h) %n 57 89
n292=  mdid² $iif($1 == 7,-v,-h) %n 107 120
n293=  mdid² $iif($1 == 7,-v,-h) %n 152 175
n294=  mdid² $iif($1 == 8,-v,-h) %n 121 131
n295=  mdid² $iif($1 == 9,-v,-h) %n 147 151
n296=  mdid² $iif($1 == 9,-v,-h) %n 180 190
n297=  did $iif($1 == 9,-v,-h) %n 238
n298=  mdid² $iif($1 == 10,-v,-h) %n 90 102
n299=  mdid² $iif($1 == 12,-v,-h) %n 132 144
n300=  mdid² $iif($1 == 12,-v,-h) %n 176 178
n301=  _set main lastset $1
n302=}
n303=alias showlast {
n304=  var %n = mdid² -v settings, %g = goto 13
n305=  goto $1
n306=  :1 | %n 6 18 | did -v settings 145,251,179,4,233,234,235 | %g
n307=  :2 | %n 19 23 | %g
n308=  :3 | %n 24 37 | did -v settings 231,232 | %g
n309=  :4 | %n 38 43 | %g
n310=  :5 | %n 44 56 | %g
n311=  :6 | %n 57 89 | %g
n312=  :7 | %n 107 120 | %n 152 175 | %g
n313=  :8 | %n 121 131 | %g
n314=  :9 | %n 147 151 | %n 180 190 | did -v settings 238 | %g
n315=  :10 | %n 90 102 | %g
n316=  :12 | %n 132 144 | did -v settings 5,146,176,177,178 | %g
n317=  :11 | %n 191 230 | %g
n318=  :13 | _set main lastset $1
n319=  did -c settings 3 $1
n320=}
n321=; personal protection
n322=alias _ppgrab {
n323=  %_pp.ctcp = $_isnum²($did(settings,57)) $+ , $+ $_isnum²($did(settings,65)) $+ , $+ $_isnum²($did(settings,73))
n324=  %_pp.dccs = $_isnum²($did(settings,58)) $+ , $+ $_isnum²($did(settings,66)) $+ , $+ $_isnum²($did(settings,74))
n325=  %_pp.msgs = $_isnum²($did(settings,59)) $+ , $+ $_isnum²($did(settings,67)) $+ , $+ $_isnum²($did(settings,75))
n326=  %_pp.ntcs = $_isnum²($did(settings,60)) $+ , $+ $_isnum²($did(settings,68)) $+ , $+ $_isnum²($did(settings,76))
n327=  var %i = 1
n328=  while ($gettok(ctcp dccs msgs ntcs,%i,32)) {
n329=    _set personal $ifmatch %_pp. [ $+ [ $ifmatch ] ]
n330=    inc %i
n331=  }
n332=  var %_opt.final, %i = 82
n333=  while (%i <= 87) {
n334=    %_opt.final = %_opt.final $+ $did(settings,%i).state $+ $iif(%i != 87,$chr(44))
n335=    inc %i
n336=  }
n337=  _set personal optn %_opt.final
n338=}
n339=alias _pp return $i(personal,$1)
n340=alias -l setsound² if ($dir="Select a file" \*.wav;*.mid) { _set personal file $shortfn($ifmatch) | did -o settings 88 1 $_pp(file) } | dialog -v settings
n341=alias _pp² return $gettok($_pp(optn),$1,44)
n342=alias _pp.init {
n343=  var %x = 57, %i = 1
n344=  while ($gettok(ctcp dccs msgs ntcs,%i,32)) {
n345=    var %_opt = $_pp($ifmatch)
n346=    did -a $dname %x $_isnum²($gettok(%_opt,1,44))
n347=    did -a $dname $calc(%x + 8) $_isnum²($gettok(%_opt,2,44))
n348=    did -a $dname $calc(%x + 16) $_isnum²($gettok(%_opt,3,44))
n349=    inc %i
n350=    inc %x
n351=  }
n352=  var %i = 1
n353=  while (%i <= 7) {
n354=    if ($gettok($_pp(optn),%i,44)) did -c $dname $calc(%i + 81)
n355=    inc %i
n356=  }
n357=  if ($_pp(file)) did -a $dname 88 $ifmatch
n358=}
n359=; titlebar
n360=alias tbar.init {
n361=  var %ti = did -c settings, %i = 1, %d = 91
n362=  while ($gettok(date time nick umode server ustat astat slag,%i,32)) {
n363=    if ($i(titlebar,$ifmatch)) %ti %d
n364=    inc %i
n365=    inc %d
n366=  }
n367=  if ($i(titlebar,sec)) did -o $dname 101 1 $ifmatch
n368=  if ($i(titlebar,update)) did -c $dname 100
n369=}
n370=alias tbar.grab {
n371=  var %g = 91
n372=  while (%g <= 98) {
n373=    _set titlebar $replace(%g,91,date,92,time,93,nick,94,umode,95,server,96,ustat,97,astat,98,slag) $did(settings,%g).state
n374=    inc %g
n375=  }
n376=  if ($did(settings,101)) _set titlebar sec $ifmatch
n377=  _set titlebar update $did(settings,100).state
n378=  .timer 1 0 tbar.chk
n379=}
n380=; event sounds
n381=alias _eventsound.init {
n382=  if ($i(sounds,play.option) isnum 181-184) did -c settings $ifmatch
n383=  if ($i(sounds,autocomp)) did -c settings 190
n384=  if ($i(sounds,filetypes)) {
n385=    var %a = $ifmatch, %f = 1
n386=    while ($gettok(%a,%f,32)) { did -a settings 186 $ifmatch | inc %f }
n387=  }
n388=}
n389=alias _eventsound.grab {
n390=  _set sounds autocomp $did(settings,190).state
n391=  var %ID_Number = 181
n392=  while (%ID_Number <= 184) {
n393=    if ($did(settings,%ID_Number).state) _set sounds play.option %ID_Number
n394=    inc %ID_Number
n395=  }
n396=}
n397=alias _eventsound.sclick {
n398=  if ($1 == 187) _eventsound.edit
n399=  if ($1 == 188) { if ($did(settings,186,$did(settings,186).sel)) _eventsound.edit $ifmatch }
n400=  if ($1 == 189) {
n401=    if ($did(settings,186,$did(settings,186).sel)) {
n402=      var %rem = $ifmatch, %all = $i(sounds,filetypes)
n403=      if ($remtok(%all,%rem,32)) _set sounds filetypes $ifmatch
n404=      else _unset sounds filetypes
n405=      %.exe = player $+ %rem
n406=      %.dir = dir $+ %rem
n407=      if ($i(sounds,%.exe)) _unset sounds %.exe
n408=      if ($i(sounds,%.dir)) _unset sounds %.dir
n409=      did -d settings 186 $did(settings,186).sel
n410=    }
n411=  }
n412=}
n413=alias _eventsound.edit {
n414=  if ($1) {
n415=    %sfile.type = $1
n416=    %sfile.dir = $i(sounds,$bind(dir,$1))
n417=    %sfile.exe = $i(sounds,$bind(player,$1))
n418=  }
n419=  %name = SoundTypeEditor
n420=  .timer 1 0 dialog -m %name %name
n421=}
n422=alias _sset {
n423=  if ($1 == dir) {
n424=    set %tempdir $sdir="Select location of files" \
n425=    if (%tempdir) did -o SoundTypeEditor 7 1 $ifmatch
n426=  }
n427=  elseif ($1 == exe) {
n428=    set %tempexe $dir="Select player" \*.exe
n429=    if (%tempexe) did -o SoundTypeEditor 8 1 $ifmatch
n430=  }
n431=  dialog -v SoundTypeEditor
n432=}
n433=on *:dialog:SoundTypeEditor:init:*:{
n434=  if (%sfile.type) did -a $dname 6 $ifmatch
n435=  if (%sfile.dir) did -a $dname 7 $ifmatch
n436=  if (%sfile.exe) did -a $dname 8 $ifmatch
n437=  unset %sfile.*
n438=}
n439=on *:dialog:SoundTypeEditor:sclick:*:{
n440=  if ($dialog(settings) == $null) { dialog -x $dname | return }
n441=  if ($did == 9) .timer -m 1 0 _sset dir
n442=  if ($did == 10) .timer -m 1 0 _sset exe
n443=  if ($did == 1) {
n444=    if (.* iswm $did(6)) {
n445=      if (($did(7)) && ($did(8))) {
n446=        _set sounds filetypes $addtok($i(sounds,filetypes),$did(6),32)
n447=        _set sounds dir $+ $did(6) $did(7)
n448=        _set sounds player $+ $did(6) $did(8)
n449=        var %f = 0
n450=        :f
n451=        inc %f
n452=        if ($did(settings,186,%f)) {
n453=          if ($ifmatch == $did(6)) return
n454=          goto f
n455=        }
n456=        did -a settings 186 $did(6)
n457=      } 
n458=    }
n459=    unset %sfile.*
n460=    dialog -v settings
n461=  }
n462=  if ($did == 2) { unset %sfile.* | dialog -v settings }
n463=}
n464=dialog mp3showinfo {
n465=  title "MP3 Show Info"
n466=  option dbu
n467=  size -4 -4 150 80
n468=  box "Select info to show (from the left list):", 1, 5 5 140 55
n469=  list 2, 10 15 50 50
n470=  button ">> &Add", 3, 63 20 25 11
n471=  button "<< &Rem", 4, 63 33 25 11
n472=  list 5, 90 15 50 50
n473=  button "&OK", 6, 45 65 25 12, ok
n474=  button "&Cancel", 7, 75 65 25 12, cancel
n475=}
n476=on *:dialog:mp3showinfo:init:*:didtok $dname 2 32 size length KBPS KHZ mode | if ($i(sounds,mp3info)) didtok $dname 5 32 $ifmatch
n477=on *:dialog:mp3showinfo:sclick:3:{
n478=  if ($did(2,$did(2).sel)) {
n479=    %.tempinfo = $ifmatch
n480=    if ($didwm($dname,5,%.tempinfo,1) == 0) did -a $dname 5 %.tempinfo
n481=  }
n482=}
n483=on *:dialog:mp3showinfo:sclick:4:if ($did(5).sel) did -d $dname 5 $did(5).sel
n484=on *:dialog:mp3showinfo:sclick:6:{ var %s = 1, %final | while ($did(5,%s)) { %final = %final $ifmatch | inc %s } | _set sounds mp3info %final }
n485=; second instance support
n486=dialog runmirc {
n487=  size -3 -3 200 85
n488=  title "mIRC"
n489=  option dbu
n490=  button "OK", 1, 50 72 37 11, ok
n491=  button "Cancel", 2, 90 72 37 11, cancel
n492=  text "Nickname:", 3, 5 6 50 7, right
n493=  text "Alternative:", 4, 5 16 50 7, right
n494=  text "Server:", 5, 5 26 50 7, right
n495=  text "Port:", 6, 5 36 50 7, right
n496=  text "Password:", 7, 5 46 50 7, right
n497=  text "Channels:", 8, 5 56 50 7, right
n498=  combo     9, 56 5 98 50, autohs drop edit sort
n499=  combo    10, 56 15 98 50, autohs drop edit sort
n500=  combo    11, 56 25 98 150, autovs drop edit sort
n501=  combo    12, 56 35 98 150, autohs autovs drop edit
n502=  edit "" ,13, 56 45 98 11, autohs
n503=  edit "" ,14, 56 55 98 11, autohs
n504=  button "Help", 15, 130 72 37 11
n505=  button "List servers", 16, 158 25 37 11
n506=}
n507=on *:DIALOG:runmirc:init:*:{
n508=  didtok $dname 12 46 6667.6663.6664.6665.6666.7000.31337
n509=  var %n = $readini -n $_mircini mirc anick
n510=  did -a $dname 9 %n
n511=  if (%RecentNicks) { didtok $dname 9 32 $ifmatch | didtok $dname 10 32 $ifmatch }
n512=  did -a $dname 10 $mid(%n,1,8) $+ `
n513=  var %i = 1
n514=  while ($i(servers,%i)) {
n515=    did -a $dname 11 $ifmatch
n516=    inc %i
n517=  }
n518=  if ($didwm($dname,11,$i(servers,1))) did -c $dname 11 $ifmatch
n519=  did -c $dname 12 1
n520=}
n521=on *:DIALOG:runmirc:sclick:16:{
n522=  _progress Retrieving servers list
n523=  var %s = 0, %f = $readini -n $_mircini files servers
n524=  var %t = $lines(%f)
n525=  while ($readini -n %f servers n $+ [ %s ] ) {
n526=    did -a $dname 11 $gettok($wildtok($ifmatch,*.*,1,32),2,58)
n527=    _progress² %s %t
n528=    inc %s
n529=  }
n530=  _progress² %t %t
n531=}
n532=on *:DIALOG:runmirc:sclick:15:help Second_Instance
n533=on *:DIALOG:runmirc:sclick:1:{
n534=  unset %_switches
n535=  if ($did(9)) %_switches = -n $+ $ifmatch $+ , $+ $iif($did(10),$did(10))
n536=  if (($did(10)) && ($did(9) == $null)) %_switches = -n $+ $did(10)
n537=  if ($did(11)) %_switches = %_switches -s $+ $ifmatch $+ $iif($did(12), [ : $+ [ $did(12) ] ] )
n538=  if ($did(13)) %_switches = %_switches -p $+ $ifmatch
n539=  if ($did(14)) %_switches = %_switches -j $+ $ifmatch
n540=  run " $+ $mircexe $+ " %_switches
n541=}
n542=alias runmirc if (($bits != 32) && ($os < 95)) { s.err This feature is only for 32bit versions of mIRC. | halt } | dialog -m runmirc runmirc
n543=dialog inputbox {
n544=  title "Basic input request"
n545=  option dbu
n546=  size -3 -3 150 50
n547=  text %inputbox.text, 1, 5 5 100 30
n548=  button "&OK", 2, 110 3 35 12, ok
n549=  button "&Cancel", 3, 110 18 35 12, cancel
n550=  edit "", 4, 5 35 140 11, autohs result
n551=}
n552=alias InputBox {
n553=  %inputbox.name = $bind(inputbox,$r(1,100)) | %inputbox.text = $iif($1,$gettok($1-,1,34),Enter value:) | %inputbox.title = $gettok($1-,2,34)
n554=  return $dialog(%inputbox.name,inputbox,-3)
n555=}
n556=on *:dialog:*:init:*:{
n557=  if ($dname == %inputbox.name) {
n558=    did -nf $dname 4
n559=    if (%inputbox.title) dialog -t $dname $ifmatch
n560=    unset %inputbox.title
n561=  }
n562=  elseif ($dname == %confirm.name) {
n563=    did -ef $dname 3
n564=    if (%confirm.title) dialog -t $dname $ifmatch
n565=    unset %confirm.title
n566=  }
n567=}
n568=dialog confirm {
n569=  title "Basic input request"
n570=  option dbu
n571=  size -3 -3 150 50
n572=  text %confirm.text, 1, 25 5 100 30, center
n573=  button "&Yes", 2, 40 35 35 12, ok result
n574=  button "&No", 3, 78 35 35 12, cancel default
n575=}
n576=alias _cnfrm {
n577=  %confirm.name = $bind(confirm,$r(1,100)) | %confirm.text = $replace($gettok($1-,1,34),&crlf;,$crlf) | %confirm.title = $gettok($1-,2,34)
n578=  return $iif($dialog(%confirm.name,confirm,-3) == &Yes,$true,$false)
n579=}
n580=dialog entry {
n581=  title "Basic input request"
n582=  option dbu
n583=  size -3 -3 150 50
n584=  text %_entry, 1, 10 5 200 12
n585=  button "&OK", 2, 40 35 35 12, ok default
n586=  button "&Cancel", 3, 78 35 35 12, cancel
n587=  edit "", 4, 10 14 130 17, multi autovs result
n588=}
n589=alias _entry %_entry = $1- | return $dialog(entry,entry,-3)
n590=dialog s.err {
n591=  title "Error"
n592=  option dbu
n593=  size -3 -3 150 50
n594=  button "&Close", 1, 60 35 37 13, ok default
n595=  text %stext, 2, 15 5 120 30, center
n596=}
n597=alias s.err {
n598=  var %IntErrText = $gettok($1-,1,34), %IntErrTitle = $gettok($1-,2,34)
n599=  %stext = $iif(%IntErrText != $null,%IntErrText,Internal error encountered!)
n600=  dialog -m s.err s.err
n601=  if (%IntErrTitle) dialog -t s.err $ifmatch
n602=  unset %stext
n603=}
n604=;eof