advIDENTd — File Browser
advIDENTdv1.3 / advIDENTdv1.3 / advIDENTd.mrc
advIDENTd.mrc — 7.68 KB — Download this file
;--------------------------
; advIDENTd v1.3 by Eistee
;--------------------------
;------------------------------------------
; Visual Config
; Here you can Configure the output format
; for your MTS engine or what ever
;------------------------------------------
; The Request thats comming in $1- = Request IP
alias -l advIDENTD.request { echo $colour(Other) -si2 *** IDENTd request from $1- }
; mIRC Default Reply. $1- = The RAW Reply (61852 , 7000 : USERID : UNIX : Eistee)
alias -l advIDENTD.nreply { echo $colour(Other) -si2 *** IDENTd replied: $1- }
; advIDENTd Reply $1- = The RAW Reply (61852 , 7000 : USERID : UNIX : Eistee)
alias -l advIDENTD.areply { echo $colour(Other) -si2 *** advIDENTd replied: $1- }
;------------------
; advIDENTd - Code
;------------------
on *:START: {
.identd off
if ($portfree(113)) socklisten advIDENTd 113
}
on *:SOCKLISTEN:advIDENTd: {
var %i = 1
while ($sock($+(advIDENTd.,%i))) inc %i
sockaccept $+(advIDENTd.,%i)
advIDENTD.request $sock($+(advIDENTd.,%i)).ip
}
on *:SOCKREAD:advIDENTd.*: {
if ($sockerr > 0) return
sockread %tmp.advIDENTd
if ($sockbr == 0) return
if ($readini($+($scriptdir,advIDENTd.ini),n,advIDENTd,$sock($sockname).ip)) {
var %reply = %tmp.advIDENTd : $ifmatch
advIDENTD.areply %reply
}
else {
var %i = 1
while ($ini($+($scriptdir,advIDENTd.ini),advIDENTd,%i)) {
var %ip = $iif($longip($ifmatch),$ini($+($scriptdir,advIDENTd.ini),advIDENTd,%i),$dll($+($scriptdir,advIDENTd.dll),namelookup,$ini($+($scriptdir,advIDENTd.ini),advIDENTd,%i)))
echo -s ip %ip
if ($sock($sockname).ip == $matchtok(%ip,$sock($sockname).ip,1,32)) {
echo -s if $ifmatch
var %reply = %tmp.advIDENTd : $readini($+($scriptdir,advIDENTd.ini),n,advIDENTd,$ini($+($scriptdir,advIDENTd.ini),advIDENTd,%i))
advIDENTD.areply %reply
}
inc %i
}
if (!%reply) {
var %reply = %tmp.advIDENTd : USERID : $readini($mircini,ident,system) : $readini($mircini,ident,userid)
advIDENTD.nreply %reply
}
}
sockwrite -n $sockname %reply
sockclose $sockname
unset %tmp.advIDENTd
}
;---------------------
; advIDENTd - DIALOGS
;---------------------
alias advIDENTd dialog -m advIDENTd advIDENTd
menu menubar,status {
advIDENTd:advIDENTd
}
dialog -l advIDENTd {
title "advIDENTd v1.3 by Eistee"
size -1 -1 147 140
option dbu
text "I&P or Host:", 1, 8 9 30 8
combo 2, 36 8 60 60, sort size edit drop
button "&Add", 3, 99 8 20 10, disable
button "&Delete", 4, 120 8 20 10, disable
box "Reply", 5, 8 24 132 66, disable
radio "Normal &lookup ''USERID : System : User-ID''", 6, 13 34 116 8, disable
radio "Always return ''ERROR : &NO-USER''", 7, 13 44 116 8, disable
radio "Always return ''ERROR : &HIDDEN-USER''", 8, 13 54 116 8, disable
radio "Always return ''ERROR : &UNKNOWN-ERROR''", 9, 13 64 116 8, disable
radio "&Custom:", 10, 13 74 30 8, disable
edit "", 11, 45 73 88 10, disable
box "Normal lookup", 12, 8 96 93 37, disable
text "&System:", 13, 13 106 25 8, disable
edit "", 14, 45 105 50 10, disable
text "User-&ID:", 15, 13 118 25 8, disable
edit "", 16, 45 117 50 10, disable
button "OK", 17, 108 99 32 12, ok
button "Cancel", 18, 108 114 32 12, cancel
link "advIDENTd v1.3", 19, 104 130 44 8, center
}
on *:DIALOG:advIDENTd:init:0: {
var %i = 1
while ($ini($+($scriptdir,advIDENTd.ini),advIDENTd,%i)) {
did -a advIDENTd 2 $ifmatch
inc %i
}
}
on *:DIALOG:advIDENTd:edit:2: {
did -a advIDENTd 3 &Add
did -b advIDENTd 4
if ($did(2)) {
did -e advIDENTd 3,5,6,7,8,9,10
if ($did(6).state) did -e advIDENTd 12,13,14,15,16
if ($did(10).state) did -e advIDENTd 11
}
else did -b advIDENTd 3,5,6,7,8,9,10,11,12,13,14,15,16
}
on *:DIALOG:advIDENTd:sclick:2: {
var %id $readini($+($scriptdir,advIDENTd.ini),n,advIDENTd,$did(2))
did -a advIDENTd 3 S&ave
did -e advIDENTd 3,4,5,6,7,8,9,10,11
did -r advIDENTd 11,14,16
if (($gettok(%id,1,58) == $+(USERID,$chr(32))) && ($numtok(%id,58) == 3)) {
did -u advIDENTd 7,8,9,10
did -c advIDENTd 6
did -b advIDENTd 11
did -e advIDENTd 12,13,14,15,16
did -r advIDENTd 11
did -a advIDENTd 14 $gettok(%id,2,58)
did -a advIDENTd 16 $gettok(%id,3,58)
}
elseif (($gettok(%id,1,58) == $+(ERROR,$chr(32))) && ($gettok(%id,2,58) == $+($chr(32),NO-USER)) && ($numtok(%id,58) == 2)) {
did -u advIDENTd 6,8,9,10
did -c advIDENTd 7
did -b advIDENTd 11,12,13,14,15,16
did -r advIDENTd 11,14,16
}
elseif (($gettok(%id,1,58) == $+(ERROR,$chr(32))) && ($gettok(%id,2,58) == $+($chr(32),HIDDEN-USER)) && ($numtok(%id,58) == 2)) {
did -u advIDENTd 6,7,9,10
did -c advIDENTd 8
did -b advIDENTd 11,12,13,14,15,16
did -r advIDENTd 11,14,16
}
elseif (($gettok(%id,1,58) == $+(ERROR,$chr(32))) && ($gettok(%id,2,58) == $+($chr(32),UNKNOWN-ERROR)) && ($numtok(%id,58) == 2)) {
did -u advIDENTd 6,7,8,10
did -c advIDENTd 9
did -b advIDENTd 11,12,13,14,15,16
did -r advIDENTd 11,14,16
}
else {
did -u advIDENTd 6,7,8,9
did -c advIDENTd 10
did -b advIDENTd 12,13,14,15,16
did -e advIDENTd 11
did -r advIDENTd 14,16
did -a advIDENTd 11 %id
}
}
on *:DIALOG:advIDENTd:sclick:4: {
remini $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2)
did -d advIDENTd 2 $did(2).sel
did -d advIDENTd 2 0
did -r advIDENTd 11,14,16
did -u advIDENTd 6,7,8,9,10
did -b advIDENTd 3,4,5,6,7,8,9,10,11,12,13,14,15,16
did -a advIDENTd 3 &Add
}
on *:DIALOG:advIDENTd:sclick:6: did -b advIDENTd 11 | did -e advIDENTd 12,13,14,15,16 | did -f advIDENTd 14
on *:DIALOG:advIDENTd:sclick:7,8,9: did -b advIDENTd 11,12,13,14,15,16 | did -f advIDENTd 17
on *:DIALOG:advIDENTd:sclick:10: did -b advIDENTd 12,13,14,15,16 | did -e advIDENTd 11 | did -f advIDENTd 11
on *:DIALOG:advIDENTd:sclick:3,17: {
if ($did(3).enabled) {
if ($did(6).state == 1) {
if ($did(14) == $null) {
:enter14
if ($input(Please enter a System name:,eho,No System name entered,$readini($mircini,ident,system)) != $null) did -a advIDENTd 14 $ifmatch
else {
if ($input(You must enter a System name to save!,w,Not Saved) == $true) goto enter14
else goto exit
}
}
if ($did(16) == $null) {
:enter16
if ($input(Please enter a User ID:,eho,No User ID entered,$readini($mircini,ident,userid)) != $null) did -a advIDENTd 16 $ifmatch
else {
if ($input(You must enter a User ID to save!,w,Not Saved) == $true) goto enter16
else goto exit
}
}
writeini -n $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2) USERID : $did(14) : $did(16)
}
if ($did(7).state == 1) writeini -n $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2) ERROR : NO-USER
if ($did(8).state == 1) writeini -n $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2) ERROR : HIDDEN-USER
if ($did(9).state == 1) writeini -n $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2) ERROR : UNKNOWN-ERROR
if ($did(10).state == 1) {
if ($did(11) == $null) {
:enter11
if ($input(Please enter a Reply:,eho,No custom Reply entered,) != $null) did -a advIDENTd 11 $ifmatch
else {
if ($input(You must enter a custom Reply to save!,w,Not Saved) == $true) goto enter11
else goto exit
}
}
writeini -n $+(",$scriptdir,advIDENTd.ini,") advIDENTd $did(2) $did(11)
}
if ($did(3) == &Add) { did -a advIDENTd 2 $did(2) | did -a advIDENTd 3 S&ave }
:exit
}
}
on *:DIALOG:advIDENTd:sclick:19: { run http://www.mircscripts.org/comments.php?id=1884 }
;eof