/ScriptServ

alias dpf { if (!$dialog(dpf)) { dialog -md dpf dpf } }

dialog dpf {
  title "Dead Pixel Finder - By Amun"
  size -1 -1 220 80
  option dbu
  box "", 1, 0 -2 220 82
  icon 2, 5 5 15 15,  $scriptdirdpf.black.png, 0
  icon 3, 5 23 15 15,  $scriptdirdpf.red.png, 0
  icon 4, 5 41 15 15,  $scriptdirdpf.green.png, 0
  icon 5, 5 59 15 15,  $scriptdirdpf.yellow.png, 0
  link Check Black, 7, 25 9 37 8
  link Check Red, 8, 25 27 37 8
  link Check Green, 9, 25 45 37 8
  link Check Yellow, 10, 25 63 37 8
  text "Dead Pixel Finder v0.1 by Amun", 14, 67 5 147 8, center
  link "More Help", 15, 67 64 26 8
  button "Finish", 16, 187 67 30 10, ok cancel
  link "Open Help", 6, 67 46 28 8
  text "If you need any help, please read the help file associated with this script. If you still need further help, click the link that reads 'More Help'. Thanks for using this script. I hope it helped you somehow.", 11, 67 15 147 28, center
  link "More Useful Scripts", 12, 67 55 47 8
  box "", 13, 62 -2 158 82
}

on *:dialog:dpf:*:*: {
  if ($devent == mouse) { return }
  if ($did == 2 || $did == 7) { dpf.check black }
  if ($did == 3 || $did == 8) { dpf.check red }
  if ($did == 4 || $did == 9) { dpf.check green }
  if ($did == 5 || $did == 10) { dpf.check yellow }
  if ($did == 15) { .server -mz irc.mircaddict.net -j #mIRCaddict }
  if ($did == 6) { .run " $+ $scriptdirdpfhelp.txt $+ " }
  if ($did == 12) { .url http://www.mircscripts.org }
}

alias dpf.check {
  if (!$1) { echo -a DPF ERROR: Please use the dialog to initiate Dead Pixel Finder | return }
  if (!$window(@DPF)) { window -dfpaw0 +ldf @DPF -5 -5 $calc($window(-1).w + 10) $calc($window(-1).h + 10) }
  if ($1 == black) { %dpf.color = 1 }
  if ($1 == red) { %dpf.color = 4 }
  if ($1 == green) { %dpf.color = 3 }
  if ($1 == yellow) { %dpf.color = 8 }
  dpf.draw %dpf.color
}

alias dpf.draw { clear @DPF | .drawfill @DPF $1 $1 -5 -5 0 0 }

menu @DPF {
  dclick:dpf.close
  Close:dpf.close
}

on *:keydown:@DPF:*: { 
  echo -a $keyval
  if ($keyval == 27) { dpf.close }
}

alias dpf.close {
  if (!$window(@DPF)) { 
    echo -a DPF ERROR: Dead Picture Finder is not active. 
    return 
  } 
  .window -c @DPF
}

menu status,menubar,channel {
  Dead Pixel Finder
  .Start:dpf
  .-
  .Color:
  ..Black:dpf.check black
  ..Red:dpf.check red
  ..Green:dpf.check green
  ..Yellow:dpf.check yellow
  .Help:run " $+ $scriptdirdpfhelp.txt $+ "
  .-
  .Unload: {
    echo -a DPF: Unsetting variables...
    .unset %dpf.*
    echo -a DPF: Unloading $script $+ ...
    .timer -m 1 0 .unload -rs " $+ $script $+ "
    echo -a DPF: Unload Complete.
  }
}