/ScriptServ

;Idlerpg player info by idk
;usage: /idlerpg

alias idlerpg {
  if ($1) {
    dialog -m idlerpg idlerpg
    set %idle.player $1
    did -a idlerpg 2 %idle.player
    sockopen idlerpg firefox.itn.liu.se 80
  }
  else dialog -m idlerpg idlerpg
}

dialog idlerpg {
  title "Idlerpg Player Info"
  size -1 -1 133 166
  option dbu
  text "Player", 1, 2 4 16 8
  edit "", 2, 19 2 50 10
  button "Read", 3, 71 2 30 9
  button "Close", 4, 102 2 30 9, ok
  box "Player Info", 5, 1 14 131 151
  list 6, 3 21 125 141, size hsbar
}

on *:dialog:idlerpg:sclick:3:{
  if ($sock(idlerpg)) sockclose idlerpg
  set %idle.player $did(idlerpg,2)
  sockopen idlerpg firefox.itn.liu.se 80
  did -r idlerpg 6
}

on *:dialog:idlerpg:close:*:unset %idle.player

on *:sockopen:idlerpg:{
  sockwrite -n idlerpg GET $+(/idlerpg/playerview.php?player=,%idle.player,&alltime=1)
  sockwrite -n idlerpg Host: firefox.itn.liu.se $+ $crlf $+ $crlf 
}

on *:sockread:idlerpg:{
  var %i
  sockread %i
  if (*#g7 irpg* iswm %i) || (*font-family* iswm %i) || (*backgroun-color* iswm %i) || (*color:* iswm %i) halt
  if (* $+ $chr(125) $+ * iswm %i) || (*body* iswm %i) || (* $+ $chr(45) $+ $chr(45) $+ * iswm %i) halt
  if (*Game Info* iswm %i) || (*Player* iswm %i) || (*Source* iswm %i) || (*Thanks* iswm %i) halt
  if (%idle.player $+ * iswm %i) halt
  if (*<b>Total time idled:</b>* iswm %i) { did -a idlerpg 6 $striphtml(%i) | did -a idlerpg 6 $chr(32) | halt }
  if (*weapon:* iswm %i) { did -a idlerpg 6 $striphtml(%i) | did -a idlerpg 6 $chr(32) | halt } 
  if (*quit:* iswm %i) { did -a idlerpg 6 $striphtml(%i) | did -a idlerpg 6 $chr(32) | halt } 
  if (*sum:* iswm %i) { did -a idlerpg 6 $striphtml(%i) | did -a idlerpg 6 $chr(32) | halt }
  if (*total:* iswm %i) { did -a idlerpg 6 $striphtml(%i) | did -a idlerpg 6 $chr(32) | halt }
  if (*<blockquote>* iswm %i) did -a idlerpg 6 $chr(32)
  if (!$striphtml(%i)) halt
  did -a idlerpg 6 $striphtml(%i)
  did -z idlerpg 6
}

menu menubar {
  Idlerpg Player Info:idlerpg
}

;striphtml alias by fubar
alias -l striphtml {
  if ($1) {
    var %strip,%parm = <> $remove($1-,> <,><,$chr(9)) <>,%n = 2
    while ($gettok($gettok(%parm,%n,62),1,60)) {
      %strip = %strip $ifmatch
      inc %n
    }
    return %strip
  }
}