/ScriptServ

; ***** Scroll Pops Vrs 1.0 by DND *****
on ^*:notify:{ if (!$appactive) && ((%sp.n)) { spop.call a $nick } }
on ^*:unotify:{ if (!$appactive) && ((%sp.n)) { spop.call b $nick } }
on ^*:text:*:#: { 
  if (!$appactive) {
    if (%sp.c) && (($regex($strip($1-),%sp.t))) { spop.call c $chan $+($chr(40),$nick,$chr(41)) $strip($1-) } 
    elseif  (%sp.ni) && (($me isin $strip($1-))) { spop.call f $chan $+($chr(40),$nick,$chr(41)) $strip($1-) } 
  }
}
on ^*:action:*:#: { 
  if (!$appactive) {
    if (%sp.c) && (($regex($strip($1-),%sp.t))) { spop.call c $chan $+($chr(40),$nick,$chr(41)) $strip($1-) } 
    elseif  (%sp.ni) && (($me isin $strip($1-))) { spop.call f $chan $+($chr(40),$nick,$chr(41)) $strip($1-) } 
  }
}
on ^*:notice:*:*: { 
  if (!$appactive) && ((%sp.no)) {
    if ($chan) { spop.call g $chan $+($chr(40),$nick,$chr(41)) $strip($1-) }
    else { spop.call h $+($chr(40),$nick,$chr(41)) $strip($1-) }
  }
}
on ^*:open:?:{ if (!$appactive) && ((%sp.q)) { spop.call e $+($chr(40),$nick,$chr(41)) $strip($1-) } }
on ^*:invite:*:{ if (!$appactive) && ((%sp.i)) { spop.call i $+($chr(40),$nick,$chr(41)) invites you to join $chan } }
on ^*:kick:*:{ if (!$appactive)  && ((%sp.k)) { spop.call k $+($chr(40),$nick,$chr(41)) just kicked $knick from $chan $1- } }
on ^*:ban:*:{ if (!$appactive) && ((%sp.b)) { spop.call l $+($chr(40),$nick,$chr(41)) just set a ban of $banmask in $chan } }
alias -l spop.call {
  if (!$window(@s.pops)) { spop.create | spop.draw $1- | .timerspop.mup -o 30 0 spop.mup }
  else { spop.draw $1- | .timerspop.mdown off | if (%h.cur < 120) { .timerspop.oful off | .timerspop.mup -o 30 0 spop.mup } }
}
alias -l spop.create {
  var %x = $calc($window(-1).w -200), %y = $window(-1).h | window -Bfphdo +dL @s.pops %x %y 200 120
  var %y.com = $window(@s.pops).dy | %y.cur = $calc(%y.com +120) | %h.cur = 0
  window @s.pops -200 120
}
alias -l spop.draw {
  drawpic -c @s.pops 0 0 $+(",$scriptdirspop.jpg,")
  spop.paint $1-
  drawdot @s.pops
}
alias -l spop.paint {
  if ($1 == a) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Notify
    spop.paintm $2 is online
    return
  }
  elseif ($1 == b) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Notify
    spop.paintm $2 is offline
    return
  }
  elseif ($1 == c) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Text
    spop.paintm $2-
    return
  }
  elseif ($1 == d) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Action
    spop.paintm $2-
    return
  }
  elseif ($1 == e) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Query
    spop.paintm $2-
    return
  }
  elseif ($1 == f) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Nic Mention
    spop.paintm $2-
    return
  }
  elseif ($1 == g) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Channel Notice
    spop.paintm $2-
    return
  }
  elseif ($1 == h) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Notice
    spop.paintm $2-
    return
  }
  elseif ($1 == i) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Invite
    spop.paintm $2-
    return
  }
  elseif ($1 == k) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Kick
    spop.paintm $2-
    return
  }
  elseif ($1 == l) {
    drawtext -nor @s.pops $rgb(106,106,106) "Verdana" 9 9 30 Ban
    spop.paintm $2-
    return
  }
}
alias -l spop.paintm {
  var %i = $1-, %c = 1, %j = $wrap(%i,"Verdana",9,120,1,0), %h = 45
  while (%j) {
    if (%c == 5) { return }
    drawtext -nr @s.pops $rgb(106,106,106) "Verdana" 9 9 %h $wrap(%i,"Verdana",9,120,1,%c)
    dec %j | inc %c | inc %h 12
  }
}
alias -l spop.mup {
  dec %y.cur 4 | inc %h.cur 4
  window @s.pops $calc($window(-1).w -200) %y.cur 200 %h.cur
  if (%h.cur => 120) { .timerspop.mup off | .timerspop.oful -o 1 10 spop.oful | halt }
}
alias -l spop.mdown {
  inc %y.cur 4 | dec %h.cur 4
  window @s.pops $calc($window(-1).w -200) %y.cur 200 %h.cur
  if (%h.cur == 0) { window -c @s.pops }
}
alias -l spop.oful { .timerspop.mdown -o 30 0 spop.mdown }
dialog spop {
  size -1 -1 115 115
  option dbu
  title "Scroll Pops Vrs 1.0"
  box "Trigger Events", 1, 5 2 50 95
  button "Apply", 2, 48 100 30 12
  button "Close", 3, 80 100 30 12, ok
  check "Custom words", 11, 10 15 42 8
  check "Your nic", 10, 10 25 40 8
  check "Notices", 4, 10 35 40 8
  check "Queries", 5, 10 45 40 8
  check "Notifies", 6, 10 55 40 8
  check "Invites", 7, 10 65 40 8
  check "Kicks", 8, 10 75 40 8
  check "Bans", 9, 10 85 40 8
  box "Custom Words", 12, 60 2 50 95
  list 13, 65 15 40 60
  edit "", 14, 65 71 40 9, autohs
  button "Add", 15, 65 82 20 10
  button "Del", 16, 85 82 20 10
}
on *:dialog:spop:*:*:{
  if ($devent == init) {
    if (%sp.c) { did -c $dname 11 }
    if (%sp.ni) { did -c $dname 10 }
    if (%sp.no) { did -c $dname 4 }
    if (%sp.q) { did -c $dname 5 }
    if (%sp.n) { did -c $dname 6 }
    if (%sp.i) { did -c $dname 7 }
    if (%sp.k) { did -c $dname 8 }
    if (%sp.b) { did -c $dname 9 }
    didtok $dname 13 124 $mid(%sp.t,5,-5)
  }
  elseif ($devent == sclick) {
    if ($did == 2) {
      if ($did(11).state) { set %sp.c on } | else { unset %sp.c }
      if ($did(10).state) { set %sp.ni on } | else { unset %sp.ni }
      if ($did(4).state) { set %sp.no on } | else { unset %sp.no }
      if ($did(5).state) { set %sp.q on } | else { unset %sp.q }
      if ($did(6).state) { set %sp.n on } | else { unset %sp.n }
      if ($did(7).state) { set %sp.i on } | else { unset %sp.i }
      if ($did(8).state) { set %sp.k on } | else { unset %sp.k }
      if ($did(9).state) { set %sp.b on } | else { unset %sp.b }
    }
    elseif ($did == 15) { if ($did(14)) { did -a $dname 13 $did(14) | did -r $dname 14 | spop.spt } }
    elseif ($did == 16) { if ($did(13).sel) { did -d $dname 13 $did(13).sel | if (!$did(13).lines) { unset %sp.t } | else { spop.spt } }
    }
  }
}
alias spop { if (!$dialog(spop)) { dialog -m spop spop } }
alias -l spop.spt { set %sp.t $+(/\b,$chr(40),$didtok($dname,13,124),$chr(41),\b/i) }
menu @s.pops {
  sclick : { showmirc -s }
}
menu menubar {
  Scroll Pops: spop  
}