;; ++++++++++++++++++++++++++++++++++++++++
;; +++++++++++++++++++ ircZP Remote <ZP> ++
;; by slushey <slushey@slushey.net> +++++++
;; ++++++++++++++++++++++++++++++++++++++++
;; ++++++++++ www.team-clanx.net ++++++++++
;; ++++ www.slushey.net +++++++++++++2003++
;; ++++++++++++++++++++++++++++++++++++++++

alias away {
  if ($1- != $null) { 
    %away.reason = $1- 
    %away.ctime = $ctime 
    if ($r.get(away,showmsg) = on) { 
      .timer.showmsg 0 $r.get(away,showmsgtime) away.announce 
    } 
    if ($r.get(away,usenick) = on) { 
      set %away.me. [ $+ [ $scid ] $+ ] . [ $+ [ $network ] ] $me 
      /nick $r.get(away,awaynick) 
    }
    if ($r.get(away,annaway) = on) { 
      away.announce 
    } 
    ecko -sit Setting away to all servers, please wait. 
    var %ctr = 0 | var %tot = $scon(0) 
    while (%ctr < %tot) { 
      inc %ctr 
      scon %ctr .raw away : $+ %away.reason ( $+ $time_str $+ ) 
    } 
  }
  else { 
    var %ctr = 0
    var %tot = $scon(0)
    while (%ctr < %tot) { 
      inc %ctr | scon %ctr .raw away 
    }
    if (%away.me. [ $+ [ $scid ] $+ ] . [ $+ [ $network ] ] != $null) { 
      nick %away.me. [ $+ [ $scid ] $+ ] . [ $+ [ $network ] ]
    } 
    if (($r.get(away,annback) = on) && ($away = $true)) { 
      back.announce 
    } 
    if ($timer(.showmsg) != $null) { 
      .timer.showmsg off 
    } 
    unset %away.* 
  }
}
alias away.announce { 
  ame is away... $bracket(%away.reason) since $bracket($time_str(%away.ctime)) $+ . $iif($r.get(away,pager) = on,Pager is enabled.) $logo 
}
alias back.announce { 
  ame is returning... $bracket(%away.reason) since $bracket($time_str(%away.ctime)) gone for $bracket($xdur($calc($ctime - %away.ctime))) $+ . $logo 
}
on *:START:{ unset %away.* }
on *:CONNECT:{ 
  if (%away.reason != $null) { 
    .raw away : $+ %away.reason ( $+ $time_str(%away.ctime $+ ) 
    ecko -sit Re-activating server-side away settings. $bracket($server) 
  }
  .timer.auto.away.check 0 10 away.check.autoaway
  .timer.clr.away.nicks 0 3600 unset %away.msgs.* 
}
on *:TEXT:*:?:{ 
  if ($away != $false) { 
    if ((%away.msg. [ $+ [ $nick ] ] = $null) && ($r.get(away,autoreply) == on)) { 
      set -u3600 %away.msg. [ $+ [ $nick ] ] = $true
      msg $nick I am currently away $bracket(%away.reason) since $bracket($time_str(%away.ctime)) $+ . $iif($r.get(away,pager) = on,To page me type: /ctcp $me PAGE [message]) $+ . $logo
    }
  } 
}
alias away.check.autoaway { return }