Q-Ajournal — File Browser

Q-Ajournalv0.2 / Q-Ajournalv0.2 / q-ajournal.mrc

q-ajournal.mrc — 8.75 KB — Download this file

;Q-Ajournal v0.2 by Queen-Amidala
;Written 12/16/03
;http://www.planet-naboo.com
;queenie@planet-naboo.com
;Last updated 12/15/04
;***********************************


;INITIALIZATION
on *:LOAD:{  
  echo -a 14[13Q-Ajournal v0.214]13 by Queen-Amidala loaded! To use, simply type 13/journal or right click in your nicklist, channel, or status window and choose "Q-Ajournal v0.2" Please read the documentation for further assistance and author contact information.
}


;JOURNAL VIEW/OPEN DIALOG CODE
dialog q-ajournal {
  title "Q-Ajournal v0.2 by Queen-Amidala"
  size -1 -1 193 172
  option dbu
  box "Your Q-Ajournal", 1, 3 3 186 166
  text "View Page", 8, 120 14 25 8
  combo 7, 147 10 36 64, size drop sort
  button "Update", 3, 9 154 29 10
  button "Edit", 5, 39 154 29 10
  button "OK", 4, 69 154 29 10, ok
  edit "", 2, 9 24 174 125, read multi return vsbar
  icon 6, 167 151 15 15,  " $+ $scriptdirqaicon.jpg", 0
}



;INIT/LOAD JOURNAL.INI
on *:dialog:q-ajournal:init:*: { 
  var %loop = $iif(. isin $calc($ini($scriptdirq-ajournal.ini,0)/5),$int($calc($ini($scriptdirq-ajournal.ini,0)/5 + 1)),$calc($ini($scriptdirq-ajournal.ini,0)/5))
  while (%loop) {  
    did -a $dname 7 %loop
    dec %loop
  }
  if (%newPage) {
    did -c $dname 7 %newPage
    .unset %newPage
  }
  else {
    did -c $dname 7 1
  }
  var %count = 5    
  var %loop = $calc($ini($scriptdirq-ajournal.ini,0)-(($did(q-ajournal,7).seltext - 1) * %count))
  while (%loop) && (%count) && ($ini($scriptdirq-ajournal.ini,0)) {
    did -a $dname 2 SUBJECT: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),SUBJECT) $crlf
    did -a $dname 2 DATE & TIME: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),DATETIME) $crlf
    did -a $dname 2 - $crlf

    var %file = $+($scriptdir,$ini($scriptdirq-ajournal.ini,%loop),.txt)
    var %line = 1
    while (%line <= $lines(%file)) { 
      did -a $dname 2 $read(%file,%line) $crlf
      inc %line 
    }

    did -a $dname 2 - $crlf
    did -a $dname 2 MOOD: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),MOOD) $crlf
    did -a $dname 2 MUSIC: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),MUSIC) $crlf
    did -a $dname 2 -------------------------------------------------- $crlf
    dec %loop
    dec %count
  }
  rePropj $dname
}



;PAGE NUMBER SELECT
on *:dialog:q-ajournal:sclick:7:{
  did -r $dname 2
  var %count = 5
  var %loop = $calc($ini($scriptdirq-ajournal.ini,0)-(($did(q-ajournal,7).seltext - 1) * %count))
  while (%loop) && (%count) {
    did -a $dname 2 SUBJECT: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),SUBJECT) $crlf
    did -a $dname 2 DATE & TIME: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),DATETIME) $crlf
    did -a $dname 2 - $crlf

    var %file = $+($scriptdir,$ini($scriptdirq-ajournal.ini,%loop),.txt)
    var %line = 1
    while (%line <= $lines(%file)) { 
      did -a $dname 2 $read(%file,%line) $crlf
      inc %line 
    }

    did -a $dname 2 - $crlf
    did -a $dname 2 MOOD: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),MOOD) $crlf
    did -a $dname 2 MUSIC: $readini($scriptdirq-ajournal.ini,$ini($scriptdirq-ajournal.ini,%loop),MUSIC) $crlf
    did -a $dname 2 -------------------------------------------------- $crlf
    dec %count
    dec %loop
  }

}

;UPDATE BUTTON
on *:dialog:q-ajournal:sclick:3:{
  dialog -md q-aj_update q-aj_update
  dialog -x q-ajournal q-ajournal
}


;EDIT ENTRIES BUTTON
on *:dialog:q-ajournal:sclick:5:{
  set %newPage $did(q-ajournal,7).seltext
  dialog -md q-aj_edit q-aj_edit
  dialog -x q-ajournal q-ajournal
}



;UPDATE DIALOG CODE
dialog q-aj_update {
  title "Q-Ajournal v0.2 UPDATE"
  size -1 -1 193 172
  option dbu
  text "Current Music:", 6, 9 156 36 8
  text "Subject:", 7, 9 17 21 8
  text "Current Mood:", 4, 9 141 36 8
  box "Update Your Q-Ajournal", 1, 3 3 187 165
  edit "", 8, 31 14 153 10, autohs
  edit "", 2, 9 26 175 103, multi return vsbar
  combo 3, 46 138 74 66, size drop
  edit "", 5, 45 154 108 10, autohs
  button "Post", 9, 129 131 26 9
  button "Cancel", 12, 158 131 26 9, cancel
  icon 11, 169 147 15 15,  " $+ $scriptdirqaicon.jpg", 0
}



;INIT FOR UPDATE DIALOG
on *:dialog:q-aj_update:init:*: { 
  filter -o " $+ $scriptdirmoods.txt" q-aj_update 3
  rePrope $dname
}

;ON EDIT EVENT
on *:dialog:q-aj_update:edit:2,8:{
  rePrope $dname
}

;POST ENTRY BUTTON
on *:dialog:q-aj_update:sclick:9:{

  writeini -n " $+ $scriptdirq-ajournal.ini" $ctime($fulldate) SUBJECT $did(q-aj_update,8)  
  writeini -n " $+ $scriptdirq-ajournal.ini" $ctime($fulldate) DATETIME $fulldate  

  var %i = 1
  while (%i <= $did(q-aj_update,2).lines) { 
    write " $+ $scriptdir $+ $ctime $+ .txt" $did(q-aj_update,2,%i)
    inc %i
  }

  writeini -n " $+ $scriptdirq-ajournal.ini" $ctime($fulldate) MOOD $did(q-aj_update,3).seltext
  writeini -n " $+ $scriptdirq-ajournal.ini" $ctime($fulldate) MUSIC $did(q-aj_update,5)

  dialog -md q-ajournal q-ajournal
  dialog -x q-aj_update q-aj_update
}

on *:dialog:q-aj_update:sclick:12:{
  dialog -md q-ajournal q-ajournal
}


;EDIT ENTRIES DIALOG CODE
dialog q-aj_edit {
  title "Q-Ajournal v0.2 EDIT"
  size -1 -1 193 172
  option dbu
  box "Edit Your Q-Ajournal Entries", 1, 3 3 187 166
  text "Search by Date", 3, 9 14 39 8 
  text "Edit Subject:", 7, 10 44 31 8
  text "Edit Entry:", 10, 10 58 28 7
  combo 4, 10 25 79 92, size drop
  edit "", 8, 41 41 143 10
  edit "", 2, 9 65 176 80, multi return vsbar
  button "Save Changes", 9, 9 149 41 10
  button "Remove Entry", 6, 52 149 41 10  
  button "Cancel", 5, 95 149 41 10, cancel
  icon 11, 169 149 15 15,  " $+ $scriptdirqaicon.jpg", 0
}


;INIT FOR EDIT DIALOG
on *:dialog:q-aj_edit:init:*: { 
  if ($isfile($scriptdirq-ajournal.ini)) { 
    var %loop = 1
    while (%loop <= $ini($scriptdirq-ajournal.ini,0)) {
      did -a $dname 4 $asctime($ini($scriptdirq-ajournal.ini,%loop))
      inc %loop
    }
    else { echo -a 14[13Q-Ajournal v0.214] 13ERROR: you do not have any journal entries to edit yet. }
  }
}


on *:dialog:q-aj_edit:sclick:4:{
  did -r $dname 8,2
  did -a $dname 8 $readini($scriptdirq-ajournal.ini,$ctime($did(q-aj_edit,4).seltext),SUBJECT)

  var %efile = $+($scriptdir,$ctime($did(q-aj_edit,4).seltext),.txt)
  var %eline = 1
  while (%eline <= $lines(%efile)) { 
    did -a $dname 2 $read(%efile,%eline)
    inc %eline 
  }
}



;SAVE CHANGES BUTTON
on *:dialog:q-aj_edit:sclick:9:{
  writeini -n " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext) SUBJECT $did(q-aj_edit,8)  
  .remove " $+ $scriptdir $+ $ctime($did(q-aj_edit,4).seltext) $+ .txt"
  var %i = 1
  while (%i <= $did(q-aj_edit,2).lines) { 
    write " $+ $scriptdir $+ $ctime($did(q-aj_edit,4).seltext) $+ .txt" $did(q-aj_edit,2,%i)
    inc %i
  }
  dialog -md q-ajournal q-ajournal
  dialog -x q-aj_edit q-aj_edit
}


;REMOVE ENTRY BUTTON
on *:dialog:q-aj_edit:sclick:6:{
  remini " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext)
  remini " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext) SUBJECT
  remini " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext) DATETIME
  .remove " $+ $scriptdir $+ $ctime($did(q-aj_edit,4).seltext) $+ .txt"
  remini " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext) MOOD
  remini " $+ $scriptdirq-ajournal.ini" $ctime($did(q-aj_edit,4).seltext) MUSIC
  dialog -md q-ajournal q-ajournal
  dialog -x q-aj_edit q-aj_edit
}



;CANCEL BUTTON
on *:dialog:q-aj_edit:sclick:5:{
  dialog -md q-ajournal q-ajournal
  dialog -x q-aj_edit q-aj_edit
}


alias rePropj { 
  did $iif($ini($scriptdirq-ajournal.ini,0),-e,-b) $1 5,7,8 
}

alias rePrope { 
  did $iif($did($1,8).text && $did($1,2).text,-e,-b) $1 9 
}


;POPUP MENU TO OPEN JOURNAL
menu status,nicklist,channel {
  $iif(!$dialog(Q-Ajournal),Q-Ajournal v0.2)  : dialog -md Q-Ajournal Q-Ajournal
}
;ALIAS TO OPEN JOURNAL
alias journal { dialog -md Q-Ajournal Q-Ajournal }



;UPDATES IN v0.2
;Added organization to edit one entry at a time
;Added page number option to display only 5 entries at a time
;Re-organized entries to be displayed in reverse order, most current on top
;Disabled option buttons unless usable within the dialog (dummy proofing)


;FUTURE UPDATES WISHLIST
;avatars for different moods?
;colors/more exciting, colorful layout
;If you have any comments, suggestions, or concerns please email queenie@gobbly.net



;****************************************
;WEBSITE: http://www.planet-naboo.com
;EMAIL: queenie@planet-naboo.com
;NETWORK: DALnet
;CHANNEL: #scriptinghelp
;****************************************