/ScriptServ

; */* --------------------------
; Icon Viewer v1.2 by Nenzo
; Nenzo86@gmail.com
; ----------------------------- *\*

dialog iconv {
  title "Icon Viewer v1.2 By Nenzo"
  size -1 -1 246 217
  option dbu
  box "Icon Viewer 1.2", 1, 2 2 241 201
  edit "", 2, 3 205 111 10, read
  button "&Load", 3, 186 205 26 10
  button "&Close", 4, 215 205 26 10, ok
  list 5, 5 11 234 189, size
}
on *:dialog:iconv:*:*: { var %m mdx,%d $dname
  if ($devent == init) {
    %m MarkDialog %d | %m SetMircVersion $version
    %m SetFont 1,2,3,4 + 13 400 Tahoma
    %m SetBorderStyle 2,3,4,5 staticedge
    %m SetControlMDX 5 listview autoarrange labeltip extsel icon single > $mdx.vdll
    _d -i 5 1 iconspacing 61 66
  }
  if ($devent == sclick) {
    if ($did == 5) {
      if ($did(%d,5).sel) {
        _d -ra 2 Icon index: $calc($did(%d,5).sel - 2))
    } | }
    if ($did == 3) iconload
  }
}
alias iconv dialog -m iconv iconv | if ($1) { .timerex 1 0 loadicons $1- }
alias -l mdx dll $shortfn($scriptdir $+ mdx\mdx.dll) $1-
alias -l mdx.vdll return $scriptdir $+ mdx\Views.mdx
alias -l _d did $1 iconv $2-
alias -l iconload var %p = $sfile(Icon File,Select a icon file!,Icon It!) | if (%p) { loadicons %p }
alias -l loadicons {
  var %p $1-,%i 0,%c $ci(%p)
  _d -ra 2 Total Icons: %c - File: $nopath(%p)
  if (!%c) { _d -ra 2 Invalid Icon File: $nopath(%p) | return }
  _d -r 5 | _d -i 5 1 clearicons normal
  while (%i <= %c) {
    _d -i 5 1 seticon normal 0 $+(%i,$chr(44),%p)
    if (%i) _d -a 5 0 + %i 0 0 $calc(%i -1)
    inc %i
  }
}
; Counticon alias by Xint, modified to fit my needs.
alias -l ci {
  var %i 0,%w window | %w -nhp @_c
  while (!$error) { drawpic -no @_c 1 1 %i $1- | inc %i }
  :error | reseterror | %w -c @_c | return %i
}
menu menubar,status {
  -
  Icon Viewer
  .Open:iconv
  .Readme:run $scriptdir $+ readme.txt
}
on *:load: if ($version < 6.16) { echo -at This addon Requires mIRC 6.16 | unload -rs $script | return }