/ScriptServ

; Quote Manager
; by ch1zra
; ch1zra@gmail.com
; http://uptheirons.co.sr/
; #Scripters @ irc.krstarica.com
; Copyright © Up The Irons ! inc. 
; 
; a $script inspired by [Setsuna] - Lord of Quotes \m/

alias quote {
  if (!$1) {
    if (!$window(@quote)) {
      ;      window -oadlCke +Lse @Quote 15 15 600 400
      window -oadlke +Le @Quote 200 200 1 1
      var %g 1
      while (%g <= 400) {
        window -oadlke +Le @Quote $window(@quote).x $window(@quote).y %g %g
        inc %g 20
      }
      while (%g <= 600) {
        window -oadlke +Le @Quote 200 200 %g 400
        inc %g 20
      }
      quote.go
    }
    else { window -a @quote }
  }
  if ($1 == add) {
    write -a $qt($scriptdirquote.db) $2-
    echo -a [Quote Manager] quote added : $1-
    if ($window(@quote)) { quote.go }
  }
  if ($1 == random) {
    msg $active $read($qt($scriptdirquote.db))
  }
}

alias quote.go {
  clear @quote
  var %i 1
  while (%i <= $lines($qt($scriptdirquote.db))) {
    aline @quote %i $read($qt($scriptdirquote.db),%i)
    inc %i
  }
  sline @quote 1
}

alias quote.about {
  if ($input(Quote manager v1.4 $crlf $crlf by ch1zra $crlf a $chr(36) $+ script $& 
    inspired by [Setsuna] - Lord of Quotes \m/ $crlf $crlf ch1zra@gmail.com $crlf $& 
    #Scripters @ irc.krstarica.com $crlf http://uptheirons.co.sr/ $crlf $crlf $& 
    Copyright © Up The Irons ! inc. Scripting Team,oi, About Quote Manager) == $true) {
  }
}

on *:INPUT:@quote: {
  if (!$1) { quote.go }
  elseif ($1 == /say) {
    if (!$2) {
      if ($sline(@quote,1) == $null) { halt }
      else { msg $lactive $gettok($sline(@quote,1),2-,32) }
    }
    elseif ($2 isnum) {
      msg $lactive $gettok($line(@quote,$2),2-,32)
    }
  }
  elseif ($1 == /add) {
    if ($2 != $null) {
      write -a $qt($scriptdirquote.db) $2-
    }
    quote.go
  }
  elseif ($1 == /refresh) { quote.go }
  elseif ($1 == /close) || ($1 == /exit) || ($1 == /quit) { window -c @quote }
  elseif ($1 == /help) {
    .run $qt($scriptdirquotehelp.txt)
  }
  elseif ($1 == /del) {
    write -dl $+ $gettok($sline(@quote,1),1,32) $qt($scriptdirquote.db)
    quote.go
  }
  else {
    filter -c @quote @quote * $+ $1- $+ *
  }
  sline @quote 1
  halt
}

menu channel,menubar,nicklist,status {
  Quote Manager:quote
}

menu @quote {
  dclick:msg $lactive $gettok($sline(@quote,1),2-,32)
  Refresh:quote.go
  Say:msg $lactive $gettok($sline(@quote,1),2-,32)
  Delete:write -dl $+ $gettok($sline(@quote,1),1,32) $qt($scriptdirquote.db) | quote.go
  -
  Help:.run $qt($scriptdirquotehelp.txt)
  About:quote.about
  -
  Close:window -c @quote
}

; EOF - ch1zra