/ScriptServ

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Addon: mIRC Tweak
;Version: v1.00
;Author: Zmodem
;Files: mirctweak.mrc,readme.txt
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;Aliases
alias -l mtr return return
alias -l tok return $gettok($2-,$1,44)
alias -l pval writeini $mircini $1 $2 $3-
alias -l scrptdr return $shortfn($scriptdir)
alias -l gset return $readini($script,S,$1)
alias -l ptok return $puttok($1,$2,$3,44)
alias -l gval return $readini($mircini,$1,$2)
alias -l mecho echo -a  $+ $color(info) $+ *** $1-
alias -l mtwkchk $iif(!$dialog(mtweak),mtwkclose)
alias -l \n return $crlf $+ $chr(32) $chr(32) $chr(32)
alias -l mtwkabt $iif(!$dialog(mtwkabt),dialog -m mtwkabt mtwkabt)
alias -l mtweak_unload return $input(Completely unloaded mIRC Tweak v1.00! Check: http://www.mircscripts.org for updates! $\n $+ $\n $+ (Author: Zmodem (Zmodem@netzero.net)),68,mIRC Tweak Unloaded) | .unload -rs $script
alias -l mtwkreadme $iif($isfile($scrptdr $+ Readme.txt),run $scrptdr $+ Readme.txt,return $input(mIRC Tweak could not locate the readme file that should have been included with the ZIP archive in which mIRC Tweak came with. You must try re-downloading this file again and get the readme file or email the author for a copy.,260,Readme Error))
alias -l mtweak if ($!dialog(mtweak)) { $iif($server,$iif($input(A server connection has been detected! It is recommended that you are not on a server or doing anything important at this time while trying to tweak your internal mIRC settings. mIRC will most-likely need to be rebooted pending any changes you make. Continuing is NOT recommended. Do you wish to continue anyways?,136,Connection Detected),dialog -m mtweak mtweak),dialog -m mtweak mtweak) }
alias -l mtwkclose if ($group(#mtwk).status == on) { .disable #mtwk | .remove mtwkcpy.ini | $iif($input(You must now restart mIRC and in order for the changes to take effect you must allow the following: $crlf $+ $\n 1.> Two reboots must be made. $\n 2.> You must not have any other copies of mIRC running. $\n 3.> You must agree that by clicking 'Yes' you are allowing this addon to modify your mIRC ini file and take full responsibility for what happens no matter what the outcome. $crlf $+ $crlf $+ Do you wish to restart mIRC now?,136,mIRC Settings Changed),mtwkreboot) }
alias -l mtwkreboot {
  if ($server) { .raw QUIT | .partall }
  close -i | close -c | close -f | close -g | close -m | close -s | close -@
  .disable #mtwk
  .remove $mircdirmtwkcpy.ini 
  .copy $mircini $mircdirmtwkcpy.ini 
  .enable #mtwkcpy
  .run $mircexe $mircdirmtwkcpy.ini 
  .exit
}
alias -l mtchk {
  var %d = $1, %i = $2, %e = $3, %b = $4
  did $+(-,$iif($tok(5,$gval(Options,n0)),u,c)) %d 5
  did $+(-,$iif($tok(1,$gval(Options,n3)) > 200,c,u)) %d 6
  did $+(-,$iif($tok(1,$gval(Options,n3)) > 200,e,b)) %d 7
  did -z %d 7 201 1000
  did -c %d 7 %b
  did -ra %d 11 %b
  did $+(-,$iif($gval(DDE,ServerStatus) == off,c,u)) %d 12
  did $+(-,$iif($tok(11,$gval(Options,n1)),c,u)) %d 13
  did $+(-,$iif($tok(5,$gval(Options,n2)),u,c)) %d 14
  did $+(-,$iif($gval(socks,enabled) == no,c,u)) %d 15
  did -c %d $iif($tok(21,$gval(Options,n0)) <= 4096,19,20)
}

;Dialogs
dialog mtweak {
  title "mIRCTweak v1.00"
  size -1 -1 185 119
  option dbu
  tab "Performance", 1, 5 6 174 87
  tab "Connection", 2
  tab "DCC", 3
  check "Disable &Highlighting (Mild Text Display Enhancement)", 5, 10 25 136 8, tab 1
  check "Enable Window &Buffering (Speed Up Text Display)", 6, 10 38 130 8, tab 1
  scroll "Buffer", 7, 17 61 96 10, horizontal, tab 1
  text "Lowest", 8, 20 51 19 8, tab 1
  text "Highest", 9, 91 51 19 8, tab 1
  text "Normal", 10, 56 51 19 8, tab 1
  text "", 11, 116 61 31 9, tab 1
  check "Disable &DDE (mIRC Loads Quicker When Executed)", 12, 10 80 134 8, tab 1
  check "&Skip MOTD (Faster Connection)", 13, 10 25 136 8, tab 2
  check "&Normal Address Lookup (Faster Server Connection)", 14, 10 38 130 8, tab 2
  check "Do Not Use &Firewall (Faster Server Resolution)", 15, 10 51 132 8, tab 2
  button "&Pump DCC Sending", 16, 30 28 55 12, tab 3
  button "&Faster DCC Sends", 17, 95 28 55 12, tab 3
  text "DCC Packet Sizes:", 18, 22 51 54 8, tab 3
  radio "4096 (&Normal)", 19, 72 51 45 8, group, tab 3
  radio "8192 (&Fastest)", 20, 122 51 45 8, tab 3
  button "&OK", 21, 5 101 26 13, cancel, group
  button "&Help", 22, 152 101 27 13
}
dialog mtwkabt {
  option dbu
  size -1 -1 100 75
  title "About mIRC Tweak"
  box "", 1, 4 4 92 48
  text "mIRC Tweak", 2, 6 15 85 8, center
  text "v1.00", 3, 6 25 85 8, center
  text "Author: Zmodem", 4, 6 35 85 8, center
  link "Zmodem", 5, 4 59 25 8
  button "&Close", 20, 71 59 25 12, ok
}

;Dialog Events
on *:DIALOG:mtweak:*:*: {
  var %d = $dname, %i = $did, %e = $devent, %b = $tok(1,$gval(Options,n3)), %r = $gval(Options,n3)
  if (%e == init) { mtchk %d %i %e %b | $mtr }
  if (%e == scroll) {
    .enable #mtwk
    did -ra %d 11 $did(%i).sel
    pval Options n3 $ptok(%r,$did(%i).sel,1)
    $mtr
  }
  if (%e == sclick) {
    $iif((%i != 0) && (%i != 1) && (%i != 2) && (%i != 3) && (%i != 21) && (%i != 22),.enable #mtwk)
    $iif(%i == 5,pval Options n0 $ptok($gval(Options,n0),$iif($did(%i).state,0,1),5))
    if (%i == 6) {
      if ($did(%i).state) { did -e %d 7 | pval Options n3 $ptok(%r,201,1) | did -z %d 7 201 1000 | did -c %d 7 $tok(1,$gval(Options,n3)) | did -ra %d 11 $did(7).sel | $mtr }
      did -b %d 7 | pval Options n3 $ptok(%r,200,1) | did -r %d 11
      $mtr
    }
    $iif(%i == 12,pval DDE ServerStatus $iif($did(%i).state,off,on))
    $iif(%i == 13,pval Options n1 $ptok($gval(Options,n1),$iif($did(%i).state,1,0),11))
    $iif(%i == 14,pval Options n2 $ptok($gval(Options,n2),$iif($did(%i).state,0,1),5))
    $iif(%i == 15,pval Socks Enabled $iif($did(%i).state,no,yes))
    if (%i == 16) { .pdcc 2999999999999 | mecho Increased DCC PUMP. | $mtr }
    if (%i == 17) { .fsend ON | mecho Adjusted DCC Sends to Fast Send. | $mtr }
    $iif(%i == 19,pval Options n0 $ptok($gval(Options,n0),4096,21))
    $iif(%i == 20,pval Options n0 $ptok($gval(Options,n0),8192,21))
    $iif(%i == 21,mtwkclose)
    $iif(%i == 22,mtwkreadme)
  }
}
ON *:DIALOG:mtwkabt:sclick:5:run mailto:zmodem@netzero.net

;Groups
#mtwk off
#mtwk end
#mtwkcpy off
ON *:START:.remove mirc.ini | .copy mtwkcpy.ini mirc.ini | .disable #mtwkcpy | .enable #mtwkUC | .run $mircexe mirc.ini | .exit
#mtwkcpy end
#mtwkUC off
ON *:START:.disable #mtwkUC | return $input(mIRC tweaks are now complete!,68,mIRC Tweaked!)
#mtwkUC end

;Internal Events
on *:LOAD:if ($version == 5.91) { mecho mIRC Tweak v1.00 by: Zmodem Loaded! Check your Menubar & Statusbar for menus on it! | return } | mecho mIRC Tweak v1.00 requires mIRC v5.91, no greater no less, to operate functionally. mIRC versions 5.91+ may operate as well, but are far TOO risky to attempt. Unloading addon... | mtwk_unload

;Menus
menu menubar,status {
  mIRC Tweak
  .Setup:mtweak
  .-
  .ReadMe File:mtwkreadme
  .About:mtwkabt
  .-
  .Unload:$iif($input(Are you sure that you want to completely unload mIRC Tweak v1.00?,264,Unload mIRC Tweak),mtweak_unload)
}