/ScriptServ

;System Info [02/07/2009] by MTec89
;to open System Info type /si


;#DIALOGS
dialog si {
  title "System Info [/si]"
  size %si.hor %si.vert 526 93
  option pixels
  text "Server Up", 1, 1 1 49 16
  text "SERVER UP", 2, 50 1 190 20
  text "Win Up", 3, 1 43 49 16
  text "WIN UP", 4, 50 43 190 20
  text "mIRC Up", 5, 2 22 49 16
  text "MIRC UP", 6, 50 22 190 20
  text "Idle For:", 7, 1 64 49 16
  text " TIME", 8, 50 64 190 20
  text "DCC GETS", 9, 242 1 133 20
  text "DCC SENDS", 10, 242 22 133 20
  text "DATE", 11, 242 43 133 20
  button "Config", 12, 242 64 49 24
  button "Spam It", 13, 293 64 57 24
  button "<", 17, 352 64 22 24
  text "0 0 100", 14, 377 1 85 20
  text "CPU:", 19, 463 1 26 20
  text "CPU2", 25, 491 1 35 20
  text "0 0 100", 16, 377 22 85 20
  text "RAM:", 21, 463 22 27 20
  text "RAM2", 23, 491 22 35 20
}
dialog siconfig {
  title "Config"
  size -1 -1 440 327
  option pixels
  tab "Tab 1", 1, -11 -32 500 500
  tab "Tab 2", 13
  tab "Tab 5", 51
  tab "Tab 6", 68
  tab "Tab 7", 25
  box "Spam Command", 2, 103 1 334 297, tab 1
  radio "/me", 3, 106 26 160 13, tab 1
  radio "/ame", 4, 106 64 106 13, tab 1
  radio "/echo -s", 5, 106 44 151 13, tab 1
  radio "/echo -a", 6, 106 84 112 13, tab 1
  radio "/msg $active", 7, 106 104 126 13, tab 1
  radio "/msg", 8, 106 124 53 13, tab 1
  edit "#chan OR nick", 9, 161 121 188 20, tab 1
  radio "Advanced2 [/me to active, unless its a status]", 10, 106 164 282 13, tab 1
  radio "Advanced [/msg to active, unless its a status]", 11, 106 144 271 13, tab 1
  text "These options will let you decide how and where you want to spam your information. you may only choose one of these options. If you choose the /msg option with the text box you must not leave it say (#chan OR Nick). You Must enter either a #channel name or a NickName", 12, 109 184 316 86, tab 1
  box "Spam Stuff", 14, 103 1 334 297, tab 13
  check "Current Nick", 15, 109 24 125 18, tab 13
  check "Current Server:port", 16, 109 44 125 18, tab 13
  check "Server Uptime", 17, 109 64 125 18, tab 13
  check "mIRC Uptime", 18, 109 84 125 18, tab 13
  check "Windows Uptime", 19, 109 104 125 18, tab 13
  check "Idle time", 20, 109 124 125 18, tab 13
  check "Time and Date", 21, 109 144 125 18, tab 13
  check "DCC Sends and Gets", 22, 109 164 125 18, tab 13
  text "These options spam the related info into whatever option you have set for spamming. For example checking (Current Nick) will send a message like this: [Nick: YourNick] and checking (Current Server:port) will send a message like this: [Server: xx.xx.xx:6667] ect...ect... checking these options will send that info while unchecking it will not send that info.", 23, 245 21 181 166, tab 13
  box "Brackets", 24, 245 189 99 78, tab 13
  text "Left:", 27, 252 212 28 16, tab 13
  edit "", 28, 284 210 54 21, tab 13 center
  text "Right:", 29, 252 233 28 16, tab 13
  edit "", 30, 284 230 54 21, tab 13 center
  check "Ram Information", 106, 109 184 125 18, tab 13
  check "CPU Information", 108, 109 204 125 18, tab 13
  box "About", 52, 103 1 334 297, tab 51
  text "System Info %si.ver by MTec89 (e-motz.com)", 53, 113 19 306 16, tab 51
  text "Your Version:", 54, 115 61 86 16, tab 51
  edit "[xx/xx/xxxx]", 55, 204 59 87 21, tab 51 read center
  text "Current Version:", 56, 115 84 87 16, tab 51
  button "Check For New Version", 57, 293 59 125 21, tab 51
  box "Version System", 58, 109 40 322 91, tab 51
  edit "[xx/xx/xxxx]", 61, 204 81 87 21, tab 51 read center
  button "Get Current Version", 62, 293 81 125 21, tab 51
  box "Misc.", 69, 103 1 334 297, tab 68
  box "DCCs", 75, 110 19 315 91, tab 68
  check "Track DCC Sends and Gets", 76, 116 37 160 20, tab 68
  box "Time and Date", 77, 109 114 315 43, tab 68
  text "Seperate Time and Date with this Character:", 78, 117 132 220 17, tab 68
  combo 79, 341 129 75 148, tab 68 size drop
  box "Edit DCC Numbers", 80, 299 36 121 69, tab 68
  text "Sends:", 81, 307 57 36 16, tab 68
  edit "", 82, 346 54 28 21, tab 68 center
  text "/", 83, 375 57 8 16, tab 68
  edit "", 84, 384 54 28 21, tab 68 center
  text "Gets:", 85, 316 77 27 16, tab 68
  edit "", 86, 346 74 28 21, tab 68 center
  text "/", 87, 375 77 8 16, tab 68
  edit "", 88, 384 74 28 21, tab 68 center
  button "Reset Sends", 89, 119 61 87 19, tab 68
  button "Reset Gets", 90, 209 61 87 19, tab 68
  button "Clear Send Fails", 91, 119 82 87 19, tab 68
  button "Clear Get Fails", 92, 209 82 87 19, tab 68
  box "Dialog Toggle", 99, 109 163 315 75, tab 68
  check "Enable Toggle Using", 100, 116 179 123 20, tab 68
  edit "FX", 101, 243 177 33 21, tab 68 center
  text "This feature allows you to open or close the main dialog using an (F) key", 102, 118 201 297 28, tab 68
  box "StartUp", 115, 109 238 315 55, tab 68
  check "StartUp at StartUp", 116, 116 254 116 20, tab 68
  text "Open the main dialog when mIRC starts.", 117, 241 252 175 34, tab 68
  box "RAM/CPU", 26, 103 1 334 297, tab 25
  box "Update Interval", 70, 110 13 321 43, tab 25
  check "Auto-Update Stats", 71, 115 29 109 20, tab 25
  text "Every", 72, 302 31 32 16, tab 25
  edit "", 73, 336 27 43 21, tab 25 center
  text "Seconds", 74, 381 31 45 16, tab 25
  box "CPU", 109, 110 124 321 60, tab 25
  box "RAM", 31, 110 58 321 62, tab 25
  text "RAM Meter, showing how much RAM you are using", 97, 115 73 294 16, tab 25
  check "Enable RAM Meter", 98, 115 92 116 20, tab 25
  text "Update Ram every", 103, 241 96 94 16, tab 25
  edit "", 104, 336 94 43 21, tab 25 center
  text "Seconds", 105, 381 95 46 16, tab 25
  text "Seconds", 114, 381 161 44 16, tab 25
  edit "", 113, 336 159 43 21, tab 25 center
  text "CPU Meter, Show how much of your CPU you are using", 110, 115 139 295 16, tab 25
  text "Update CPU every", 112, 242 162 92 16, tab 25
  check "Enable CPU Meter", 111, 115 159 113 20, tab 25
  button "O.K.", 93, 395 303 40 20, ok
  list 94, 0 4 100 292, size
}




;#DIALOG EVENTS
on *:dialog:siconfig:*:*: {
  if ($devent == edit) {
    if ($did == 9) { set %si.sp.9 $did(9).text }
    if ($did == 28) { set %si.leftbrac $did(28).text }
    if ($did == 30) { set %si.rightbrac $did(30).text }
    if ($did == 73) { set %si.update $did(73).text }
    if ($did == 86) { set %si.dcc.get.succ $did(86).text }
    if ($did == 88) { set %si.dcc.get.tot $did(88).text }
    if ($did == 82) { set %si.dcc.send.succ $did(82).text }
    if ($did == 84) { set %si.dcc.send.tot $did(84).text }
    if ($did == 101) { set %si.d.tog.key $did(101).text | .disable #FKEY.* | .enable #FKEY. $+ %si.d.tog.key }
    if ($did == 104) { set %si.ram.sec $did(104).text }
    if ($did == 113) { set %si.cpu.sec $did(113).text }
  }

  if ($devent == sclick) {
    if ($did == 3) { did -u $dname 4,5,6,7,8,10,11 | did -b $dname 9 | set %si.sp.cmd /me }
    if ($did == 4) { did -u $dname 3,5,6,7,8,10,11 | did -b $dname 9 | set %si.sp.cmd /ame }
    if ($did == 5) { did -u $dname 3,4,6,7,8,10,11 | did -b $dname 9 | set %si.sp.cmd /echo -s }
    if ($did == 6) { did -u $dname 3,4,5,7,8,10,11 | did -b $dname 9 | set %si.sp.cmd /echo -a }
    if ($did == 7) { did -u $dname 3,4,5,6,8,10,11 | did -b $dname 9 | set %si.sp.cmd /msg $active }
    if ($did == 8) { did -u $dname 3,4,5,6,7,10,11 | did -e $dname 9 | set %si.sp.cmd 9 }
    if ($did == 10) { did -u $dname 3,4,5,6,7,8,11 | did -b $dname 9 | set %si.sp.cmd /mea }
    if ($did == 11) { did -u $dname 3,4,5,6,7,8,10 | did -b $dname 9 | set %si.sp.cmd /msga }
    if ($did == 15) { if ($did(15).state == 1) set %si.sp.nick 1 | else set %si.sp.nick 0 }
    if ($did == 16) { if ($did(16).state == 1) set %si.sp.server 1 | else set %si.sp.server 0 }
    if ($did == 17) { if ($did(17).state == 1) set %si.sp.servup 1 | else set %si.sp.servup 0  }
    if ($did == 18) { if ($did(18).state == 1) set %si.sp.mircup 1 | else set %si.sp.mircup 0  }
    if ($did == 19) { if ($did(19).state == 1) set %si.sp.winup 1 | else set %si.sp.winup 0 }
    if ($did == 20) { if ($did(20).state == 1) set %si.sp.idle 1 | else set %si.sp.idle 0 }
    if ($did == 21) { if ($did(21).state == 1) set %si.sp.timedate 1 | else set %si.sp.timedate 0 }
    if ($did == 22) { if ($did(22).state == 1) set %si.sp.dccs 1 | else set %si.sp.dccs 0 }
    if ($did == 25) { if ($did(25).state == 1) did -e $dname 32,34,36 | set %si.sp.colors 1 | else set %si.sp.colors 0 | did -b $dname 32,34,36 }
    if ($did == 57) { sicheckver }
    if ($did == 62) { sigetver }
    if ($did == 71) {
      if ($did(71).state == 1) { set %si.updte 1 | did -e $dname 73 | si2 }
      else { set %si.updte 0 | did -b $dname 73 }
    }
    if ($did == 76) {
      if ($did(76).state == 1) { set %si.dcc 1 | did -e $dname 82,84,86,88,89,90,91,92,22 | si2 }
      else { set %si.dcc 0 | did -b $dname 82,84,86,88,89,90,91,92,22 }
    }
    if ($did == 79) { set %si.td.sep $did(siconfig,79).sel }
    if ($did == 91) { set %si.dcc.send.succ %si.dcc.send.tot }
    elseif ($did == 92) { set %si.dcc.get.succ %si.dcc.get.tot }
    elseif ($did == 89) { set %si.dcc.send.succ 0 | set %si.dcc.send.tot 0 }
    elseif ($did == 90) { set %si.dcc.get.succ 0 | set %si.dcc.get.tot 0 }
    if ($did == 94) {
      if ($did(94).seltext == Spam Commands) { did -f $dname 1 | did -f $dname 94 }
      if ($did(94).seltext == Spam Stuff) { did -f $dname 13 | did -f $dname 94 }
      if ($did(94).seltext == Misc) { did -f $dname 68 | did -f $dname 94 }
      if ($did(94).seltext == About) { did -f $dname 51 | did -f $dname 94 }
      if ($did(94).seltext == RAM/CPU) { did -f $dname 25 | did -f $dname 94 }
    }
    if ($did == 98) { 
      if ($did(98).state == 1) { set %si.ram 1 | did -e $dname 104 }
      else { set %si.ram 0 | did -b $dname 104 }
    }
    if ($did == 100) { 
      if ($did(100).state == 1) { set %si.d.tog 1 | did -e siconfig 101 | .enable #FKEY. $+ %si.d.tog.key }
      else { set %si.d.tog 0 | did -b $dname 101 | .disable #FKEY.* }
    }
    if ($did == 106) { 
      if ($did(106).state == 1) { set %si.sp.ram 1 }
      else { set %si.sp.ram 0 }
    }
    if ($did == 108) { 
      if ($did(108).state == 1) { set %si.sp.cpu 1 }
      else { set %si.sp.cpu 0 }
    }
    if ($did == 111) { 
      if ($did(111).state == 1) { set %si.cpu 1 | did -e $dname 113 }
      else { set %si.cpu 0 | did -b $dname 113 }
    }
    if ($did == 116) { 
      if ($did(116).state == 1) { set %si.start 1 }
      else { set %si.start 0 }
    }

    did -ra siconfig 86 %si.dcc.get.succ
    did -ra siconfig 88 %si.dcc.get.tot
    did -ra siconfig 82 %si.dcc.send.succ
    did -ra siconfig 84 %si.dcc.send.tot
  }

  if ($devent == init) {
    did -a $dname 94 Spam Commands
    did -a $dname 94 Spam Stuff
    did -a $dname 94 Misc
    did -a $dname 94 RAM/CPU
    did -a $dname 94 About
    did -ra $dname 9 %si.sp.9
    did -ra $dname 28 %si.leftbrac
    did -ra $dname 30 %si.rightbrac
    did -ra $dname 55 %si.ver
    did -ra $dname 53 System Info %si.ver by MTec89 (e-motz.com)
    did -ra $dname 73 %si.update
    did -ra $dname 86 %si.dcc.get.succ
    did -ra $dname 88 %si.dcc.get.tot
    did -ra $dname 82 %si.dcc.send.succ
    did -ra $dname 84 %si.dcc.send.tot
    did -ra $dname 101 %si.d.tog.key
    did -ra $dname 104 %si.ram.sec
    did -ra $dname 113 %si.cpu.sec
    did -fc $dname 94 1
    did -b $dname 9

    var %i = 1
    while (%i < 256) { did -a $dname 79 $chr(%i) | inc %i }

    did -c $dname 79 %si.td.sep

    if (%si.sp.ram == 1) { did -c $dname 106 }
    if (%si.sp.cpu == 1) { did -c $dname 108 }
    if (%si.cpu == 1) { did -c $dname 111 }
    elseif (%si.cpu == 0) { did -b $dname 113 }
    if (%si.updte == 1) { did -c $dname 71 | did -e $dname 73 }
    elseif (%si.updte == 0) { did -b $dname 73 }
    if (%si.dcc == 1) { did -c $dname 76 }
    elseif (%si.dcc == 0) { did -b $dname 82,84,86,88,89,90,91,92,22 }
    if (%si.ram == 1) { did -c $dname 98 | did -e $dname 104 }
    elseif (%si.ram == 0) { did -u $dname 98 did -b $dname 104 }
    if (%si.d.tog == 1) { did -c $dname 100 | did -e $dname 101 }
    elseif (%si.d.tog == 0) { did -u $dname 100 | did -b $dname 101 }

    if (%si.sp.cmd == /me) { did -c $dname 3 }
    elseif (%si.sp.cmd == /ame) { did -c $dname 4 }
    elseif (%si.sp.cmd == /echo -s) { did -c $dname 5 }
    elseif (%si.sp.cmd == /echo -a) { did -c $dname 6 }
    elseif (%si.sp.cmd == /msg $active) { did -c $dname 7 }
    elseif (%si.sp.cmd == 9) { did -c $dname 8 | did -e $dname 9 }
    elseif (%si.sp.cmd == /mea) { did -c $dname 10 }
    elseif (%si.sp.cmd == /msga) { did -c $dname 11 }

    if (%si.sp.nick == 1) { did -c $dname 15 }
    if (%si.sp.server == 1) { did -c $dname 16 }
    if (%si.sp.servup == 1) { did -c $dname 17 }
    if (%si.sp.mircup == 1) { did -c $dname 18 }
    if (%si.sp.winup == 1) { did -c $dname 19 }
    if (%si.sp.idle == 1) { did -c $dname 20 }
    if (%si.sp.timedate == 1) { did -c $dname 21 }
    if (%si.sp.dccs == 1) { did -c $dname 22 }
    if (%si.start == 1) { did -c $dname 116 }
  }

  if ($devent == close) {
    %si.cfg.hor = $dialog($dname).x
    %si.cfg.vert = $dialog($dname).y
  }
}
on *:dialog:si:*:*: { 
  if ($devent == init) { 
    dll $udll MarkDialog $dname
    dll $udll SetMircVersion $version
    dll $udll SetBorderStyle 12,13,14,16,17 clientedge
    dll $udll SetControlMDX $dname 14 ProgressBar smooth > $scriptdirctl_gen.mdx
    dll $udll SetControlMDX $dname 16 ProgressBar smooth > $scriptdirctl_gen.mdx

    if (!$timer(sicpu)) { .timerSICPU -o 0 %si.cpu.sec $!sicpu }
    if (!$timer(siram)) { .timerSIRAM -o 0 %si.ram.sec $!siram }

    si2
  }
  if ($devent == close) {
    %si.hor = $dialog($dname).x
    %si.vert = $dialog($dname).y
    if ($timer(sicpu)) { .timerSICPU off }
    if ($timer(siram)) { .timerSIRAM off }
  }

  if ($devent == sclick) {
    if ($did == 12) { siconfig }
    elseif ($did == 13) { sispam }
    elseif ($did == 17) { sisize }
  }
}


;#ALIAS
alias sicpu {
  if (%si.cpu == 1) {
    if ($dialog(si)) {
      set %si.cpu.use $remove($right($dll($scriptdirmoo.dll,cpuinfo,_),9),$chr(40),$chr(41),$chr(37),Load)
      did -ra si 14 %si.cpu.use
      did -ra si 25 %si.cpu.use $+ %
    }
  }
  else { .timersicpu off }
}
alias siram {
  if (%si.ram == 1) {
    if ($dialog(si)) {
      set %si.ram.use $gettok($gettok($gettok($dll($qt($scriptdirmoo.dll),meminfo,_),3,32),1,40),1,46)
      did -ra si 16 %si.ram.use
      did -ra si 23 %si.ram.use $+ %
    }
  }
  else { .timersiram off }
}
alias sisize {
  if ($dialog(si).cw == 526) { set %si.wid 526 | /dialog -sp si %si.hor %si.vert 376 93 | did -ra si 17 > } 
  elseif ($dialog(si).cw == 376) { set %si.wid 376 | /dialog -sp si %si.hor %si.vert 526 93 | did -ra si 17 < }
}
alias sicheckver { sockopen siver e-motz.com 80 }
alias siver.close {
  if ($isFile(data.txt)) {
    var %lastline = $read(data.txt, $lines(data.txt))
    .remove data.txt
  }
  else var %lastline = Could not download file.
  did -ra siconfig 61 %lastline
  sockclose siver
}
alias sigetver { /run http://e-motz.com/node/4 }

#FKEY.F1 off
alias F1 si.d.tog
#FKEY.F1 end

#FKEY.cF1 off
alias cF1 si.d.tog
#FKEY.cF1 end

#FKEY.sF1 off
alias sF1 si.d.tog
#FKEY.sF1 end

#FKEY.F2 off
alias F2 si.d.tog
#FKEY.F2 end

#FKEY.cF2 off
alias cF2 si.d.tog
#FKEY.cF2 end

#FKEY.sF2 off
alias sF2 si.d.tog
#FKEY.sF2 end

#FKEY.F3 off
alias F3 si.d.tog
#FKEY.F3 end

#FKEY.cF3 off
alias cF3 si.d.tog
#FKEY.cF3 end

#FKEY.sF3 off
alias sF3 si.d.tog
#FKEY.sF3 end

#FKEY.F4 off
alias F4 si.d.tog
#FKEY.F4 end

#FKEY.cF4 off
alias cF4 si.d.tog
#FKEY.cF4 end

#FKEY.sF4 off
alias sF4 si.d.tog
#FKEY.sF4 end

#FKEY.F5 on
alias F5 si.d.tog
#FKEY.F5 end

#FKEY.cF5 off
alias cF5 si.d.tog
#FKEY.cF5 end

#FKEY.sF5 off
alias sF5 si.d.tog
#FKEY.sF5 end

#FKEY.F6 off
alias F6 si.d.tog
#FKEY.F6 end

#FKEY.cF6 off
alias cF6 si.d.tog
#FKEY.cF6 end

#FKEY.sF6 off
alias sF6 si.d.tog
#FKEY.sF6 end

#FKEY.F7 off
alias F7 si.d.tog
#FKEY.F7 end

#FKEY.cF7 off
alias cF7 si.d.tog
#FKEY.cF7 end

#FKEY.sF7 off
alias sF7 si.d.tog
#FKEY.sF7 end

#FKEY.F8 off
alias F8 si.d.tog
#FKEY.F8 end

#FKEY.cF8 off
alias cF8 si.d.tog
#FKEY.cF8 end

#FKEY.sF8 off
alias sF8 si.d.tog
#FKEY.sF8 end

#FKEY.F9 off
alias F9 si.d.tog
#FKEY.F9 end

#FKEY.cF9 off
alias cF9 si.d.tog
#FKEY.cF9 end

#FKEY.sF9 off
alias sF9 si.d.tog
#FKEY.sF9 end

#FKEY.F10 off
alias F10 si.d.tog
#FKEY.F10 end

#FKEY.cF10 off
alias cF10 si.d.tog
#FKEY.cF10 end

#FKEY.sF10 off
alias sF10 si.d.tog
#FKEY.sF10 end

#FKEY.F11 off
alias F11 si.d.tog
#FKEY.F11 end

#FKEY.cF11 off
alias cF11 si.d.tog
#FKEY.cF11 end

#FKEY.sF11 off
alias sF11 si.d.tog
#FKEY.sF11 end

#FKEY.F12 off
alias F12 si.d.tog
#FKEY.F12 end

#FKEY.cF12 off
alias cF12 si.d.tog
#FKEY.cF12 end

#FKEY.sF12 off
alias sF12 si.d.tog
#FKEY.sF12 end

alias si.d.tog {
  if ($dialog(si)) {
    if ($timer(siram)) { .timerSIRAM off }
    if ($timer(sicpu)) { .timerSICPU off }
    if ($timer(si)) { .timerSI off }
    %si.hor = $dialog(si).x
    %si.vert = $dialog(si).y
    dialog -x si si
  }
  else { si }
}
alias siconfig {
  if ($dialog(siconfig)) { dialog -x siconfig siconfig | dialog -mdo siconfig siconfig }
  else { dialog -mdo siconfig siconfig }
}
alias si2 { 
  if ($dialog(si)) {
    dialog -t si $me $iif($scid($activecid).server != $null, on $scid($activecid).server $+ : $+ $port,[Not Connected])

    did -ra si 2 $iif($scid($activecid).uptime,$duration($ifmatch),[Not Connected])
    did -ra si 4 $uptime(system,1)
    did -ra si 6 $uptime(mirc,1)
    did -ra si 8 $duration($scid($activecid).idle)

    did -ra si 9 dcc gets ( $+ %si.dcc.get.succ $+ / $+ %si.dcc.get.tot $+ ) 
    did -ra si 10 dcc sends ( $+ %si.dcc.send.succ $+ / $+ %si.dcc.send.tot $+ )
    did -ra si 11 $time $chr(%si.td.sep) $date
  }
  if (!$dialog(si)) {
    if ($timer(SI)) { .timerSI off }
  }
}
alias si {
  if ($dialog(si)) { dialog -x si si | dialog -ma si si | showmirc -x
    if (%si.updte == 1) { .timerSI -o 0 %si.update si2 }
  }
  else { dialog -ma si si | showmirc -x
    if (%si.updte == 1) { .timerSI -o 0 %si.update si2 }
  }
}
alias sisp3 { return $iif(%si.sp.nick == 1,%si.leftbrac $+ Nick: $me $+ %si.rightbrac $+ , ) $iif(%si.sp.server == 1,%si.leftbrac $+ Server: $iif($scid($activecid).server != $null, $scid($activecid).server $+ : $+ $port,[Not Connected]) $+ %si.rightbrac $+ , ) $iif(%si.sp.servup == 1,%si.leftbrac $+ Server UpTime: $uptime(server,1) $+ %si.rightbrac $+ , ) $iif(%si.sp.mircup == 1,%si.leftbrac $+ mIRC UpTime: $uptime(mirc,1) $+ %si.rightbrac $+ , ) $iif(%si.sp.cpu == 1,%si.leftbrac $+ CPU: $dll($qt($scriptdirmoo.dll),cpuinfo,_) %+ %si.rightbrac, ) }
alias sisp4 { return $iif(%si.sp.winup == 1,%si.leftbrac $+ Win $+ $os UpTime: $uptime(system,1) $+ %si.rightbrac $+ , ) $iif(%si.sp.idle == 1,%si.leftbrac $+ Idle: $duration($scid($activecid).idle) $+ %si.rightbrac $+ , ) $iif(%si.sp.timedate == 1,%si.leftbrac $+ Time&Date: $time $chr(%si.td.sep) $date $+ %si.rightbrac $+ , ) $iif(%si.sp.dccs == 1,%si.leftbrac $+ DCC Gets: %si.dcc.get.succ $+ / $+ %si.dcc.get.tot $+ %si.rightbrac $+ , ) $iif(%si.sp.dccs == 1,%si.leftbrac $+ DCC Sends: %si.dcc.send.succ $+ / $+ %si.dcc.send.tot $+ %si.rightbrac , ) $iif(%si.sp.ram == 1,%si.leftbrac $+ Memory $dll($qt($scriptdirmoo.dll),meminfo,_) %+ %si.rightbrac, ) }
alias sispam {
  if (%si.sp.cmd == /me) { /scid $activecid describe $active $sisp3 | /scid $activecid describe $active $sisp4 }
  if (%si.sp.cmd == /echo -s) { /scid $activecid echo -s $sisp3 | /scid $activecid echo -s $sisp4 }
  if (%si.sp.cmd == /echo -a) { /scid $activecid echo -a $sisp3 | /scid $activecid echo -a $sisp4 }
  if (%si.sp.cmd == /msg $ $+ active) { /scid $activecid msg $active $sisp3 | /scid $activecid msg $active $sisp4 }
  if (%si.sp.cmd == /mea) {
    if ($active == Status Window) { /scid $activecid echo -s $sisp3 | /scid $activecid echo -s $sisp4 }
    else { /scid $activecid describe $active $sisp3 | /scid $activecid describe $active $sisp4 }
  }
  if (%si.sp.cmd == /msga) { 
    if ($active == Status Window) { /scid $activecid echo -s $sisp3 | /scid $activecid echo -s $sisp4 }
    else { /scid $activecid msg $active $sisp3 | /scid $activecid msg $active $sisp4 }
  }
  if (%si.sp.cmd == 9) { /scid $activecid msg %si.sp.9 $sisp3 | /scid $activecid msg %si.sp.9 $sisp4 }
}
alias udll { return $qt($scriptdirmdx.dll) }
alias siabout { siconfig | did -f siconfig 51 | did -f siconfig 94 | did -c siconfig 94 6 }

;#OTHER STUFF
on 1:SOCKOPEN:siver: {
  if ($sockerr > 0) { return }
  sockwrite -n $sockname GET /uploads/si.txt HTTP/1.1
  sockwrite -n $sockname Host: e-motz.com
  sockwrite -n $sockname Connection: keep-alive
  sockwrite $sockname $crlf
  if ($isfile(data.txt)) { .remove data.txt }
}
on 1:SOCKREAD:siver: {
  sockread -f &data
  bwrite data.txt -1 -1 &data
  .timersiver 1 1 siver.close
}
on *:FILESENT:*: {
  if (%si.dcc == 1) {
    inc %si.dcc.send.succ | inc %si.dcc.send.tot | notice $nick Sent $filename to $nick $address | echo -a Sent $filename to $nick $address
  }
}
on *:FILERCVD:*: {
  if (%si.dcc == 1) {
    inc %si.dcc.get.succ | inc %si.dcc.get.tot | notice $nick Receieved $filename from $nick $address | echo -a Receieved $filename from $nick $address
  }
}
on *:GETFAIL:*: {
  if (%si.dcc == 1) {
    inc %si.dcc.get.tot | notice $nick $filename from $nick $address failed | echo -a $filename from $nick $address failed
  }
}
on *:SENDFAIL:*: {
  if (%si.dcc == 1) {
    inc %si.dcc.send.tot | notice $nick $filename to $nick $address failed | echo -a $filename to $nick $address failed
  }
}
on *:load: {
  si.setvar
  echo -a System Info %si.ver by MTec89 Loaded [/si] [ http://www.e-motz.com ]
  if ($?!="Do you wish to check for a new version? Your version is %si.ver $+ .") { 
    siconfig
    .timer -o 1 1 did -f siconfig 94 | did -f siconfig 51 | did -c siconfig 94 7 | sicheckver
  }
}
on *:unload:echo -a System Info %si.ver by MTec89 unloaded [ http://www.e-motz.com ] | unset %si.*
on *:start: {
  if (%si.start == 1) { si }
}
menu * {
  System Info
  .About:siabout
  .System Info:si
  .Config:siconfig
  .Spam It:sispam
}
alias si.setvar {
  set %si.dcc.send.succ 0 
  set %si.dcc.send.tot 0
  set %si.dcc.get.succ 0
  set %si.dcc.get.tot 0
  set %si.vert 84
  set %si.hor 70
  set %si.cfg.vert 84
  set %si.cfg.hor 70
  set %si.wid 540
  set %si.sp.nick 1
  set %si.sp.server 1
  set %si.sp.servup 1
  set %si.sp.mircup 1
  set %si.sp.winup 1
  set %si.sp.idle 1
  set %si.sp.timedate 1
  set %si.sp.dccs 1
  set %si.sp.cmd /me
  set %si.sp.9 #chan OR nick
  set %si.sp.ram 1
  set %si.sp.cpu 1
  set %si.update 1
  set %si.leftbrac [
  set %si.rightbrac ]
  set %si.td.sep 215
  set %si.ver [02/07/2009]
  set %si.newver 
  set %si.updte 1
  set %si.dcc 1
  set %si.ram 1
  set %si.d.tog 1
  set %si.d.tog.key F5
  .enable #FKEY. $+ %si.d.tog.key
  set %si.ram.sec 1
  set %si.time.sec 1
  set %si.time 1
  set %si.ram 1
  set %si.cpu 1
  set %si.cpu.sec 1
  set %si.cpu.use
  set %si.ram.use
  set %si.start 1
}




;[EoF]