/ScriptServ

;ENNSLookup source_code1.0 beta4
;Author: ENNE
;For info: http://ennslookup.altervista.org
;Warning: don't modify and ripping this code please
on *:LOAD: {
echo -a 1,0ENNSLookup correctly loaded!
if ($version < 6.16) { echo -a 4,0ENNSlookup warning: this addon has developed on mIRC 6.16, your mIRC version is only $version and some functions could not work correctly. }
echo -a 1,0For use ENNSlookup type the command: /ennslookup <domain> <server> <querytype> (domain, server and querytype aren't closely necessary) or go in the mIRC's main menu.
}
menu menubar {
-
ENNSlookup
.Start:ennslookup
.Uninstall:ennslookup.uninstall
}
alias ennslookup {
if (($1 != $null) && ($2 != $null)) {
if ($3 != $null) {
set %ennslookup.domain $1
set %ennslookup.nameserver $2
set %ennslookup.querytype $3
}
}
if ($dialog(ennslookup) = ennslookup) { dialog -x ennslookup }
dialog -mr ennslookup ennslookup
}
alias ennslookup.uninstall {
set %ennslookup.uninstall_sure $?!="This will unistall ENNSlookup. Are you sure?"
if (%ennslookup.uninstall_sure = $true) {
sockclose *ennslookup*
unset %ennslookup*
echo -a 1,0ENNSlookup is uninstalled! Thx for have used! For info: http://ennslookup.altervista.org
.unload -rs $nopath($script)
}
}
dialog ennslookup {
title "ENNSlookup - powered by ENNE"
size -1 -1 243 187
option dbu
tab "NSlookup", 1, 2 2 239 183
text "Domain to lookup:", 6, 4 19 235 7, tab 1
edit "", 7, 4 26 229 9, tab 1
edit "", 9, 4 44 229 9, tab 1
combo 11, 4 62 31 50, tab 1 drop
button "Send NSlookup Query!", 19, 178 73 62 10, tab 1 default flat
edit "", 15, 4 84 235 99, tab 1 read multi hsbar vsbar
button "?", 12, 233 26 7 9, tab 1 flat
button "?", 13, 233 44 7 9, tab 1 flat
button "?", 18, 35 62 7 9, tab 1 flat
box "Status", 16, 46 55 193 18, tab 1
text "ENNSlookup has been loaded.", 17, 49 63 182 7, tab 1
text "Name Server to use:", 8, 4 37 235 7, tab 1
text "Query type:", 10, 4 55 38 7, tab 1
text "Results:", 14, 5 77 97 7, tab 1
tab "Live Update", 2
button "Search and Download Update!", 25, 76 32 91 12, tab 2 flat
box "Update Status", 27, 7 51 230 19, tab 2
text "In this section you can automatically download software's updates!", 30, 9 60 225 8, tab 2
text "For more info visit:", 32, 99 89 45 8, tab 2
button "http://ennslookup.altervista.org", 33, 79 97 85 10, tab 2
tab "Feedback", 3
text "With this form you can contact the author for comments, questions, problems, bugs reports and many others of ENNSlookup.", 39, 8 21 167 16, tab 3
text "Insert your name:", 40, 9 42 44 8, tab 3
edit "", 41, 53 41 122 10, tab 3
text "Insert your email:", 42, 9 52 43 8, tab 3
text "Insert your comments, questions, problems, bugs reports...", 44, 9 62 166 8, tab 3
edit "", 43, 53 51 122 10, tab 3
edit "", 45, 8 70 229 19, tab 3 multi hsbar
button "Send Message!", 46, 8 90 229 9, tab 3 flat
box "Feedback Status", 47, 9 101 229 18, tab 3
text "Waiting your informations...", 48, 11 109 225 8, tab 3
tab "Languages", 4
text "For the moment, in this version, only english language is avalaible.", 20, 41 56 160 8, tab 4
text "For more info visit:", 37, 103 93 45 8, tab 4
button "http://ennslookup.altervista.org", 38, 81 101 85 10, tab 4
tab "Info", 5
text "Software's name:", 21, 9 25 42 8, tab 5
text "", 52, 29 43 209 8, tab 5
text "Date of first use:", 26, 9 70 41 8, tab 5
text "Developed on:", 29, 9 79 35 8, tab 5
text "Your mIRC version:", 31, 9 88 47 8, tab 5
text "", 53, 29 52 209 8, tab 5
text "Author:", 35, 9 34 18 8, tab 5
text "Used's times:", 23, 9 97 32 8, tab 5
text "", 50, 52 25 186 8, tab 5
text "", 51, 28 34 210 8, tab 5
text "Version:", 22, 9 43 19 8, tab 5
text "License:", 28, 9 52 19 8, tab 5
text "Release:", 24, 9 61 21 8, tab 5
text "", 54, 31 61 207 8, tab 5
text "", 55, 51 70 187 8, tab 5
text "", 56, 45 79 193 8, tab 5
text "", 57, 57 88 181 8, tab 5
text "", 58, 42 97 196 8, tab 5
text "For more info visit:", 34, 101 121 45 8, tab 5
button "http://ennslookup.altervista.org", 36, 83 129 85 11, tab 5
}
on *:dialog:ennslookup:edit:7: { set %ennslookup.domain $did(ennslookup,7).text }
on *:dialog:ennslookup:edit:9: { set %ennslookup.nameserver $did(ennslookup,9).text }
on *:dialog:ennslookup:init:0: {
if (%ennslookup.now_version = $null) { set %ennslookup.now_version 1.0 beta4 }
did -a ennslookup 11 ANY
did -a ennslookup 11 A
did -a ennslookup 11 CNAME
did -a ennslookup 11 NS
did -a ennslookup 11 MX
did -a ennslookup 11 PTR
did -a ennslookup 11 SOA
did -a ennslookup 11 TXT
if (%ennslookup.querytype = $null) { set %ennslookup.querytype ANY }
if (%ennslookup.querytype = ANY) { did -c ennslookup 11 1 }
if (%ennslookup.querytype = A) { did -c ennslookup 11 2 }
if (%ennslookup.querytype = CNAME) { did -c ennslookup 11 3 }
if (%ennslookup.querytype = NS) { did -c ennslookup 11 4 }
if (%ennslookup.querytype = MX) { did -c ennslookup 11 5 }
if (%ennslookup.querytype = PTR) { did -c ennslookup 11 6 }
if (%ennslookup.querytype = SOA) { did -c ennslookup 11 7 }
if (%ennslookup.querytype = TXT) { did -c ennslookup 11 8 }
if ($did(ennslookup,11).seltext = $null) { set %ennslookup.querytype ANY | did -c ennslookup 11 1 }
did -a ennslookup 7 %ennslookup.domain
if (%ennslookup.nameserver = $null) { set %ennslookup.nameserver ns1.ticino.com }
did -a ennslookup 9 %ennslookup.nameserver
inc %ennslookup.nr_use
if (%ennslookup.nr_use = 1) { set %ennslookup.first_use $date $time }
did -a ennslookup 50 ENNSlookup
did -a ennslookup 51 ENNE
did -a ennslookup 52 %ennslookup.now_version
did -a ennslookup 53 freeware
did -a ennslookup 54 4. January 2006
did -a ennslookup 55 %ennslookup.first_use
did -a ennslookup 56 mIRC 6.16
did -a ennslookup 57 $version
did -a ennslookup 58 %ennslookup.nr_use
}
on *:dialog:ennslookup:sclick:11: { set %ennslookup.querytype $did(ennslookup,11).seltext }
on *:dialog:ennslookup:sclick:12: { did -a ennslookup 17 Help: in this field you insert the internet domain to lookup. }
on *:dialog:ennslookup:sclick:13: { did -a ennslookup 17 Help: in this field you insert the name server for lookup the domain. }
on *:dialog:ennslookup:sclick:18: { did -a ennslookup 17 Help: you can choose the query type, if you want see all type, select 'ANY'. }
on *:dialog:ennslookup:sclick:19: {
if ($did(ennslookup,19).text = Send NSlookup Query!) {
if (($did(ennslookup,7).text = $null) && ($did(ennslookup,9).text = $null)) { did -a ennslookup 17 Error: domain and name server no inserted. | halt }
if ($did(ennslookup,7).text = $null) { did -a ennslookup 17 Error: domain no inserted. | halt }
if ($did(ennslookup,9).text = $null) { did -a ennslookup 17 Error: name server no inserted. | halt }
if ($sock(ennslookup) = ennslookup) { did -a ennslookup 17 Error: query connection already in use! | halt }
if (%ennslookup.querytype = $null) { set %ennslookup.querytype ANY | did -c ennslookup 11 1 }
did -b ennslookup 7
did -b ennslookup 9
did -b ennslookup 11
did -b ennslookup 12
did -b ennslookup 13
did -b ennslookup 18
did -a ennslookup 19 Stop Query!
did -r ennslookup 15
did -a ennslookup 17 Opening query connection...
sockopen ennslookup hosting5.ticinocom.com 80
halt
}
if ($did(ennslookup,19).text = Stop Query!) {
sockclose ennslookup
did -a ennslookup 17 Query request stopped, connection close.
did -e ennslookup 7
did -e ennslookup 9
did -e ennslookup 11
did -e ennslookup 12
did -e ennslookup 13
did -e ennslookup 18
did -a ennslookup 19 Send NSlookup Query!
halt
}
}
on *:dialog:ennslookup:sclick:25: {
did -a ennslookup 30 Connection with update's server opening...
sockopen ennslookup_update ennslookup.altervista.org 80
}
on *:sockopen:ennslookup: {
unset %ennslookup.nrline
set %ennslookup.contentlenght 27 + $len(%ennslookup.domain)
set %ennslookup.contentlenght %ennslookup.contentlenght + $len(%ennslookup.nameserver)
set %ennslookup.contentlenght %ennslookup.contentlenght + $len(%ennslookup.querytype)
did -a ennslookup 17 Sending dates to services...
sockwrite -n $sockname POST /test/nslookup.php HTTP/1.1
sockwrite -n $sockname Accept: image/gif, image/x-xbitmap, image/jpeg, image/pjpeg, application/vnd.ms-excel, application/vnd.ms-powerpoint, application/msword, application/x-shockwave-flash, */*
sockwrite -n $sockname Accept-Language: it-ch
sockwrite -n $sockname Content-Type: application/x-www-form-urlencoded
sockwrite -n $sockname Accept-Encoding: gzip, deflate
sockwrite -n $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1; .NET CLR 1.1.4322)
sockwrite -n $sockname Host: enne.skystorm.net
sockwrite -n $sockname Content-Length: %ennslookup.contentlenght
sockwrite -n $sockname Connection: Keep-Alive
sockwrite -n $sockname Cache-Control: no-cache
sockwrite -n $sockname $null
sockwrite -n $sockname server= $+ %ennslookup.nameserver $+ &querytype= $+ %ennslookup.querytype $+ &dominio= $+ %ennslookup.domain
}
on *:sockread:ennslookup: {
sockread %ennslookup.sread
if (%ennslookup.sread = $null) { halt }
did -a ennslookup 17 Receiving dates from services...
if ((Apache isin %ennslookup.sread) && (CentOS isin %ennslookup.sread)) { halt }
if ((INPUT TYPE isin %ennslookup.sread) && (SELECT NAME isin %ennslookup.sread)) { halt }
if (INPUT TYPE="txt" isin %ennslookup.sread) { halt }
if ("querytype" isin %ennslookup.sread) { halt }
if ((OPTION isin %ennslookup.sread) && (/OPTION isin %ennslookup.sread)) { halt }
if ((Server isin %ennslookup.sread) && (nameserver !isin %ennslookup.sread)) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline Name Server used: $remove(%ennslookup.sread,	,<BR>,Server,$chr(58)) }
if ((Address isin %ennslookup.sread) && (internet address !isin %ennslookup.sread)) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline Address: $remove(%ennslookup.sread,$chr(32),Address,53,$chr(58),$chr(35),<BR>) | inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline }
if (Non-authoritative answer isin %ennslookup.sread) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline $remove(%ennslookup.sread,<BR>) | inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline }
if ((Name isin %ennslookup.sread) && (nameserver !isin %ennslookup.sread)) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline Name: $remove(%ennslookup.sread,<BR>,	,Name,$chr(58)) }
if (nameserver isin %ennslookup.sread) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline $replace($remove(%ennslookup.sread,<BR>),	,$chr(32)) }
if (mail exchanger isin %ennslookup.sread) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline $replace($remove(%ennslookup.sread,<BR>),	,$chr(32)) }
if (Authoritative answers can be found from isin %ennslookup.sread) {
inc %ennslookup.nrline
did -i ennslookup 15 %ennslookup.nrline
inc %ennslookup.nrline
did -i ennslookup 15 %ennslookup.nrline $remove(%ennslookup.sread,<BR>)
inc %ennslookup.nrline
did -i ennslookup 15 %ennslookup.nrline
}
if (internet address isin %ennslookup.sread) { inc %ennslookup.nrline | did -i ennslookup 15 %ennslookup.nrline $replace($remove(%ennslookup.sread,<BR>),	,$chr(32)) }
if (</HTML> isin %ennslookup.sread) {
sockclose $sockname
did -a ennslookup 17 End of query, connection closed.
did -e ennslookup 7
did -e ennslookup 9
did -e ennslookup 11
did -e ennslookup 12
did -e ennslookup 13
did -e ennslookup 18
did -a ennslookup 19 Send NSlookup Query!
}
}
on *:sockclose:ennslookup: {
did -a ennslookup 17 Query connection closed.
did -e ennslookup 7
did -e ennslookup 9
did -e ennslookup 11
did -e ennslookup 12
did -e ennslookup 13
did -e ennslookup 18
did -a ennslookup 19 Send NSlookup Query!
}
on *:sockopen:ennslookup_update: {
set %ennslookup.update_start off
sockwrite -n $sockname GET /ennslookup.mrc HTTP/1.1
sockwrite -n $sockname Host: ennslookup.altervista.org
sockwrite -n $sockname $null
}
on *:SOCKREAD:ennslookup_update: {
sockread %ennslookup.update_download
if (%ennslookup.update_download = $null) { halt }
set %ennslookup.tmp_nfound ;ENNSlookup source_code
if (%ennslookup.tmp_nfound = $left(%ennslookup.update_download,23)) {
set %ennslookup.new_version $remove(%ennslookup.update_download,%ennslookup.tmp_nfound)
if (%ennslookup.new_version != %ennslookup.now_version) {
set %ennslookup.update_start on
.remove $remove($script,$mircdir)
did -a ennslookup 30 New version found ( $+ %ennslookup.new_version $+ ), downloading...
}
if (%ennslookup.new_version = %ennslookup.now_version) {
set %ennslookup.update_start off
did -a ennslookup 30 No new version found.
sockclose $sockname
halt
}
}
if (%ennslookup.update_start = on) {
.write $remove($script,$mircdir) %ennslookup.update_download
}
set %ennslookup.tmp_nEND ;end_ENNSlookup source_code END
if (%ennslookup.tmp_nEND = $left(%ennslookup.update_download,31)) {
did -a ennslookup 30 Download new version complete, click "Yes" to mIRC's question.
set %ennslookup.now_version %ennslookup.new_version
set %ennslookup.update_start off
.timerennslookup_NEWVERSIONUNLOAD 1 1 /.unload -rs $remove($script,$mircdir)
.timerennslookup_NEWVERSION1 1 1 /.load -rs $remove($script,$mircdir)
.timerennslookup_NEWVERSION2 1 1 /dialog -x ennslookup
.timerennslookup_NEWVERSION3 1 1 /dialog -mr ennslookup ennslookup
.timerennslookup_NEWVERSION5 1 2 did -a ennslookup 17 New version ( $+ %ennslookup.new_version $+ ) correctly loaded!
}
}
on *:sockclose:ennslookup_download: {
set %ennslookup.update_start off
did -a ennslookup 30 Connection with update's server closed.
}
on *:dialog:ennslookup:sclick:46: {
set %ennslookup.fb_ok off
if ($did(ennslookup,41).text = $null) { did -a ennslookup 48 Error: no name inserted! | halt }
if ($did(ennslookup,43).text = $null) { did -a ennslookup 48 Error: no email address inserted! | halt }
if ($did(ennslookup,45).text = $null) { did -a ennslookup 48 Error: no comments inserted! | halt }
if ($sock(ennslookup_feedback) = ennslookup_feedback) { did -a ennslookup 48 Error: feedback connection already opened! | halt }
sockopen ennslookup_feedback ennslookup.altervista.org 80
}
on *:sockopen:ennslookup_feedback: {
set %ennslookup.fb_name $replace($did(ennslookup,41).text,$chr(32),$chr(37) $+ 20)
set %ennslookup.fb_email $replace($did(ennslookup,43).text,$chr(32),$chr(37) $+ 20)
set %ennslookup.fb_message $replace($did(ennslookup,45).text,$chr(32),$chr(37) $+ 20)
did -a ennslookup 48 Feedback's connection opened...
sockwrite -n $sockname GET /gbook/guestbook.php?akce=pridej_zapis&datum= $+ $date $+ $chr(37) $+ 20 $+ $time $+ &name= $+ %ennslookup.fb_name $+ &email= $+ %ennslookup.fb_email $+ &message= $+ %ennslookup.fb_message HTTP/1.1
sockwrite -n $sockname Host: ennslookup.altervista.org
sockwrite -n $sockname $null
}
on *:sockclose:feedback_ennslookup: {
if (%ennslookup.fb_ok != on) { did -a ennslookup 48 Error: connection closed, message not sent! }
}
on *:sockread:ennslookup_feedback: {
sockread %ennslookup.fb_read
if (%ennslookup.fb_read = $null) { halt }
if (fb_ENNSlookup indirizzo email errato isin %ennslookup.fb_read) { did -a ennslookup 48 Error: wrong email address! | sockclose $sockname | halt }
if ($did(ennslookup,45).text isin %ennslookup.fb_read) {
did -a ennslookup 48 Message sent!
set %ennslookup.fb_ok on
sockclose $sockname
halt
}
}
on *:dialog:ennslookup:sclick:33: { run http://ennslookup.altervista.org }
on *:dialog:ennslookup:sclick:36: { run http://ennslookup.altervista.org }
on *:dialog:ennslookup:sclick:38: { run http://ennslookup.altervista.org }
;end_ENNSlookup source_code END