/ScriptServ

/*
=====================================================
Msn Delete Checker v1.0

BY SeRDaR406

This addon shows the people who are on your list who haven't added you to  their 

own list and the people who have deleted you from their list. 
=====================================================
*/
dialog mdec {
  title "Msn Delete Checker v1.0"
  size -1 -1 328 177
  option dbu
  icon $msn.ico, 0
  box "", 1, 3 1 128 60
  text "Msn address:", 2, 6 8 47 8
  edit "", 3, 5 16 123 10, autohs
  text "Password:", 4, 6 28 33 8
  edit "", 5, 6 36 122 10, pass autohs
  list 6, 50 47 78 13, size
  box "", 7, 134 1 192 162
  list 8, 137 16 186 144, size
  text "Who has deleted/not added you:", 9, 138 7 144 8
  text "Warning and Informations:", 10, 3 65 65 8
  edit "If your address or password in ''whatever way'' says that its hasnt been sent to the addon writer.There isn't a fake!. The people on the list means; people who have added or deleted you which means that the people on or list haven't added you to theirs. a bit confusing hope you have understood it :)", 11, 2 74 129 56, read multi vsbar
  button "Button", 12, 231 179 37 12, hide cancel
  edit "Ready For Action..!", 16, 1 165 325 11, read
  icon 13, 2 130 129 34, $mdeclogo, 0
}
alias -l msn.ico return $shortfn($scriptdirmsn.ico)
alias -l views.mdx return $shortfn($scriptdirviews.mdx)
alias -l mdx.dll return $shortfn($scriptdirmdx.dll)
alias -l bars.mdx return $shortfn($scriptdirbars.mdx)
alias -l close.ico return $shortfn($scriptdirclose.ico)
alias -l check.ico return $shortfn($scriptdircheck.ico)
alias -l mdeclogo return $shortfn($scriptdirlogo.png)
alias -l mdx dll $mdx.dll $1 $2-
alias mdec10 $iif(!$dialog(mdec),dialog -m mdec mdec)
on *:dialog:mdec:init:*: {
  mdx SetMircVersion $version
  mdx MarkDialog $dname
  mdx SetBorderStyle $dname 6 
  mdx SetFont $dname 2,4,6,8 13 400 Tahoma
  mdx SetFont $dname 3,5 13 700 Tahoma
  mdx SetColor $dname 8 text $rgb(521,22,122)
  mdx SetControlMDX $dname 8 listview flatsb header grid report > $views.mdx
  did -i $dname 8 1 headerdims 200:1 200:2
  mdx SetControlMDX $dname 6 toolbar flat nodivider list > $bars.mdx
  did -i $dname 6 1 bmpsize 16 16
  did -i $dname 6 1 setimage icon small 0, $+ $check.ico
  did -i $dname 6 1 setimage icon small 0, $+ $close.ico
  did -a $dname 6 +a 1 Check
  did -a $dname 6 1 -
  did -a $dname 6 +W 55 2 Close
  did -i $dname 8 1 headertext + 0 Nick $+ $chr(9) $+ + 0 Address
}
on *:dialog:mdec:sclick:*: {
  if ($did == 6) {
    if ($did(6).sel == 2) {
      if (!$did(3)) return $input(Type your msn address please!,ohud,Error)
      elseif (!$did(5)) return $input(Type your password of msn adress,ohud,Error)
      else {
        did -r $dname 8
        did -ra $dname 16 Checking.Please wait...
        if ($sock(msndc)) sockclose msndc
        set %acc $did(3)
        set %account $+(passport=,%acc,&,password=,$did(5),&submit=Check) 
        sockopen msndc www.blockstatus.com 80
        did -i $dname 8 1 headertext + 0 Nick $+ $chr(9) $+ + 0 Address
      }
    }
    $iif($did(6).sel == 4,.timer 1 0 dialog -x $dname $dname)
  }
}
on *:sockopen:msndc: {
  if ($sockerr) echo -a No Connection!
  else {
    var %s = sockwrite -n $sockname
    %s POST /msn/delete-checker HTTP/1.1
    %s Accept: image/gif, image/x-xbitmap, image/jpeg, image/pjpeg, application/x-shockwave-flash, */*
    %s Referer: http://www.blockstatus.com/msn/delete-checker
    %s Accept-Language: tr
    %s Accept-Encoding: gzip, deflate
    %s User-Agent: Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1; .NET CLR 1.1.4322)
    %s Content-Type: application/x-www-form-urlencoded; charset="utf-8"
    %s Content-Length: $calc($len(%account) + 1)
    %s Host: www.blockstatus.com
    %s Connection: Keep-Alive
    %s Cache-Control: no-cache
    %s
    %s %account
  }
}
alias -l htmlfree { 
  if ($len($1-) <= 900) { 
    var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;,$chr(9)) 
    return %x
  }
} 
on *:sockread:msndc: {
  sockread %mdata
  if (*<b>MSN ID:</b>*  iswm %mdata) && (%acc isin %mdata) && (Error !isin %mdata) && ($dialog(mdec)) {
    did -i mdec 8 1 headertext + 0 $+(Nick,$chr(32),$chr(40),Total:,$remove($gettok(%mdata,3,32),<b>,<br>,</b>,</br>,%acc),$chr(32),persons,$chr(41)) $+ $chr(9) $+ + 0 Address
    did -ra mdec 16 Listed all persons...!
  }
  if (Invalid isin %mdata) && ($dialog(mdec)) && (passport isin %mdata) { did -ra mdec 16 Msn address or password is wrong...! | sockclose msndc }
  if ((width="150" isin %mdata) && (Email !isin %mdata)) set %address $htmlfree(%mdata)
  if (width="250" isin %mdata) && (NickName !isin %mdata) && ($dialog(mdec)) did -a mdec 8 1 1 $htmlfree(%mdata) $+ $chr(9) $+ 2 %address
}
alias -l check->files {
  echo -a Missing File. $+(",4,$1,") Copy file to $+(",4,$scriptdir,") folder.
  echo -a Addon unloaded.
  .unload -rs $shortfn($script)
}
on *:load: {
  if ($isfile($mdx.dll) == $false) check->files mdx.dll
  elseif ($isfile($bars.mdx) == $false) check->files bars.mdx
  elseif ($isfile($views.mdx) == $false) check->files views.mdx
  elseif ($isfile($msn.ico) == $false) check->files msn.ico
  elseif ($isfile($close.ico) == $false) check->files close.ico
  elseif ($isfile($check.ico) == $false) check->files check.ico
  elseif ($isfile($mdeclogo) == $false) check->files logo.png
  else {
    echo -a 4Msn Delete Checker v1.0 7BY SeRDaR406 loaded.
    echo -a Type 4/mdec10 to open.
  }
}
menu menubar,status {
  Msn Delete Checker 
  .Open: mdec10
  .-
  .Unload : .unload -rs $shortfn($script) 
}