/ScriptServ

/*
======================
Google Logo Maker 0.1

BY SeRDaR406
======================
*/
dialog glo {
  title "Google Logo Maker v0.1"
  size -1 -1 160 55
  option dbu
  box "", 1, 2 -1 156 41
  text "Type your name or nick:", 2, 5 5 58 8
  edit "", 3, 5 13 150 10, limit 22
  button "Create", 4, 41 25 37 12, disable
  button "Edit", 5, 80 25 37 12, disable
  button "Close", 6, 119 25 37 12, cancel
  edit "Google Logo Maker v0.1 BY SeRDaR406", 7, 2 43 157 11, read autohs
}

alias goglogo $iif(!$dialog(glo),dialog -m glo glo)
alias -l create->logo {
  if ($len($1-) <= 2) return $input(Your name or nickname must be minimum "3" characters,ohud,Error)
  else {
    if ($window(@goglogo)) window -c @goglogo
    if ($window(@sl)) window -c @sl
    unset %numtok %fileitem %pw %gln
    did -b $dname 5
    set %logname $replace($1-,$chr(32),+,ý,i,Ý,i,ö,o,ü,u,ð,g,ç,c,þ,s,Ð,g,Ö,o,Ü,u,Þ,s)
    did -ra $dname 7 Your logo is creating.Please wait...
    sockclose glogo
    sockopen glogo www.goglogo.com 80
  }
}
alias -l remove->logofiles {
  unset %logname %gifiles %pw
  var %a = 1
  var %fi = $+(",$scriptdir,goglogo.txt,")
  while (%a <= $lines(%fi)) {
    if (_.gif !isin $read(%fi,%a)) .remove $+(",$scriptdir,$read(%fi,%a),") 
    inc %a
  }
  .remove $+(",$scriptdir,goglogo.txt,")  
  drawrect -rfd @goglogo $rgb(70,122,185) 1 $calc($window(@goglogo).w - 150) 100 60 20 5 5
  drawrect -rd @goglogo $rgb(0,0,0) 1 $calc($window(@goglogo).w - 150) 100 60 20 5 5
  drawrect -rfd @goglogo $rgb(70,122,185) 1 $calc($window(@goglogo).w - 80) 100 60 20 5 5
  drawrect -rd @goglogo $rgb(0,0,0) 1 $calc($window(@goglogo).w - 80) 100 60 20 5 5
  drawtext -or @goglogo $rgb(255,255,255) Tahoma 11 $calc($window(@goglogo).w - 134) 103 Save
  drawtext -or @goglogo $rgb(255,255,255) Tahoma 11 $calc($window(@goglogo).w - 65) 103 Close
}
alias -l load->logo {
  unset %size %nl %numtok %fileitem %pw 
  var %o = 1
  var %fi = $+(",$scriptdir,goglogo.txt,")
  window -pCk[0] +t @Goglogo $calc($dialog(glo).x - 40) $calc($dialog(glo).y + 75) 900 160
  drawrect -rf @goglogo $rgb(255,255,255) 1 0 0 900 200
  while (%o <= $lines(%fi)) {
    set %pw $calc((%pw + $pic($+(",$scriptdir,$read(%fi,%o),")).width) + 2)
    if (_.gif isin $read(%fi,%o)) set %pw $calc(%pw + 15)
    if ($dialog(glo)) {
      window -pCk[0] +t @Goglogo $calc($dialog(glo).x - 40) $calc($dialog(glo).y + 75) %pw 160
      if (_.gif !isin $read(%fi,%o)) drawpic @goglogo $calc(($window(@goglogo).w - $pic($+(",$scriptdir,$read(%fi,%o),")).width) - 2) 1 $+(",$scriptdir,$read(%fi,%o),")  
    }
    inc %o
  }
  if ($dialog(glo)) did -ra glo 7 Google Logo Maker v0.1 BY SeRDaR406
  remove->logofiles
}
on *:dialog:glo:edit:3: $iif($did(3),did -e $dname 4,did -b $dname 4)
on *:dialog:glo:sclick:*: {
  if ($did == 4) create->logo $did(3)
  if ($did == 5) run %gln
}
on *:sockopen:glogo: {
  if ($sockerr) echo -a No Connection!
  else {
    var %s = sockwrite -n $sockname
    %s GET /s.asp?lo= $+ %logname HTTP/1.1
    %s Host: www.goglogo.com
    %s $crlf
  }
}
on *:sockread:glogo: {
  var %u
  sockread %u
  if (Error-Input isin %u) && ($dialog(glo)) did -ra glo 7 Please use only these characters - [A-Z][a-z][0-9]
  if (?lo= isin %u) { write -c $+(",$scriptdir,goglogo.txt,") | set %gifiles $remove($gettok(%u,3-,32),border=0>,<img,src=,",images,/,<a>) }
  if (<br><br> isin %u) { 
    sockclose glogo
    var %i = 1 
    while (%i <= $numtok(%gifiles,32)) { 
      var %files = $gettok(%gifiles,%i,32) 
      write $+(",$scriptdir,goglogo.txt,") %files
      if (_.gif !isin %files) {      
        sockclose $+(getlogo*,%files)
        sockopen $+(getlogo*,%files) www.goglogo.com 80
        sockmark $+(getlogo*,%files) %files
      }  
      inc %i 
    }
  }
}
on *:sockopen:getlogo*: {
  inc %numtok
  var %t = sockwrite -n $sockname
  %t GET $+(/images/,$sock($sockname).mark) HTTP/1.1
  %t Host: www.goglogo.com
  %t $crlf
}
on *:sockread:getlogo*: {
  var %c
  sockread %c
  if (Length isin %c) set %size $gettok(%c,2,32)
  if (* !iswm %c) { 
    write -c $+(",$scriptdir,$sock($sockname).mark,") 
    sockclose $+(savelogo*,$sock($sockname).mark) 
    set %nl $sock($sockname).rcvd
    sockrename $sockname $+(savelogo*,$sock($sockname).mark) 
  }
}
on *:sockread:savelogo*: {
  sockread &sl
  bwrite $+(",$scriptdir,$remove($sockname,savelogo*),") -1 -1 &sl
  var %progrs = $calc(100 * ($sock($sockname).rcvd - %nl) / %size)
  if (%progrs == 100) { inc %fileitem | if ($dialog(glo)) did -ra glo 7 Your logo creating.Please wait... $+(%numtok,/,%fileitem) | sockclose $sockname }
  if (%fileitem == %numtok) load->logo
}
alias -l save->logo {
  set %gln $+(",$scriptdir,$1,.bmp,")
  window -ph +t @sl 0 0 $window(@goglogo).w 134
  drawrect -rf @sl $rgb(255,255,255) 1 0 0 $window(@goglogo).w 134
  drawcopy @goglogo 0 0 $window(@goglogo).w 134 @sl 0 0
  drawsave @sl %gln
  window -c @sl
  window -c @goglogo
  if ($dialog(glo)) did -e glo 5
}
menu @goglogo {
  uclick: {
    if ($inrect($mouse.x,$mouse.y,$calc($window(@goglogo).w - 150),100,60,20)) {
      var %logoname = $input(Type a name for your logo:,e,Save Logo)
      if (%logoname) save->logo %logoname
    }
    if ($inrect($mouse.x,$mouse.y,$calc($window(@goglogo).w - 80),100,60,20)) window -c @goglogo
  }
}
menu menubar,status {
  Google Logo Maker v0.1
  .Open:goglogo
  .-
  .Unload: .unload -rs $shortfn($script)
}
on *:load: {
  if ($version < 6.2) { echo -a This addon works on only mIRC v6.2 | .unload -rs $shortfn($script) }
  else { echo -a Google Logo Maker v0.1 loaded. | echo -a Type to open: /goglogo }
}