Basic — File Browser
Basicv09272000 / Basicv09272000 / SYS / basic.ini
basic.ini — 41.35 KB — Download this file
[aliases]
n0=adcc {
n1= if (*!*@* isignore t) .ignore -rt *!*@*
n2= if ($address($1,5)) {
n3= var %find = $ifmatch , %i = 1
n4= while ($ignore(%i)) {
n5= var %mask = $ifmatch
n6= if (%mask isignore t) {
n7= if ((%mask == %find) || (%mask iswm %find)) .ignore -rt %mask
n8= }
n9= inc %i
n10= }
n11= }
n12= set -u300 $_var(adcc.,$1) 1
n13= if ($show) iecho $1 is now allowed to DCC you within 5 minutes.
n14=}
n15=aecho {
n16= echo -slti14 $$1 $2-
n17= var %a = 1
n18= while ($chan(%a)) {
n19= echo -lti14 $ifmatch $$1 $2-
n20= inc %a
n21= }
n22=}
n23=autoaway {
n24= if (($1 == $null) && ($i(awaysettings,automins))) {
n25= iecho Autoaway is currently : $upper($i(awaysettings,autoaway))
n26= iecho Auto away after : $i(awaysettings,automins) minute(s) Idle
n27= }
n28= elseif ($1 == on) {
n29= _set awaysettings autoaway on
n30= if ($i(awaysettings,automins) == $null) {
n31= _set awaysettings autosecs $iif($2 isnum,$mult($2,60),600)
n32= _set awaysettings automins $iif($2 isnum,$2,10)
n33= }
n34= if ($show) iecho Auto-away is ON, after $i(awaysettings,automins) minute(s) idle
n35= if ($server) .timer897 0 15 checkidle
n36= }
n37= elseif ($1 == off) {
n38= _set awaysettings autoaway off
n39= if ($show) iecho Autoaway is OFF
n40= .timer897 Off
n41= }
n42=}
n43=away {
n44= var %l = $i(awaysettings,logging), %p = $group(#awaypager)
n45= if ($format(away_switches,%l,%p)) var %_tmp.a = $ifmatch
n46= else var %_tmp.a = [l\ $+ $lower(%l) $+ ]] [p\ $+ $lower(%p) $+ ]]
n47= if (($away) && ($1)) {
n48= away $1- %_tmp.a
n49= set %afk.reason $1-
n50= }
n51= elseif ($away) back
n52= else {
n53= %awaysince = $ctime
n54= %awayppl = ""
n55= %awaytime = $ctime
n56= if ($1) %afk.reason = $1-
n57= else if ($i(awaysettings,defaultmsg)) %afk.reason = $ifmatch
n58= else %afk.reason = gone
n59= away %afk.reason %_tmp.a
n60= if (($i(awaysettings,method) == verbose) && (%silent_away != TRUE)) if ($chan(0)) ame is away: %afk.reason %_tmp.a
n61= if ($i(awaysettings,antiidle)) aidle
n62= }
n63=}
n64=back if ($away) !away | else iecho You are not away.
n65=_back {
n66= if (($numtok(%awayppl,32)) && ($_isfile($logdiraway.log))) iecho $_useless(%awayppl) messaged you while you were gone. $cs($fkey(/readlog)) to read msgs, $cs($fkey(/remlog)) to delete.
n67= if ($i(awaysettings,autoaway) == on) .timer897 0 15 checkidle
n68= var %gt = $remove($duration($calc($ctime - %awaytime)),ecs,ins,rs,r,ays,ay,ec,in,$chr(32))
n69= if ((($i(awaysettings,method) == verbose) && (%silent_away != TRUE)) && ($chan(0))) { if (%awaytime isnum) ame is back -- gone for %gt | else ame is back... }
n70= if (%awaytime isnum) iecho $1- $+ $c1 $+ ( $+ $c3 $+ gone: $+ $c3 %gt $+ $+ $c1 $+ ) | else iecho $1-
n71= unset %awaytime %awayppl %silent_away | .timer.anti.idle off | resetidle
n72=}
n73=bc iecho $1- = $calc( $1- )
n74=bracketcheck {
n75= if (%bracket.right == $null) %bracket.right = <
n76= if (%bracket.left == $null) %bracket.left = >
n77=}
n78=c clear $1-
n79=ca clearall
n80=jump {
n81= if (%split.jump == $null) iecho No split server available.
n82= elseif ($bits == 16) server %split.jump
n83= else {
n84= var %i = 1
n85= while ($chan(%i)) {
n86= set %split.chans $addtok(%split.chans,$ifmatch,44)
n87= inc %i
n88= }
n89= if (%split.chans) set -u %split.chans -j $+ %split.chans
n90= else unset %split.chans
n91= run -n $lfnfix($mircexe) -s $+ %split.jump %split.chans -n $+ $left($me,-1) $+ _
n92= }
n93=}
n94=wq {
n95= inc %cf5.Var
n96= if ((%cF5.Var > $query(0)) || (%cF5.Var < 0) || (%cF5.Var !isnum)) %cf5.Var = 1
n97= editbox -a /wii $query(%cF5.Var)
n98=}
n99=chat dcc chat $1-
n100=checkautoget {
n101= if ((!* iswm $2) && ($right($2,-1) == $me) && ($i(main,autosend) == on) && ($3)) {
n102= var %f, %file.1 = $replace($3-,?,_), %file.2 = $replace($3-,_,$chr(32)), %file.3 = $replace($3-,$chr(32),_)
n103= if ($_isfile( [ $wavedir $+ [ $3- ] ] )) var %f = $ifmatch
n104= elseif ($_isfile( [ $mididir $+ [ $3- ] ] )) var %f = $ifmatch
n105= elseif ($_isfile( [ $mp3dir $+ [ $3- ] ] ))) var %f = $ifmatch
n106= elseif ($_isfile( [ $wavedir $+ [ %file.1 ] ] )) var %f = $ifmatch
n107= elseif ($_isfile( [ $wavedir $+ [ %file.2 ] ] )) var %f = $ifmatch
n108= elseif ($_isfile( [ $wavedir $+ [ %file.3 ] ] )) var %f = $ifmatch
n109= elseif ($_isfile( [ $mididir $+ [ %file.1 ] ] )) var %f = $ifmatch
n110= elseif ($_isfile( [ $mididir $+ [ %file.2 ] ] )) var %f = $ifmatch
n111= elseif ($_isfile( [ $mididir $+ [ %file.3 ] ] )) var %f = $ifmatch
n112= elseif ($_isfile( [ $mp3dir $+ [ %file.1 ] ] )) var %f = $ifmatch
n113= elseif ($_isfile( [ $mp3dir $+ [ %file.2 ] ] )) var %f = $ifmatch
n114= elseif ($_isfile( [ $mp3dir $+ [ %file.3 ] ] )) var %f = $ifmatch
n115= if (%f) dcc send $1 %f | else .msg $1 I don't have that file ( $+ $3- $+ )
n116= halt
n117= }
n118=}
n119=checkidle if (($idle < $i(awaysettings,autosecs)) || ($away)) return | iecho $^k(Autoaway after [ $i(awaysettings,automins) ] minutes idle.) | away auto-dead after $i(awaysettings,automins) minutes | unset %awayppl | .timer897 off
n120=checkspam {
n121= if (($i(spam,toggle) != on) || ($level($_ulist($1)) > 30) || ($numtok($i(spam,words),32) == 0)) return
n122= var %nick = $gettok($1,1,33), %spam = $i(spam,words), %m = 1, %tmp, %ignore = 0
n123= while ($gettok(%spam,%m,32)) {
n124= if ($ifmatch isin $2-) { %ignore = 1 | break }
n125= inc %m
n126= }
n127= if (%ignore == 0) return
n128= .ignore [ -pu $+ [ $i(ctcps,ignore_time) ] ] $_mask($1,$i(ctcps,ignore_type))
n129= write sys\spam.txt < $+ %nick $+ > $strip($2-)
n130= iecho Possible spam from %nick 4[ $+ $gettok($1,2,33) $+ 4]
n131= haltdef | halt
n132=}
n133=cloak if ($istok(on off,$1,32)) { _set main ctcpcloaking $1 | iecho $bind(,$c3,CTCP) Cloaking is now $upper($i(main,ctcpcloaking)) } | else toggle main ctcpcloaking $bind(,$c3,CTCP) Cloaking
n134=cls clear
n135=cps2kb return $_bytes($1) $+ /s
n136=dcc {
n137= if (($1 == stats) || ($1 == $null)) dccstats
n138= elseif ($1 == history) dcc_hist
n139= elseif ($istok(send chat packetsize maxcps,$1,32)) !dcc $1-
n140= else iecho DCC: invalid parameters
n141=}
n142=dns {
n143= if (($1 == -h) && ($2)) { .dns -h $2 | %dns.host = $2 }
n144= elseif ($1 == -c) { dns -c | unset %dns.host }
n145= elseif (($server == $null) && (. !isin $$1)) { iecho Not connected to server | halt }
n146= else { %dns.host = $$1 | .dns $$1 }
n147= if ((%dns.host) && ($show)) iecho Looking up $^k(%dns.host)
n148=}
n149=dos run command.com
n150=drot echo $colour(action) -a [rot13] * $rot13($1-)
n151=echo {
n152= if ($format(echo)) !echo $1-
n153= elseif (-*i* iswm $1) {
n154= if (($me ison $2) || ($query($2)) || ($chat($2))) echo $1-
n155= else echo $_cv($1-)
n156= }
n157= else echo $_cv($1-)
n158=}
n159=readlog {
n160= var %file = " $+ $logdir $+ away.log"
n161= if ($_isfile(%file)) {
n162= var %wn = @Away Messages, %wp = $mwin(430,240) 430 240
n163= window -k +ftls %wn $winpos(%wn,%wp) @Awaymsgs $winfont(%wn)
n164= loadbuf -p %wn %file
n165= titlebar %wn Shift+F4 to delete.
n166= }
n167= else iecho There are no messages.
n168=}
n169=ji if ($server) join -i
n170=closeq close -m
n171=closeqr {
n172= var %i = 1, %logfiles
n173= while ($query(%i)) {
n174= var %log = " $+ $logdir $+ $replace($ifmatch,|,_,^,_,`,_,\,_) $+ _ $+ $date(yyyymmdd) $+ .log"
n175= if ($_isfile(%log)) %logfiles = $addtok(%logfiles,$ifmatch,124)
n176= .timer -m 1 0 close -m $query(%i)
n177= inc %i
n178= }
n179= var %i = 1
n180= while ($gettok(%logfiles,%i,124)) {
n181= .timer 1 0 .remove $ifmatch
n182= inc %i
n183= }
n184=}
n185=ia if ($active == $query($active)) ig $ifmatch
n186=closea {
n187= closeq
n188= .partall
n189= var %i = 1
n190= while ($chat(%i)) {
n191= var %nick = $ifmatch
n192= if ($istok(active waiting,$chat(%i).status,32) == $false) {
n193= close -c %nick
n194= dec %i
n195= }
n196= else inc %i
n197= }
n198=}
n199=getidle .enable #getidle | .raw WHOIS $1 $1
n200=groups {
n201= var %g = 1
n202= while ($group(%g)) {
n203= iecho In $align(15,$nopath($group(%g).fname)) : $align(15,$group(%g)) ( $+ $group(%g).status $+ )
n204= inc %g
n205= }
n206=}
n207=hd haltdef
n208=iecho echo $iif(@* iswm $active,-slti14,-alti14) $pre $1-
n209=lagcheck unset %slag | %_slag = $ctime | .raw SELF-LAG | .raw PONG $server $server
n210=mdid {
n211= var %t = $numtok($3-,32)
n212= while (%t) {
n213= did $1-2 $gettok($3-,%t,32)
n214= dec %t
n215= }
n216=}
n217=mrot .describe $active ß $+ $rot13($1-) | echo $colour(action) -a [rot13] * $me $1-
n218=ov {
n219= if ($1 == on) {
n220= if ($server) umod +cfgksw | if ($show) iecho Opervision is now $^k(ON) | _set main operview on
n221= if ($window(@Oper-View) == $null) { _set windows oview.dock off | window -k +flts @Oper-View $winpos(@Oper-View,0 0 300 200) @Oper-View }
n222= }
n223= elseif ($1 == off) { if ($server) umod -cfgksw | if ($show) iecho Opervision is now $^k(OFF) | _set main operview off | _set windows oview.dock off | close -@ @Oper-View }
n224= elseif ($1 == dock) ovdock
n225=}
n226=ping {
n227= var %targ = $iif($1,$1,$remove($active,=)), %i = 1
n228= ctcp %targ ping
n229= if (%targ ischan) {
n230= set %masspingchan $addtok(%masspingchan,%targ,44)
n231= set %masspingchantotal.2. [ $+ [ %targ ] ] 0
n232= set %masspingchantotal.1. [ $+ [ %targ ] ] $nick(%targ,0)
n233= set %masspingchanresult $+ %targ 0
n234= while ($nick(%targ,%i)) {
n235= set %massping $+ $ifmatch %targ
n236= inc %i
n237= }
n238= }
n239= else unset %massping [ $+ [ %targ ] ]
n240=}
n241=pingout {
n242= var %g = $rand(1,5)
n243= if (%g == 1) quit Ping timeout
n244= elseif (%g == 2) quit Read error 131 (Connection reset by peer)
n245= elseif (%g == 3) quit Broken pipe
n246= elseif (%g == 4) quit Idle time limit exceeded
n247= else quit Operation timed out
n248=}
n249=pnop _cnops PING $ticks
n250=q query $1-
n251=query {
n252= if (($1 == -n) && ($2)) var %s = -n, %n = $2, %q = $3-
n253= elseif ($1) var %n = $1, %q = $2-, %s
n254= else { iecho /query: insufficient parameters | return }
n255= if (($server) && ($left(%q,1) != $null)) {
n256= if ($format(query_text2,$me,%n,%q)) var %_query = $ifmatch
n257= else {
n258= bracketcheck
n259= if (%nickalign == right) var %_query = $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $_align(10,$me) $+ $+ $c1 $+ %bracket.left $+ %q
n260= else var %_query = $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $align(10,$me) $+ $+ $c1 $+ %bracket.left $+ %q
n261= }
n262= .timer -m 1 1 echo -lti %n %_query
n263= .timer -m 1 0 .msg %n %q
n264= }
n265= set %showcomchan. $+ %n $true
n266= query $iif(%s,%s) %n
n267=}
n268=quit {
n269= if ($isid) halt
n270= if ($server) {
n271= if (($1- == $null) && ($i(messages,quits) == random)) {
n272= if ($_isfile(sys\quits.txt)) .raw QUIT : $+ $read sys\quits.txt
n273= elseif ( [ $readini -n $_mircini text quit ] ) .raw QUIT : $+ $ifmatch
n274= else .raw QUIT : $+ $me has no reason.
n275= }
n276= else .raw QUIT : $+ $1-
n277= }
n278= unset %hardquit %chan.*
n279= _ondisc
n280=}
n281=rawcon .raw PRIVMSG $me :DCC CHAT CHAT $longip($1) $2 $+
n282=remove {
n283= if ($1) set -u %dfile $1-
n284= else set -u %dfile $dir="Select a file to delete" \*.*
n285= if ($_isfile(%dfile)) {
n286= .remove %dfile
n287= if ($show) iecho Removed " $+ %dfile $+ "
n288= }
n289=}
n290=removetmp var %r = $findfile($mircdir,*.$$$,0,1,.remove $1-)
n291=repchar return $left($1,$calc($2 - 1)) $+ $3 $+ $right($1,$calc($len($1) - $2))
n292=rot {
n293= if ($1 == $null) {
n294= _set main rot $iif($i(main,rot) != on,on,off)
n295= iecho ROT13 encryption is $upper($i(main,rot))
n296= }
n297= else {
n298= .raw PRIVMSG $active :ß $+ $rot13($1-)
n299= echo $colour(action) [rot13] < $+ $me $+ > $1-
n300= }
n301=}
n302=rot13 {
n303= var %t = $replace($1-,$chr(32),$chr(1)), %a, %i = 1, %r
n304= var %l = $len(%t)
n305= while (%i <= %l) {
n306= var %r = $asc($mid(%t,%i,1))
n307= if ((%r isnum 97-109) || (%r isnum 65-77)) { var %a = $add(%r,13) | var %t = $repchar(%t,%i,$chr(%a)) | inc %i | continue }
n308= if ((%r isnum 110-122) || (%r isnum 78-90)) { var %a = $sub(%r,13) | var %t = $repchar(%t,%i,$chr(%a)) | inc %i | continue }
n309= inc %i
n310= }
n311= return $replace(%t,$chr(1),$chr(32))
n312=}
n313=send dcc send $1-
n314=send2ip if ($chat($1).ip) dcc send $chat($1).ip $2- | else { %send2ip.nick = $iif($query($1).address,$query($1).address,$1) | %send2ip.file = $2- | .dns $1 | iecho Attempting to send to $1 $+ 's IP. Please wait... }
n315=server if ($server) quit switching servers | server $$1-
n316=setcolors {
n317= var %c^array = background.action.ctcp.highlight text.info text.info2.invite.join.kick.mode.nick.normal.notice.notify.other.own.part.quit.topic.wallops.whois.editbox.editbox text.listbox.listbox text, %^c = 1
n318= while ($gettok(%c^array,%^c,46)) {
n319= colour $ifmatch $gettok($1-,%^c,44)
n320= inc %^c
n321= }
n322= saveini
n323=}
n324=vlrf {
n325= if ($_isfile(%LastRcvdFile)) {
n326= if ((*.exe iswm %LastRcvdFile) || (*.bat iswm %LastRcvdFile)) { if ($_cnfrm(WARNING: You are about to execute a program. Continue?)) run %LastRcvdFile }
n327= elseif ((*.wav iswm %LastRcvdFile) || (*.mid iswm %LastRcvdFile)) splay %LastRcvdFile
n328= elseif ((*.doc iswm %LastRcvdFile) || (*.zip iswm %LastRcvdFile)) run %LastRcvdFile
n329= elseif (((*.mp3 iswm %LastRcvdFile) || (*.mp2 iswm %LastRcvdFile)) && ($_isfile($i(apps,mp3player)))) run $i(apps,mp3player) %LastRcvdFile
n330= elseif ($istok(.txt .ini .log,$right(%LastRcvdFile,4),32)) notepad %LastRcvdFile
n331= elseif (($istok(.gif .bmp .jpg,$right(%LastRcvdFile,4),32)) && ($i(apps,picviewer))) run $i(apps,picviewer) %LastRcvdFile
n332= else {
n333= var %tmp_app = $dir="Select application to open $nopath(%LastRcvdFile) " \*.exe
n334= run $shortfn(%tmp_app) $shortfn(%LastRcvdFile)
n335= }
n336= }
n337= elseif (%LastRcvdFile) iecho $ifmatch does not exist anymore.
n338= else iecho No file to view.
n339=}
n340=remlog {
n341= var %f = " $+ $logdir $+ away.log"
n342= if ($_isfile(%f)) { .remove %f | window -c @Away Messages | iecho Away messages have been cleared. }
n343= else iecho The message logfile does not exist.
n344=}
n345=igall ignore -pntiu60 *!*@* | if ($query(0)) close -m | iecho Ignoring everything for 60 seconds
n346=tbar {
n347= if ($format(titlebar,$atime,$me,$usermode,$server,$_op($active),$_away,$slag(%slag),$_uptime)) titlebar $ifmatch
n348= else {
n349= unset %_tbar
n350= if ($i(titlebar,date)) %_tbar = [[ $+ $replace($adate,/,-) $+ ]]
n351= if ($i(titlebar,time)) %_tbar = %_tbar [[ $+ $atime $+ ]]
n352= if ($i(titlebar,nick)) %_tbar = %_tbar [[ $+ $me $+ ]]
n353= if ($i(titlebar,umode)) %_tbar = %_tbar [[ $+ $usermode $+ ]]
n354= if ($i(titlebar,server)) %_tbar = %_tbar [[ $+ $server $+ ]]
n355= if ($i(titlebar,ustat)) %_tbar = %_tbar [[ $+ $_op($active) $+ ]]
n356= if ($i(titlebar,astat)) %_tbar = %_tbar [Status: $_away $+ ]]
n357= if ($i(titlebar,slag)) %_tbar = %_tbar [Lag: $slag(%slag) $+ ]]
n358= if (%_tbar) titlebar %_tbar
n359= else .timer.tbar off
n360= }
n361=}
n362=tbar.chk if (($i(titlebar,update) != 1) && ($timer(.tbar))) { .timer.tbar off | titlebar - Basic $basic.ver for mIRC v $+ $version - } | else if ($server) { if ($i(titlebar,update)) { .timer.tbar 0 $iif($i(titlebar,sec),$i(titlebar,sec),10) tbar } }
n363=tbar.set {
n364= var %t = 1
n365= while ($gettok(date time nick umode server ustat astat slag update,%t,32)) {
n366= _set titlebar $ifmatch 1
n367= inc %t
n368= }
n369= _set titlebar sec 10
n370=}
n371=update.self-address _srn $1 | var %a = $readini -n $_mircini about fulladdress | writeini -n $_mircini about fulladdress $1 $+ ! $+ $gettok(%a,2-,33)
n372=uptime iecho Uptime: $_uptime
n373=ver if ($1) ctcp $1 version | elseif (($query($active)) || ($active ischan)) ctcp $active version | elseif ((=* iswm $active) && ($server)) ctcp $remove($active,=) version
n374=view {
n375= if ($_isfile($i(apps,picviewer)) == $null) { iecho You need to set a pic viewer | setup | return }
n376= if ($1) set -u %file $1- | else set -u %file $$dir="Select a file to view" \*.jpg;*.gif;*.bmp;*.tif
n377= if ($_isfile(%file)) run $i(apps,picviewer) %file | else iecho %file does not exist
n378=}
n379=vnop _cnops VERSION
n380=wi whois $iif($1,$1,$me)
n381=wii if ($1) .raw WHOIS $nc($1) $nc($1) | else whois $me
n382=xget .adcc $$1 | ctcp $$1 xdcc send #$$2
n383=xhelp ctcp $$1 xdcc help
n384=xlist ctcp $$1 xdcc list
n385=_cnops {
n386= if ($nopnick(#,0) == 0) { iecho There are no non-ops in # $+ . | halt }
n387= var %.sendctcp = $1-, %^i = 1, %.^tmp = $gettok(%.sendctcp,1,32)
n388= while ($nopnick(#,%^i)) {
n389= var %.pn = $ifmatch
n390= if (%.pn != $me) {
n391= set $_var(ctcp.nick.,%.pn) TRUE
n392= .timer -m 1 $mult(%^i,500) .raw PRIVMSG %.pn : $+ %.sendctcp $+
n393= }
n394= inc %^i
n395= }
n396= if ($format(ctcp,$bind(Non-Ops:,#),%.^tmp)) echo -alti14 $ifmatch
n397= else echo -alti14 -> $bind(,$c2,[,$c3,ctcp,$c2,$chr(40),,$c3,Non-Ops:,#,,$c2,$chr(41),],$c3) %.^tmp
n398=}
n399=_echo echo $iif(@* iswm $active,-slti14,-alti14) $1-
n400=_eventsound if ($i(sounds,toggle) == on) if ($_isfile($i(sounds,$1))) splay $ifmatch
n401=_fnig .ignore - $+ $1 $+ u $+ $2 *
n402=_iecho if ($left($active,1) isin @=) echo -lsti14 $x $1- | else echo -alti14 $x $1-
n403=_onconnect {
n404= if ($server == $null) return
n405= %on.connect = TRUE
n406= .raw USERHOST $me
n407= if ($i(main,autojoin) == on) joinall
n408= if ($i(main,operview) == on) mode $me +cfgksw
n409= ReArrange servers $server
n410= _set recent_ports $server $port
n411= .guser -a 60 $me 3
n412= resetidle
n413= if ($i(AwaySettings,autoaway) == on) .timer897 0 15 checkidle
n414= echo -s $pre Nick : $+ $^k $me
n415= echo -s $pre Ident: $+ $^k $readini -n $mircini ident userid
n416= if ($host) echo -s $pre Host : $+ $^k $host
n417= if ($ip) echo -s $pre IP $x(2) $+ : $+ $^k $ip
n418= .timer 0 30 lagcheck
n419= if ($i(titlebar,update)) .timer.tbar 0 $iif($i(titlebar,sec),$i(titlebar,sec),10) tbar
n420= .timer 1 10 .identd off
n421= .timer 1 10 set %hardquit 1
n422= _eventsound Connect
n423=}
n424=_rport return $i(recent_ports,$_recs($1))
n425=_run {
n426= unset %file
n427= if ($_isfile($1-)) %file = $ifmatch
n428= elseif ($_isfile($_sounddir($1-))) %file = $ifmatch
n429= elseif ($_isfile($_pathfile($1-))) %file = $ifmatch
n430= elseif ($_isfile($_mircdir($1-))) %file = $ifmatch
n431= if (%file == $null) { if ($show) iecho /run: file does not exist: $1- }
n432= else _run² %file
n433=}
n434=_run² {
n435= var %ext = $right($remove($1-,"),3)
n436= if ($istok(txt.ini.inf.log.mrc,%ext,46)) run $iif($lof($1-) >= 65000,wordpad.exe,notepad.exe) $1-
n437= elseif ($istok(mp3.mp2,%ext,46)) { if ($_isfile($i(apps,mp3player))) run $ifmatch $1- | else _run³ $1- }
n438= elseif ($istok(jpg.bmp.gif.tif.png,%ext,46)) { if ($_isfile($i(apps,picviewer))) run $ifmatch $1- | else _run³ $1- }
n439= elseif ($istok(wav.mid,%ext,46)) splay $1-
n440= elseif ($istok(bat.exe.com,%ext,46)) { if ($_cnfrm(WARNING: You are trying to open an executable, command or batch file that is potentially dangerous to the computer! Are you sure you want to proceed?)) run $1- }
n441= else _run³ $1-
n442=}
n443=_run³ run $dir="Select application or cancel to use associated program" \*.exe $1-
n444=_srn if ($istok(%RecentNicks,$1,32) == $false) %RecentNicks = $1 %RecentNicks | if ($numtok(%RecentNicks,32) > 9) %RecentNicks = $gettok(%RecentNicks,1-9,32)
n445=; eof
[script]
n0=on &^*:INVITE:#:{
n1= if ($halted) return | hd
n2= var %EchoWindow = echo $iif($_mopt(3,26),-alti14,-slti14)
n3= var %EchoWindow = echo $iif(@* iswm $active,-slti14,-alti14)
n4= if ($format(invite,$nick,$address,$chan)) %EchoWindow $ifmatch
n5= else %EchoWindow $pre $+ $c3 $+ $nick $+ $c1 $+ ( $+ $c3 $+ $replace($address,@,$bind(,$c4,@,$c3)) $+ $+ $c1 $+ ) invites you to $+ $c2 $chan $+ $c1 $+ ( $+ $c3 $+ F5 to join $+ $c1 $+ )
n6=}
n7=on *:RAWMODE:#:{
n8= var %m = $iif(*.* iswm $nick,ServerMode,Mode)
n9= if ($:event(#).mode == 2) halt
n10= var %w = -lti14 #
n11= var %s = $iif($:event(#).mode == 0,%w,-sli14)
n12= if ($format(mode,#,$nick,$1-)) echo %s $ifmatch
n13= else echo %s $pre $+ $c1 $+ %m ( $+ $nick $+ $+ $c1 $+ : $+ $c3 $+ # $1- $+ $+ $c1 $+ )
n14=}
n15=on @^*:SERVEROP:#:{
n16= hd | if ($istok(%§opch. [ $+ [ $opnick ] ] ,#,44)) return
n17= if (($i(main,nethack)) || ($i(#,nethack))) {
n18= set -u180 %ServerOps. [ $+ [ # ] ] $addtok(%ServerOps. [ $+ [ # ] ] ,$opnick,32)
n19= if ($servmod // $numtok(%ServerOps. [ $+ [ # ] ] ,32)) ServerOpProtect #
n20= else .timer.ServerOp. [ $+ [ # ] ] 1 0 ServerOpProtect #
n21= }
n22=}
n23=alias -l ServerOpProtect {
n24= .raw MODE $1 - $+ $servmod(o) %ServerOps. [ $+ [ $1 ] ]
n25= unset %ServerOps. [ $+ [ $1 ] ]
n26=}
n27=on ^*:SERVEROP:#:hd
n28=on ^*:BAN:#:hd | if (($banmask iswm $_fulladdress) && ($nick != $me)) echo -stil $pre $nick has banned you in # ( $+ $banmask $+ )
n29=on ^*:MODE:#:hd
n30=on ^*:DEOP:#:unset %§opch. [ $+ [ $opnick ] ] | hd
n31=on ^*:UNBAN:#:hd
n32=on ^*:VOICE:#:_eventsound Voice | hd
n33=on ^*:DEVOICE:#:_eventsound Devoice | hd
n34=on ^*:OP:#:set %§opch. $+ $opnick $addtok(%§opch. [ $+ [ $opnick ] ] ,$chan,44) | _eventsound Op | hd
n35=on ^*:SERVERMODE:#:hd
n36=on ^*:HELP:#:hd
n37=on ^*:DEHELP:#:hd
n38=on &^*:KICK:# {
n39= if ($halted) return | hd | _settext $1-
n40= if ($format(kick,$chan,$nick,$knick,%^1)) { var %tmp_k = $ifmatch | if ($knick == $me) echo -lsti14 %tmp_k | else echo -lti14 $chan %tmp_k }
n41= else if ($knick == $me) echo -slti14 $pre $+ $c1 $+ You were kicked from $+ $c3 $chan by $+ $c3 $nick $+ $c1 $+ ( $+ $c3 $+ %^1 $+ $+ $c1 $+ )
n42= else echo -lti14 $chan $pre $+ $c3 $+ $knick $+ $c1 $+ was kicked by $+ $c3 $nick $+ $c1 $+ ( $+ $c3 $+ %^1 $+ $+ $c1 $+ )
n43=}
n44=on &^*:USERMODE:{
n45= if ($halted) return | hd
n46= if ($format(usermode,$me,$1-)) _echo $ifmatch | else iecho Usermode changed to: $+ $c3 $1-
n47=}
n48=on &^*:SNOTICE:*:{
n49= if ($halted) return
n50= if ((*IP#?Mismatch:* iswm $1-) || (*host*running*version* iswm $1-) || (*If?you?are?having?problems?connecting?due* iswm $1-)) halt
n51= var %psn = $+ $c4 $+ $chr(91) $+ $gettok($nick,-1,46) $+ ] $+ $c3
n52= if (*is?now?operator* iswm $1-) var %snotice = New $iif($asc($mid($9,2,1)) == 79,global,local) IRC Op $4-5
n53= elseif (*K-Lined* iswm $1-) var %snotice = $8 is K:lined on $server
n54= elseif (*KILL?message* iswm $1-) var %snotice = $10 has killed $8 $13-
n55= elseif (*User*trying?to?become?a?server* iswm $1-) var %snotice = User $5 trying to become server $11-
n56= elseif (*rehashing?Server?config* iswm $1-) var %snotice = Rehash requested by $4
n57= else var %snotice = $iif($1 == ***,$2-,$1-), %psn = $+ $c4 $+ ! $+ $nick $+ ! $+ $c3
n58= if ($format(snotice,$nick,$1-)) var %snotice = $ifmatch | else var %snotice = %psn %snotice
n59= if ($window(@Oper-View)) { aline -hp @Oper-View %snotice | halt }
n60= if ((*look*up*hostname* iswm $1-) || (*checking?ident*) || (*got?ident?response*) || (*found*hostname* iswm $1-)) { echo -slti14 %snotice | halt }
n61= if (%connection.status == ACTIVE) echo -slti14 %snotice
n62= elseif ($_mopt(5,13)) echo $iif(((($query($active) == $null) && ($left($active,1) !isin =@) && ($active ischan)) || ($active == Status Window)),-alti14,-slti14) %snotice | else echo -slti14 %snotice
n63= halt
n64=}
n65=on &*:WALLOPS:*:{
n66= if ($halted) return | _settext $1-
n67= if ($format(wallops,$nick,%^1)) set -u %wall_temp $ifmatch | else set -u %wall_temp $+ $c4 $+ ! $+ $nick $+ ! %^1
n68= $iif($window(@Oper-View),aline -hp @Oper-View,_iecho) %wall_temp | halt
n69=}
n70=on &^*:NICK:{
n71= if ($:event(0).nick == 2) { haltdef | halt } | if ($halted) return | hd | _botnetfld² nick
n72= if ($chan(0)) {
n73= var %nick_format = $pre $+ $c3 $+ $nick $+ $c1 $+ is now known as $+ $c3 $+ $newnick
n74= if ($:event(0).nick == 0) {
n75= var %n_var = 1
n76= while ($comchan($newnick,%n_var)) {
n77= var %c_var = $ifmatch
n78= if ($format(nick,$nick,$newnick,%c_var)) echo -tli14 %c_var $ifmatch
n79= else echo -tli14 %c_var %nick_format
n80= inc %n_var
n81= }
n82= }
n83= else echo -slti14 %nick_format
n84= }
n85= else { if ($format(nick,$nick,$newnick)) echo -slti14 $ifmatch | else echo -slti14 $pre You are now known as $+ $c3 $+ $newnick }
n86=}
n87=on &^*:TOPIC:#:{
n88= if ($:event(#).topic == 2) { haltdef | halt } | if ($halted) return | hd | _settext $1-
n89= if ($format(topic,$chan,$nick,%^1)) var %topic_tmp = $ifmatch | else var %topic_tmp = $pre $+ $c3 $+ $nick $+ $c1 $+ changes topic to ' $+ $c3 $+ %^1 $+ $+ $c1 $+ '
n90= if ($:event(#).topic == 0) echo -lti14 $chan %topic_tmp
n91=}
n92=on &^*:NOTICE:*:*:{
n93= if ($halted) return | if ($_mopt(1,16) == 2) if ($_isfile( [ $readini -n $_mircini waves notice ] )) splay $ifmatch
n94= hd | var %n = 1, %n2 = $i(main,dnwindow) | _settext $1-
n95= if (($1 == DCC) && (*.*.*.* iswm $3) && ($4 == $null)) return
n96= if ($format(notice,$target,$nick,$address,%^1)) var %notice = $ifmatch
n97= elseif ($target ischan) var %notice = $+ $c5 $+ - $+ $nick $+ : $+ $target $+ - %^1
n98= else var %notice = $+ $c5 $+ - $+ $nick ( $+ $address $+ )- %^1
n99= if ($_mopt(5,13) == 0) { echo -slti14 %notice | return }
n100= if ($comchan($nick,0) == 0) { $iif(%n2,_send2nwin [ $nick ] ,_echo) %notice | return }
n101= while ($comchan($nick,%n)) {
n102= var %d = $ifmatch
n103= if (%n2) _send2nwin $nick %notice
n104= else echo -lti14 %d %notice
n105= inc %n
n106= }
n107=}
n108=on *:CLOSE:@Notices:savewinpos $target
n109=alias -l _send2nwin {
n110= if ($window(@Notices) == $null) {
n111= window -ke @Notices $winpos(@Notices) @Notices $winfont(@Notices)
n112= titlebar @Notices - $fcom(/mc) $fkey(/mc) to cycle through the nicks
n113= }
n114= if ($left($2,1) != $null) aline -hp @Notices $2-
n115= if (%NoticeLogging) write " $+ $logdir $+ notices.log" $timestamp $strip($2-)
n116= var %i = 1 | while (%dnwin. [ $+ [ %i ] ]) { inc %i | continue }
n117= set %dnwin. [ $+ [ %i ] ] $1 | set %dnwin.total %i | editbox -p @Notices /n $1
n118=}
n119=alias font- _resizefonts -
n120=alias font+ _resizefonts +
n121=alias mc {
n122= if ($active == @Notices) {
n123= if ((%dn.µ !isnum) || (%dn.µ < 0)) %dn.µ = 0
n124= elseif (%dn.µ isnum) { if (. isin %dn.µ) %dn.µ = $int(%dn.µ) }
n125= if (%dn.µ > %dnwin.total) %dn.µ = 0 | inc %dn.µ
n126= if (%dnwin. [ $+ [ %dn.µ ] ]) editbox -p $active /n $ifmatch
n127= }
n128= elseif (($gettok(%ctrlf2,1,32) == ial.upd) && ($left($gettok(%ctrlf2,2,32),1) isin &#)) {
n129= %.ial.chan = $gettok(%ctrlf2,2,32) | if ($me !ison %.ial.chan) return
n130= if ($__var(ial.upd.,%.ial.chan) == $true) || ($__var(ial.,%.ial.chan))) echo -lti14 %.ial.chan $pre Still updating IAL for %ial.chan $+ . Please wait.
n131= else { %ial.upd. [ $+ [ %ial.chan ] ] = $true | .raw WHO %.ial.chan | echo -lti14 %.ial.chan $pre Updating IAL for %.ial.chan ... }
n132= }
n133= elseif ((%clone.siteban) && ($active ischan) && ($me isop $active)) { fkb %clone.siteban | unset %clone.siteban }
n134=}
n135=menu @Notices {
n136= &Disable:_set main dnwindow 0 | close -@ $active
n137= &Logging
n138= .O&n $iif(%NoticeLogging == 1,+):%NoticeLogging = 1
n139= .O&ff $iif(%NoticeLogging != 1,+):unset %NoticeLogging
n140= &Save buffer
n141= .&to notices.log:savebuf $active " $+ $logdirnotices.log"
n142= .&Select file...:{
n143= set %N_FName $$dir="Select a file to save buffer to..." *.txt;*.log
n144= if ($_cnfrm(Overwrite [ %N_FName ] ?)) set %N_Command savebuf $active
n145= else set %N_Command savebuf -a $active
n146= %N_Command %N_FName | unset %N_Command %N_FName
n147= }
n148= .Specify &filename...:if ($inputbox(Specify a directory and filename to use.."Save log)) savebuf $active $ifmatch
n149= &Clear
n150= .&Window:clear
n151= .&Nick cache:unset %notice.nicks
n152= -
n153= &Minimize:window -n $active
n154= C&lose:close -@ $active
n155=}
n156=on *:CONNECT:unset %dnwin.* %ServerOps.*
n157=on &^*:TEXT:*:#:{
n158= if ($halted) return | hd | var %me = * $+ $me $+ * | _settext $1-
n159= if (($i(main,rot) == on) && (ß* iswm %^1)) %^1 = [rot13] $rot13(%^1)
n160= if ($format(channel_text,$chan,$nick,$address,%^1)) { echo -lti14 $chan $ifmatch | return }
n161= var %o = $+ $c2 $+ @, %v = $+ $c2 $+ +, %nick = $nick, %nick2 = $+ $c3 $+ $nick $+
n162= bracketcheck
n163= if (%prefix.modes == ON) {
n164= if ($nick isop #) var %nick = @ $+ $nick
n165= elseif ($nick isvo #) var %nick = + $+ $nick
n166= else var %nick = * $+ $nick
n167= }
n168= else var %nick = * $+ $nick
n169= if (%bracket.nickalign == ON) {
n170= if (%nickalign == right) {
n171= if ($left(%nick,1) isin @+) { %nick = $ifmatch $+ $_align(10,$remove(%nick,@)) | goto b }
n172= %nick = $replace($_align(11,%nick),*, ,@,%o,+,%v,$nick,%nick2) | goto c
n173= :b | %nick = $replace(%nick,*, ,@,%o,+,%v,$nick,%nick2) | :c
n174= }
n175= else var %nick = $replace($align(11,%nick),*, ,@,%o,+,%v,$nick,%nick2)
n176= }
n177= else %nick = $replace($remove(%nick,*),$nick,%nick2,@,%o,+,%v)
n178= if ($i(main,nickhilight)) {
n179= if (($wildtok($strip($1-),%me,1,32)) && ($chan != $active) && ($active ischan)) echo -alti14 $+ $c1 $+ %bracket.right $+ $+ $colour(highlight) $+ $nick $+ : $+ $chan $+ $+ $c1 $+ %bracket.left $+ %^1
n180= if (($wildtok($1-,%me,1,32)) && ($chan == $active)) {
n181= echo -lti14 $chan $+ $c1 $+ %bracket.right $+ $+ $colour(highlight) $+ %nick $+ $+ $c1 $+ %bracket.left $+ %^1
n182= return
n183= }
n184= }
n185= echo -lti14 $chan $+ $c1 $+ %bracket.right $+ $+ $c3 $+ %nick $+ $+ $c1 $+ %bracket.left $+ %^1
n186=}
n187=on &^*:ACTION:*:#:{
n188= if ($halted) return | hd | if ($me !ison #) halt | _settext $1-
n189= if ($format(channel_action,$chan,$nick,$address,%^1)) echo -lti14 $chan $ifmatch
n190= else echo -lti14 $chan $+ $c1 $+ $act.pre $+ $+ $c3 $nick $+ $+ $colour(action) %^1 | halt
n191=}
n192=alias -l showcomchan {
n193= if ( %showcomchan. [ $+ [ $1 ] ] ) return | set %showcomchan. $+ $1 $true | var %comchans = $_comchan($1) | var %msg = (in channels %comchans $+ )
n194= if (%comchans == $null) %msg = (no common channels found) | echo -lti14 $1 $pre Message from $+ $c1 $1 $+ %msg
n195=}
n196=on *:CLOSE:?:.timer 1 20 unset $_var(showcomchan.,$target)
n197=on &^*:TEXT:*:?:{
n198= if ($halted) return | hd | var %w = $iif(@* iswm $active,-slti14,-alti14), %default = $+ $c1 $+ [ $+ $c3 $+ $nick $+ $+ $c1 $+ ( $+ $c3 $+ $address $+ $+ $c1 $+ )] $repb($1-) | _settext $1-
n199= if ($_mopt(0,22)) { dqwindow show | if ($format(query_text1,$nick,$address,%^1)) echo -dlti14 $ifmatch | else echo -dlti14 %default }
n200= elseif (($_mopt(4,5)) && ($query($nick) == $null)) { if ($format(query_text1,$nick,$address,%^1)) echo %w $ifmatch | else echo %w %default }
n201= elseif ($query($nick)) {
n202= showcomchan $nick
n203= if ($format(query_text2,$nick,$address,%^1)) echo -lti14 $nick $ifmatch
n204= else {
n205= if (%bracket.nickalign == ON) {
n206= if (%nickalign == right) echo -lti14 $nick $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $_align(10,$nick) $+ $+ $c1 $+ %bracket.left $+ %^1
n207= else echo -lti14 $nick $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $align(10,$nick) $+ $+ $c1 $+ %bracket.left $+ %^1
n208= }
n209= else echo -lti14 $nick $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $nick $+ $+ $c1 $+ %bracket.left $+ %^1
n210= }
n211= }
n212=}
n213=on &^*:ACTION:*:?:{
n214= if ($halted) return | hd | var %w = $iif(@* iswm $active,-slti14,-alti14) | _settext $1-
n215= var %ap = $+ $c1 $+ $act.pre $+ $+ $c3
n216= if ($_mopt(0,22)) {
n217= dqwindow show
n218= if ($format(query_action1,$nick,$address,%^1)) echo -dlti14 $ifmatch
n219= else echo -dlti14 %ap $nick $+ $+ $c1 $+ \ $+ $c3 $+ $me $+ $+ $colour(action) %^1
n220= }
n221= elseif (($_mopt(4,5)) && ($query($nick) == $null)) {
n222= if ($format(query_action1,$nick,$address,%^1)) echo %w $ifmatch
n223= else echo %w %ap $nick $+ $+ $c1 $+ \ $+ $c3 $+ $me $+ $+ $colour(action) %^1
n224= }
n225= else {
n226= showcomchan $nick
n227= if ($format(query_action2,$nick,$address,%^1)) echo -lti14 $nick $ifmatch
n228= else echo -lti14 $nick %ap $nick $+ $+ $colour(action) %^1
n229= }
n230= halt
n231=}
n232=;0 = Channel 1 = Status 2 = Hide
n233=alias :event { var %c = $iif($1,$1,default), %p = $prop | var %r = $readini -n $_mircini events %c | if (%r == $null) var %r = $readini -n $_mircini events default | var %n = $findtok(join part quit mode topic ctcp nick,%p,32) | return $gettok(%r,%n,44) }
n234=on &^*:QUIT:{
n235= var %s = $:event(0).quit | if (%s == 2) { hd | halt } | if ($halted) return | hd
n236= unset %formatquitchan | var %q = 1, %quitmsg | _settext $1-
n237= if ($format(quit,$nick,$address,%^1)) %quitmsg = $ifmatch
n238= else {
n239= %quitmsg = $pre $+ $c1 $+ Quits $+ $c4 $+ : $+ $c3 $nick $+ $c4 $+ : %^1
n240= if ($_mopt(0,2)) %quitmsg = $pre $+ $c1 $+ Quits $+ $c4 $+ : $+ $c3 $nick $+ $c1 $+ ( $+ $c3 $+ $replace($address,@,$bind(,$c4,@,$c3)) $+ $+ $c1 $+ ) $+ $c4 $+ : %^1
n241= }
n242= if (%s == 1) { echo -slti14 %quitmsg | halt }
n243= if ($nick != $me) { while ($comchan($nick,%q)) { echo -lti14 $ifmatch %quitmsg | inc %q } }
n244= else { while ($chan(%q)) { echo -lti14 $ifmatch %quitmsg | inc %q } } | halt
n245=}
n246=on &^*:ERROR:*:{
n247= if ($halted) return | hd
n248= var %e = $iif((*.undernet.* iswm $6) && ($5 == by),$left($6-,-1),$left($right($5-,-1),-1))
n249= if ($format(quit,$me,%e)) echo $iif(@* iswm $active || $query($active),-s,-a) $format(quit,$me,%e)
n250= else echo -tsi14 $pre $+ $c1 $+ Error $+ $c4 $+ : $+ $c3 $me $+ $c4 $+ : $5-
n251=}
n252=on &^*:JOIN:#:{
n253= if ($:event(#).join == 2) { hd | halt } | if ($halted) return | hd | _botnetfld² join | _settext $1-
n254= var %EchoWindow = echo $iif($:event(#).join == 0,-lti14 [ # ] ,-slti14)
n255= if ($format(join,$chan,$nick,$address,%^1)) %EchoWindow $ifmatch
n256= else { %m = $+ $c1 $+ [ $+ %^1 $+ $+ $c1 $+ $chr(93) | if ((%^1 == ) || (%^1 == $null)) %m = | %EchoWindow $JoinPartDisplay(Join,$nick,$address,$chan,%m) }
n257=}
n258=on &^*:PART:#:{
n259= if ($:event(#).part == 2) { haltdef | halt } | if ($halted) return | hd | _settext $1-
n260= var %EchoWindow = $iif($:event(#).part == 0,echo -lti14 [ # ] ,echo -slti14)
n261= if ($format(part,$chan,$nick,$address,%^1)) %EchoWindow $ifmatch
n262= else {
n263= %m = $+ $c1 $+ [ $+ %^1 $+ $+ $c1 $+ $chr(93)
n264= if ((%^1 == ) || (%^1 == $null)) %m =
n265= %EchoWindow $JoinPartDisplay(Part,$nick,$address,$chan,%m)
n266= }
n267= _eventsound Part
n268=}
n269=on *:UNOTIFY:{
n270= var %x = 0, %temp, %a
n271= :x
n272= inc %x
n273= %a = $gettok(%notify,%x,32)
n274= if (%a == $null) return
n275= if ($gettok(%a,1,33) != $nick) goto x
n276= %temp = $gettok(%a,2,33)
n277= %notify = $remtok(%notify,%a,1,32)
n278= if ($format(unotify,$nick,%temp)) echo -si $ifmatch
n279= else iecho $+ $c1 $+ Unotify: $gettok(%a,1,33) $+ $c1 $+ ( $+ $c3 $+ $replace(%temp,@,$bind(,$c4,@,$c3)) $+ $+ $c1 $+ ) has quit IRC
n280= if (($query($nick)) && ($istok($i(windows,autoclose),on_unotify,32))) close -m $nick
n281=}
n282=on &*:INPUT:?:if ((/* !iswm $1) || ($ctrlenter)) { say $1- | halt }
n283=on &*:INPUT:*:if (=* iswm $active) { if ((/* !iswm $1) || ($ctrlenter)) { say $1- | halt } }
n284=on &^*:CHAT:*:{
n285= if ($halted) halt | hd
n286= if (ACTION isin $1) {
n287= _settext $repb($remove($2-,))
n288= if ($format(dcc_action_window,$nick,%^1)) echo -lti12 =$nick $ifmatch
n289= else echo -lti14 =$nick $+ $c1 $+ $act.pre $+ $+ $c3 $nick $+ $+ $colour(action) %^1
n290= }
n291= else {
n292= _settext $1-
n293= if ($format(dcc_text_window,$nick,%^1)) echo -lti14 =$nick $ifmatch
n294= else {
n295= if (%nickalign == right) echo -lti14 =$nick $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $_align(10,$nick) $+ $+ $c1 $+ %bracket.left $+ %^1
n296= else echo -lti14 =$nick $+ $c1 $+ %bracket.right $+ $+ $c3 $+ $+ $align(10,$nick) $+ $+ $c1 $+ %bracket.left $+ %^1
n297= }
n298= }
n299=}
n300=alias -l _settext %^1 = $repb($1-) | if ($left(%^1,1) == $null) %^1 =
n301=; extra popups
n302=menu status,channel {
n303= -
n304= $iif(($menu == channel) || ($mouse.key & 2),&Quit)
n305= .&Specify reason...:if ($inputbox(Enter reason"Quit)) quit $ifmatch
n306= .Quit && &part all channels:disconnect | pa
n307= .&Quit && exit mIRC:if ($_cnfrm(Really exit mIRC?"Exit mIRC)) { set %ExitQuit $true | quit }
n308= .&Pingout:pingout
n309= .&Normal
n310= ..&Select
n311= ...$_pn(0,$_qcrop(0)):quit %QuitMessage.0
n312= ...$_pn(1,$_qcrop(1)):quit %QuitMessage.1
n313= ...$_pn(2,$_qcrop(2)):quit %QuitMessage.2
n314= ...$_pn(3,$_qcrop(3)):quit %QuitMessage.3
n315= ...$_pn(4,$_qcrop(4)):quit %QuitMessage.4
n316= ...$_pn(5,$_qcrop(5)):quit %QuitMessage.5
n317= ...$_pn(6,$_qcrop(6)):quit %QuitMessage.6
n318= ...$_pn(7,$_qcrop(7)):quit %QuitMessage.7
n319= ...$_pn(8,$_qcrop(8)):quit %QuitMessage.8
n320= ...$_pn(9,$_qcrop(9)):quit %QuitMessage.9
n321= ...-
n322= ...&Random reason:quit $_quitmsg
n323= ..R&emove
n324= ...$_pn(0,$_qcrop(0)):rq 0
n325= ...$_pn(1,$_qcrop(1)):rq 1
n326= ...$_pn(2,$_qcrop(2)):rq 2
n327= ...$_pn(3,$_qcrop(3)):rq 3
n328= ...$_pn(4,$_qcrop(4)):rq 4
n329= ...$_pn(5,$_qcrop(5)):rq 5
n330= ...$_pn(6,$_qcrop(6)):rq 6
n331= ...$_pn(7,$_qcrop(7)):rq 7
n332= ...$_pn(8,$_qcrop(8)):rq 8
n333= ...$_pn(9,$_qcrop(9)):rq 9
n334= ...-
n335= ...&Clear list:if ($_cnfrm(Remove all custom quit messages?)) unset %QuitMessage.*
n336= ..&Add new...:{
n337= var %x = 0, %add = $false
n338= while (%x <= 9) {
n339= if ($__var(QuitMessage.,%x)) { inc %x | continue }
n340= else { var %add = $true | break }
n341= }
n342= if (%add == $true) { if ($inputbox(Enter quit message to add"Quit message)) set %QuitMessage. $+ %x $ifmatch }
n343= else iecho Quit messages are full.
n344= }
n345= .&Fake quit
n346= ..1. Ping timeout:quit Ping timeout
n347= ..2. Read error:quit Read error 131 (Connection reset by peer)
n348= ..3. Broken pipe:quit Broken pipe
n349= ..4. Idle time:quit Idle time limit exceeded
n350= ..5. Operation time out:quit Operation timed out
n351= .Fake &Undernet quit
n352= ..1. Reset by peer:quit Read error to $me $+ [ $+ $remove($address($me,2),*!*@) $+ ]: Connection reset by peer
n353= ..2. Operation timeout:quit Read error to $me $+ [ $+ $remove($address($me,2),*!*@) $+ ]: Operation timed out
n354= ..3. EOF from client:quit Read error to $me $+ [ $+ $remove($address($me,2),*!*@) $+ ]: EOF from client
n355= ..4. Write error:quit Write error to $me $+ [ $+ $remove($address($me,2),*!*@) $+ ], closing link
n356= ..5. Ping timeout:quit Ping timeout for $me $+ [ $+ $remove($address($me,2),*!*@) $+ ]
n357=}
n358=alias upt_upd {
n359= if ($dialog(s.err)) did -o s.err 2 1 System has been up for $str( ,300) $_uptime
n360= else .timer.uptd off
n361=}
n362=menu menubar {
n363= -
n364= &Extras
n365= .&Import
n366= ..&Autobot list...:import -a
n367= ..&Basic settings...:import -b
n368= ..&Notify list...:import -n
n369= ..&Userlist...:import -u
n370= .&Minimize mIRC
n371= ..$str(.,3) &to system tray:showmirc -t
n372= ..$str(.,3) &normal minimize:showmirc -n
n373= .&Windows
n374= ..$iif((($os >= 95) && ($bits == 32) && ($_isfile($windir(\winipcfg.exe)))),&IP Configuration...):run $windir(\winipcfg.exe)
n375= ..&Uptime info:{
n376= s.err System has been up for $str( ,300) $_uptime " Uptime Info
n377= .timer.uptd 0 1 upt_upd
n378= }
n379= .&Version check:vercheck
n380= .&Backup script files...:backup
n381= .-
n382= .$iif((($os >= 95) && ($bits == 32)),&Run instance...):runmirc
n383= .&Close instances
n384= ..&All including this:basic_exit -all
n385= ..All &except this:basic_exit -exempt
n386=}
n387=menu status {
n388= -
n389= &Help:help basic
n390=}
n391=alias _crop if ($len($1-) > 12) return $left($1-,12) $+ ... | return $1-
n392=alias _qcrop return $_crop( %QuitMessage. [ $+ [ $1 ] ] )
n393=alias rq {
n394= if ($1 isnum 0-9) {
n395= if (%QuitMessage. [ $+ [ $1 ] ]) {
n396= unset %QuitMessage. [ $+ [ $1 ] ]
n397= if (%QuitMessage. [ $+ [ $calc($1 + 1) ] ]) {
n398= var %b = $add($1,1)
n399= while (%b <= 9) {
n400= if (%QuitMessage. [ $+ [ %b ] ] ) {
n401= set %QuitMessage. [ $+ [ $calc(%b - 1) ] ] $ifmatch
n402= var %LastNum = %b
n403= }
n404= inc %b
n405= }
n406= unset %QuitMessage. [ $+ [ %LastNum ] ]
n407= }
n408= }
n409= }
n410=}
n411=; EOF