PokeRadar Script — File Browser
PokeRadarScriptv1.3.3 / PokeRadarScriptv1.3.3 / release1.3.3 / pokeradar.mrc
pokeradar.mrc — 12.6 KB — Download this file
alias -l pversion { return 1.3.3 }
alias pokeradar {
opendialog pokeradar $true
}
alias slots {
opendialog slots $true
}
alias phelp {
opendialog help $true
}
alias travel {
opendialog travel $true
}
alias evs {
opendialog evs $true
}
menu channel {
.-
.PokeRadar
..PokeRadar: pokeradar
..Travel: travel
..Slots: slots
..Help: phelp
..EVs: evs
..Update: checkupdate
}
on *:LOAD: {
if (%pokeradar_botname == $null) {
set %pokeradar_botname PokeWorldBot
set %pokeradar_pokeradar_auto on
set %pokeradar_travel_auto on
set %pokeradar_help_auto off
set %pokeradar_evs_auto off
set %pokeradar_slots_auto off
set %pokeradar_update_auto on
}
}
on *:TEXT:*:?: {
if ($nick == $botname) {
var %text $strip($1-)
if ($regex(%text,/^<> .*\(.*\): .* <>?$/)) {
var %text $remove($remove(%text,<),>)
if ($regex(%text,/.*Pok.Radar.*/)) {
opendialog pokeradar
var %place $gettok(%text,1,32)
var %place $gettok(%place,2,40)
var %place $gettok(%place,1,41)
did -o pokeradar 2 1 %place
did -r pokeradar 4
}
var %i 2
while (%i <= $numtok(%text,32)) {
var %loop = $gettok(%text,%i,32)
if (%loop == $chr(45)) { inc %i | continue }
var %shinytext $remove($gettok($gettok(%loop,2,40),3,47),$chr(41))
if (%shinytext == $chr(42)) var %shiny 2
else var %shiny 1
did -a pokeradar 4 + 0 0 %shiny $gettok(%loop,1,40) $+ $chr(9) $+ + 0 0 0 $remove($gettok($gettok(%loop,2,40),1,47),$chr(41)) $+ $chr(9) $+ + 0 0 0 $remove($gettok($gettok(%loop,2,40),2,47),$chr(41))
inc %i
}
}
if ($regex(%text,/^<>.* Help Topics: .* <>/)) {
var %text $remove(%text,<>)
opendialog help
if ($1 == Help) did -r 1
if ($gettok(%text,1,32) == More) var %i 4
else var %i 3
while (%i <= $numtok(%text,32)) {
var %loop = $gettok(%text,%i,32)
if (%loop == $chr(45)) { inc %i | continue }
did -a help 1 + 0 0 0 %loop
inc %i
}
}
}
}
on *:NOTICE:*:*: {
var %text $strip($1-)
if ($nick == $botname) {
if (attacks isin %text) {
if ($dialog(pokeradar)) {
var %text $remove(%text,<>)
var %move1 $gettok($gettok(%text,2,58),1,40)
did -e pokeradar 5
did -ra pokeradar 5 %move1
var %move2 $gettok($gettok(%text,3,41),1,40)
did -e pokeradar 6
did -ra pokeradar 6 %move2
var %move3 $gettok($gettok(%text,5,41),1,40)
did -e pokeradar 7
did -ra pokeradar 7 %move3
var %move4 $gettok($gettok(%text,7,41),1,40)
did -e pokeradar 8
did -ra pokeradar 8 %move4
}
}
if ($regex(%text,/<> Places you can go in .*: .* <>/)) {
var %text $remove(%text,<>)
opendialog travel
did -r travel 1
var %i 8
while (%i <= $numtok(%text,32)) {
var %loop $gettok(%text,%i,32)
did -a travel 1 + 0 0 0 $gettok(%loop,1,40)
inc %i
}
}
if ($regex(%text,/<> Attack time left: .* <>/)) {
if ($dialog(pokeradar)) {
var %text $remove(%text,<>)
did -ra pokeradar 21 $gettok(%text,4,32)
}
}
if ($regex(%text,/<> Travel time left: .* <>/)) {
if ($dialog(travel)) {
var %text $remove(%text,<>)
did -ra travel 5 $gettok(%text,4,32)
}
}
if ($regex(%text,/<> Your active team is as follows: .* <>/)) {
if ($dialog(pokeradar)) {
var %text $remove(%text,<>)
var %i 7
var %buttonid 22
while (%i <= $numtok(%text,32)) {
var %loop = $gettok(%text,%i,32)
did -e pokeradar %buttonid
did -ra pokeradar %buttonid $gettok(%loop,1,40)
inc %i
inc %buttonid
}
}
}
}
if ($regex(%text,/\(.*'s current EVs: .* HP, .* Attack, .* Defense, .* Speed, .* SAttack, and .* SDefense\. Total EVs gained: .* Total EVs left: .*\.\)/)) {
if (modified isin %text) var %i 15
else var %i 4
var %buffer
echo -a HP: $restevs($gettok(%text,%i,32)) $+ , Attack: $restevs($gettok(%text,$calc(%i + 2),32)) $+ , Defense: $restevs($gettok(%text,$calc(%i + 4),32)) $+ , Speed: $restevs($gettok(%text,$calc(%i + 6),32)), SAttack: $restevs($gettok(%text,$calc(%i + 8),32)) $+ , SDefense: $restevs($gettok(%text,$calc(%i + 11),32))
}
}
alias -l restevs {
var %res $abs($calc($calc($1 % 4) - 4)))
var %res $iif(%res == 4,0,%res)
return %res
}
dialog pokeradar {
title "PokeRadar"
size -1 -1 400 600
option pixels
text "Login", 11, 25 20 50 25
edit "", 12, 100 20 100 20, pass
button "Submit", 13, 210 20 75 25
text "Place", 1, 25 50 50 25
edit "", 2, 100 50 100 20
button "Submit", 10, 210 49 75 25
text "Pokemon", 3, 25 75 50 25
list 4, 100 75 220 400, size extsel
button "Attack 1", 5, 25 480 75 25, disable
button "Attack 2", 6, 105 480 75 25, disable
button "Attack 3", 7, 185 480 75 25, disable
button "Attack 4", 8, 265 480 75 25, disable
button "Get attacks", 9, 105 508 75 25
button "Read", 14, 340 75 45 25
button "Aura", 15, 340 100 45 25
button "Add line", 16, 340 125 45 25
check "Training", 17, 190 508 75 25
button "Goto", 18, 288 49 50 25
button "Accept open", 19, 327 150 70 25
button "ATL", 20, 340 175 45 25
;text "Time Left", 21, 340 200 45 25
button "Pokemon", 22, 25 541 75 25, disable
button "Pokemon", 23, 105 541 75 25, disable
button "Pokemon", 24, 185 541 75 25, disable
button "Pokemon", 25, 265 541 75 25, disable
button "Pokemon", 26, 25 570 75 25, disable
button "Pokemon", 27, 265 570 75 25, disable
button "Get pokemon", 28, 140 570 75 25
button "Pokeinfo", 29, 327 225 70 25
button "Leave", 30, 340 49 50 25
button "Wake up", 31, 20 100 60 25
check "Stay on top", 32, 13 125 80 20
button "Logout", 33, 285 20 75 25
button "EV", 34, 340 250 45 25
button "Clear List", 35, 327 200 70 25
button "Cancel Attk", 36, 15 145 70 25
button "Start Training", 37, 10 170 80 25
button "Stats", 38, 20 195 65 25
text v $+ $pversion, 39, 360 580 65 25
}
dialog travel {
title "Travel"
size -1 -1 200 470
option pixels
list 1, 50 10 104 400, size extsel
button "Get Kanto", 2, 10 410 65 25
button "Travel", 3, 75 410 65 25
button "TTL", 4, 140 410 55 25
text "Time Left", 5, 80 435 55 25
}
dialog slots {
title "Slots"
size -1 -1 75 25
option pixels
button "`Slots" 1, 0 0 75 25
}
dialog help {
title "Help"
size -1 -1 200 600
option pixels
list 1, 0 0 200 550
button "Get help", 2, 0 550 100 50
button "Read help", 3, 100 550 100 50
}
dialog evs {
title "EV Helper"
size -1 -1 300 300
option pixels
edit "", 1, 120 20 150 20
text "Track EV Pokemon:", 2, 20 20 100 25
button "Delete Track", 3, 120 45 75 25
button "List EVs", 4, 195 45 75 25
text "Inc EV Pokemon:", 5, 20 95 100 20
edit "", 6, 120 95 150 20
button "Track EVs", 7, 45 45 75 25
button "EV", 8, 45 115 75 25
button "Inc EV", 9, 120 115 75 25
button "Dec EV", 10, 195 115 75 25
button "Whole EVs", 11, 20 245 260 25
button "HP-Up", 12, 45 165 75 25
button "PP-Up", 13, 120 165 75 25
button "Calcium", 14, 195 165 75 25
button "Carbos", 15, 45 190 75 25
button "Iron", 16, 120 190 75 25
button "Protein", 17, 195 190 75 25
button "Zinc", 18, 120 215 75 25
}
on *:DIALOG:help:*:*: {
if ($devent == init) {
setmdx $dname 1
did -i $dname 1 1 headerdims 198:1
did -i $dname 1 1 headertext + 0 Help Topics
checkupdate
}
if ($devent == sclick) {
if ($did == 2) toch `help
if ($did == 3) topm `help $getsel($dname, 1)
}
}
on *:DIALOG:travel:*:*: {
if ($devent == init) {
setmdx $dname 1
did -i $dname 1 1 headerdims 100:1
did -i $dname 1 1 headertext + 0 Kanto
checkupdate
}
if ($devent == sclick) {
if ($did == 2) toch `pokeNav Kanto
if ($did == 3) toch `travel $getsel($dname, 1)
if ($did == 4) toch `ttl
}
}
on *:DIALOG:slots:sclick:1: { toch `slots }
on *:DIALOG:pokeradar:*:*:{
if ($devent == init) {
setmdx $dname 4 checkboxes sortascending
did -i $dname 4 1 headerdims 120:1 40:2 30:3
did -i $dname 4 1 headertext + 0 Pokemon $+ $chr(9) $+ + 0 Level $+ $chr(9) $+ + 0 M/F
checkupdate
}
if ($devent == sclick) {
if ($did == 9) toch `attacks
if (($did > 4) && ($did < 9)) {
if ($did($dname,17).state == 1) toch `train $did($dname,$did)
else toch ` $+ $did($dname,$did) $getsel($dname, 4)
}
if ($did == 10) toch `entered $did($dname,2)
if ($did == 13) topm `login $did($dname,12)
if ($did == 14) toch `read $getsel($dname, 4)
if ($did == 15) toch `aura $getsel($dname, 4)
if ($did == 16) { addline $?="Name:" | dialog -v $dname }
if ($did == 18) toch ` $+ $did($dname,2)
if ($did == 19) toch `accept open $getsel($dname, 4)
if ($did == 20) toch `atl
if ($did == 21) toch `ttl
if (($did > 21) && ($did < 28)) toch `switch $did($dname,$did)
if ($did == 28) toch `team
if ($did == 29) toch `pokeinfo $getsel($dname, 4)
if ($did == 30) toch `leave $did($dname,2)
if ($did == 31) toch `wake up
if ($did == 32) {
if ($did($dname,$did).state == 1) dialog -o pokeradar
else dialog -n pokeradar
}
if ($did == 33) toch `logout
if ($did == 34) toch `ev $getsel($dname, 4)
if ($did == 35) did -r $dname 4
if ($did == 36) toch `cancel
if ($did == 37) { toch `start training $?="Punchbag Name:" | dialog -v $dname | did -c $dname 4 }
if ($did == 38) { toch `stats }
}
}
alias -l addline {
did -a pokeradar 4 + 0 0 0 $1 $+ $chr(9) $+ + 0 0 0 $chr(9) $+ + 0 0 0
}
on *:DIALOG:evs:*:*: {
if ($devent == sclick) {
if ($did == 3) toch `deletetracker $did($dname,1)
if ($did == 4) toch `evstats $did($dname,1)
if ($did == 7) toch `trackev $did($dname,1)
if ($did == 8) toch `ev $did($dname,6)
if ($did == 9) toch `incev $did($dname,1) $did($dname,6)
if ($did == 10) toch `decev $did($dname,1) $did($dname,6)
if ($did == 11) toch `evstats $did($dname,1)
if (($did > 11) && ($did < 19)) toch `use $did($dname,$did).text
}
}
alias checkupdate {
if ($sock(pokeupdate)) sockclose pokeupdate
sockopen pokeupdate freewebs.com 80
}
on *:SOCKOPEN:pokeupdate: {
sockwrite -nt $sockname GET /pokeradarscript/pokeradar.mrc HTTP/1.0
sockwrite -nt $sockname Host: www.freewebs.com
sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:pokeupdate: {
if ($sockerr) { echo -a Socket Error: $sockerr | sockclose $sockname }
var %t
sockread %t
if (($gettok(%t,6,32) != $pversion) && ($gettok(%t,3,32) == pversion) && ($remove($gettok(%t,5,32),n) == retur)) {
echo -a Must update! The version you are using is: ( $+ $pversion $+ ) and the latest is ( $+ $gettok(%t,6,32) $+ )!
doupdate
sockclose $sockname
}
}
on *:SOCKOPEN:doupdate: {
sockwrite -nt $sockname GET /pokeradarscript/pokeradar.mrc HTTP/1.0
sockwrite -nt $sockname Host: www.freewebs.com
sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:doupdate: {
if ($sockerr) { echo -a Socket Error: $sockerr | sockclose $sockname }
var %t
sockread %t
if ((!%firstal) && ($remove($gettok(%t,1,32),s) == alia)) set %firstal $true
if (%firstal) write $qt($mircdir $+ temp.mrc) %t
}
on *:SOCKCLOSE:doupdate: {
var %thisf $qt($script)
var %tempf $qt($mircdir $+ temp.mrc)
echo -a Removing %thisf
remove %thisf
echo -a Renaming %tempf to %thisf
rename %tempf %thisf
unset %firstal
echo -a Update finished.
load -rs %thisf
}
alias -l doupdate {
if ($sock(doupdate)) sockclose doupdate
sockopen doupdate freewebs.com 80
echo -a Update connecting...
}
alias -l toch {
msg #Pokeworld $1-
}
alias -l topm {
msg $botname $1-
}
alias -l getsel {
return $gettok($gettok($did($1,$2).seltext,1,9),6,32)
}
alias -l pmdx {
dll mdx\mdx.dll $1-
}
alias -l pviews {
return $+($mircdir,mdx\views.mdx)
}
alias -l setmdx {
pmdx SetMircVersion $version
pmdx MarkDialog $1 $dialog($1).hwnd
pmdx SetControlMDX $1 $2 listview report nolabelwrap grid headerdrag single rowselect showsel $3- > $pviews
}
alias -l opendialog {
if (($2 == $true) || ($dialog($1))) {
if ($dialog($1)) dialog -x $1
dialog -mrd $1 $1
}
elseif (%pokeradar_ [ $+ [ $1 ] ] $+ _auto == on) opendialog $true
else halt
}
alias -l botname {
if (%pokeradar_botname) return %pokeradar_botname
else {
set %pokeradar_botname PokeWorldBot
return $botname
}
}
alias pokeradarversion { return $pversion }