/ScriptServ

; Auto Ghoster (for Unreal)
; by ch1zra
; ch1zra@gmail.com
; http://uptheirons.co.sr/
; #Scripters @ irc.krstarica.com
; Copyright © Up The Irons ! inc.

; <----------------------- $Load and $UnLoad ----------------------->

on 1:load: {
  if ($version > 6.0) { 
    echo -s   $+ $color(info) $+ *** Auto Ghoster (for Unreal)
    echo -s   $+ $color(info) $+ *** by ch1zra loaded
    echo -s   $+ $color(info) $+ *** 4 $+ http://uptheirons.co.sr/ $+ 
    writeini $scriptdirGhoster.ini Settings Enabled 1
    writeini $scriptdirGhoster.ini Settings Cmd ns     
    writeini $scriptdirGhoster.ini Settings ChangeBack 1
    writeini $scriptdirGhoster.ini Info Nick $mnick
  }
  else { 
    echo  Version 6.0 or higher recommended, get a newer version of mirc at http://www.mirc.com 
    .unload -rs $script
  } 
}

on 1:unload: {
  echo -s   $+ $color(info) $+ *** Auto Ghoster (for Unreal)
  echo -s   $+ $color(info) $+ *** by ch1zra unloaded
  echo -s   $+ $color(info) $+ *** 4 $+ http://uptheirons.co.sr/ $+ 
  .remove $scriptdirGhoster.ini
}

; <----------------------- $Aliases ----------------------->

alias -l ghoster {
  if ($dialog(ghoster)) {
    dialog -vde ghoster ghoster 
  }
  else { dialog -mod ghoster ghoster }
}

alias -l about.ghoster {
  if ($dialog(about.ghoster)) {
    dialog -vde about.ghoster about.ghoster 
  }
  else { dialog -moad about.ghoster about.ghoster }
}

; <----------------------- $Dialogs ----------------------->

dialog ghoster {
  title "Auto Ghoster (for Unreal) by ch1zra"
  size -1 -1 185 60
  option dbu
  check "Enable Auto Ghoster", 1, 5 5 60 10, flat
  text "Nick:", 2, 5 20 15 8
  edit "", 3, 35 20 50 10, autohs limit 32
  text "Password :", 4, 5 30 30 8
  edit "", 5, 35 30 50 10, pass autohs
  radio "Use ''/msg nickserv ghost''", 6, 90 10 80 10, flat
  radio "Use ''/ns ghost''", 7, 90 20 50 10, flat
  check "Change nick back after ghosting", 8, 90 30 90 10, flat
  text "http://uptheirons.co.sr/", 9, 5 45 60 8, disable
  button "About", 10, 125 45 25 10, flat
  button "Close", 11, 155 45 25 10, flat ok
}

dialog about.ghoster {
  title "About Auto Ghoster"
  size -1 -1 130 110
  option dbu
  text "Auto Ghoster is made for those chatters with bad connection.", 1, 5 5 120 16, center
  text "If you find it useful, good for you :)", 2, 5 20 120 8, center
  text "Contact info :", 3, 5 43 37 8
  text "If you don't, I won't cry :P", 5, 5 30 120 8, center
  text "¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯", 6, 5 40 120 3, center
  text "ch1zra@gmail.com", 7, 5 51 120 7
  text "http://uptheirons.co.sr/", 8, 5 59 120 7
  text "#Scripters @ irc.krstarica.com", 9, 5 67 120 7
  text "Copyright © Up The Irons ! inc. Scripting Team ", 10, 5 84 120 7
  text "¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯", 4, 5 75 120 8, center
  button "Okay, whatever... close now :)", 11, 5 95 120 10, flat ok
}

; <----------------------- $DEvents ----------------------->

on *:dialog:ghoster:init:*: {
  did -a $dname 3 $readini($scriptdirGhoster.ini,Info,Nick)
  did -a $dname 5 $readini($scriptdirGhoster.ini,Info,Pwd)
  if ($readini($scriptdirGhoster.ini,Settings,Enabled) == 0) {
    did -b $dname 2,3,4,5,6,7,8
  }
  else did -c $dname 1
  if ($readini($scriptdirGhoster.ini,Settings,Cmd) == msg) {
    did -c $dname 6
  }
  else   did -c $dname 7
  if ($readini($scriptdirGhoster.ini,Settings,ChangeBack) == 1) {
    did -c $dname 8
  }
}

on *:dialog:ghoster:close:*: {
  if ($did(3) != $null) writeini $scriptdirGhoster.ini Info Nick $did(3)
  if ($did(5) != $null) writeini $scriptdirGhoster.ini Info Pwd $did(5)
}

on *:dialog:about.ghoster:close:*: {
  if ($dialog(ghoster)) {
    dialog -vde ghoster ghoster 
  }
}

on *:dialog:ghoster:sclick:*: {
  if ($did == 1) {
    if ($did(1).state == 1) {
      did -e $dname  2,3,4,5,6,7,8
      writeini $scriptdirGhoster.ini Settings Enabled 1
    }
    else {
      did -b $dname 2,3,4,5,6,7,8
      writeini $scriptdirGhoster.ini Settings Enabled 0
    }
  }
  if ($did == 6) {
    writeini $scriptdirGhoster.ini Settings Cmd msg
  }
  if ($did == 7) {
    writeini $scriptdirGhoster.ini Settings Cmd ns
  }
  if ($did == 8) {
    if ($did(8).state == 1) {
      writeini $scriptdirGhoster.ini Settings ChangeBack 1
    }
    else {
      writeini $scriptdirGhoster.ini Settings ChangeBack 0
    }
  }
  if ($did == 10) {
    dialog -i ghoster
    about.ghoster
  }
}

; <----------------------- $IRCEvents ----------------------->

raw 433:*: {
  if ($readini($scriptdirGhoster.ini,Settings,Enabled) == 1) {
    if ($2 == $readini($scriptdirGhoster.ini,Info,Nick)) {
      echo -s [4Auto 4Ghoster] ghosting nick :  $+ $readini($scriptdirGhoster.ini,Info,Nick)
      if ($readini($scriptdirGhoster.ini,Settings,Cmd) == msg) {
        msg nickserv ghost $readini($scriptdirGhoster.ini,Info,Nick) $readini($scriptdirGhoster.ini,Info,pwd)
      }
      if ($readini($scriptdirGhoster.ini,Settings,Cmd) == ns) {
        ns ghost $readini($scriptdirGhoster.ini,Info,Nick) $readini($scriptdirGhoster.ini,Info,pwd)
      }
      HaltDef
    }
  }
}

on *:QUIT: {
  if ($readini($scriptdirGhoster.ini,Settings,ChangeBack) == 1) {
    if ($nick == $readini($scriptdirGhoster.ini,Info,Nick)) {
      echo -s [4Auto 4Ghoster] restoring nick :  $+ $readini($scriptdirGhoster.ini,Info,Nick)
      nick $readini($scriptdirGhoster.ini,Info,Nick)
    }
  } 
}

; <----------------------- $Menus ----------------------->

menu status,channel,query {
  Auto Ghoster:ghoster
}

menu menubar {
  Auto  Ghoster
  .Settings:ghoster
  .About:about.ghoster
  .-
  .Unload
  ..Yes:.unload -rs $script
}


; Auto Ghoster (for Unreal)
; by ch1zra
; ch1zra@gmail.com
; http://uptheirons.co.sr/
; #Scripters @ irc.krstarica.com
; Copyright © Up The Irons ! inc.