on *:load: if ($version < 5.7) { echo -a ! error: you need mIRC 5.7 to run Secret Mailer. Go download it! | unload -rs $script | return } | echo -a ! loaded Secret Mailer. /secretmail to run. Or just use the popups. 
menu menubar {
  Secret Mailer
  .Open: secretmail
  .Unload: unload -rs $script(secretmail.mrc)
}
alias secretmail { if ($dialog(anonmail) == $null) { .dialog -md anonmail anonmail } }
dialog anonmail {
  title "Secret Mailer 1.0.0 : Anonymous mail sender."
  size -1 -1 400 315
  option pixels
  tab "Mailer", 15, 1 1 398 313 
  tab "About", 16
  text "Mail Host/Server:", 1, 10 30 85 15, tab 15
  edit "mail.RockZone.com", 2, 105 28 180 20, autohs tab 15
  text "Reply Email (From):", 3, 10 60 90 15, tab 15
  edit "anon@scriptmasters.com", 4, 105 58 180 20, tab 15
  text "Send To:", 5, 10 90 70 15, tab 15
  edit "lamer@email.com", 6, 105 88 180 20, tab 15
  text "Subject:" 7, 10 120 60 15, tab 15
  edit "(no subject)", 8, 105 118 180 20, tab 15
  edit "(message goes here)", 9, 10 150 380 150, autovs, autohs, multi, vsbar, hsbar tab 15
  button "Send", 11, 300 35 80 20, tab 15
  button "Clear", 12, 300 65 80 20, tab 15 
  button "Quit", 13, 300 95 80 20, cancel tab 15
  text "Idle..", 14, 300 125 80 15, tab 15
  text ". . : : S e c r e t . M a i l e r . 1 . 0 . 0 : : . .", 17, 10 30 380 20, center tab 16
  box "The Mailer", 18, 10 60 380 100, center tab 16
  text "Secret Mailer is a dialog and socket based mIRC 5.7 addon. You will be able to send fake email using any replay address your mind can think of. Your IP/host will be shown, unless you use an anonymous mail server. Which is very hard to find. I supplied a mail server which I use a lot. My friend, MuD, owns RockZone.com, so don't go overboard and get him in trouble. *Disclaimer: I am not responsible for any illegal use of this. If you get in trouble, it's your ass..", 19, 12 75 375 80, center tab 16
  box "The Author and Website", 20, 10 170 380 100, center tab 16
  text "My alias is ^manson^. I am the one who coded Secret Mail. If you have any questions or bug reports, report them to me by email (toods@RockZone.com) or ICQ (1539132). This addon is copyrighted 2000 by ^manson^ and Script Masters. Visit our site at http://bloodbag.hypermart.net/", 21, 12 185 375 80, center tab 16
  button "Close", 22, 170 280 60 20, tab 16
}
on *:dialog:anonmail:sclick:*: {
  if ($did == 12) { anonmail.ca }
  if ($did == 22) { .dialog -x anonmail | .sockclose anonmail | unset %anonmail.* }
  if ($did == 11) { anonmail.send }
  if ($did == 20) { .sockclose anonmail | unset %anonmail.* }
}
alias anonmail.ca { did -r anonmail 4 | did -r anonmail 6 | did -o anonmail 8 1 (no subject) | did -o anonmail 9 1 (message goes here) | anonmail.w Cleared fields.. | .timer 1 5 anonmail.w Idle.. }
alias anonmail.w { did -o anonmail 14 1 $1- }
alias anonmail.send { 
  if ($did(anonmail,2) == $null) || ($did(anonmail,4) == $null) || ($did(anonmail,6) == $null) { anonmail.w Field Error. | return }
  .sockclose anonmail | .sockopen anonmail $did(anonmail,2) 25 | anonmail.w Connecting..
}
alias anonmail.send.data {
  .sockwrite -n anonmail to: $did(anonmail,6)
  .sockwrite -n anonmail from: $did(anonmail,4)
  .sockwrite -n anonmail subject: $did(anonmail,8)
  .sockwrite -n anonmail $did(anonmail,9)
  .sockwrite -n anonmail .
}
alias anonmail.sent { anonmail.w Mail Sent. | .sockclose anonmail | unset %anonmail.* }
alias anonmail.read {
  set %anonmail.rawnum $gettok($1-,1,32)
  set %anonmail.read $1-
  if (%anonmail.rawnum == 220) { .sockwrite -n anonmail helo x.x.org }
  if (%anonmail.rawnum == 250) { 
    if (Hello isin %anonmail.read) { .sockwrite -n anonmail mail from: $did(anonmail,4) }
    if (Sender isin %anonmail.read) { .sockwrite -n anonmail rcpt to: $did(anonmail,6) }
    if (Recipient isin %anonmail.read) { .sockwrite -n anonmail data }
    if (accepted isin %anonmail.read) { anonmail.sent }
  }
  if (%anonmail.rawnum == 354) { anonmail.send.data }
  if (%anonmail.rawnum == 553) { anonmail.w Send FAILED. | .sockclose anonmail | unset %anonmail.* }
  if (%anonmail.rawnum == 550) { anonmail.w Send FAILED. | .sockclose anonmail | unset %anonmail.* }
  else { return }
}
on *:SOCKOPEN:anonmail:{
  if ($sockerr == 3) { anonmail.w Can't connect. | .sockclose anonmail | unset %anonmail.* | return } 
  if ($sockerr == 4) { anonmail.w Can't resolve. | .sockclose anonmail | unset %anonmail.* | return } 
  else { anonmail.w Connected. | return }
}
on *:SOCKREAD:anonmail: {
  if ($sockerr > 0) { return }
  sockread %anonmail.temp
  if ($sockbr == 0) return
  if (%anonmail.temp == $null) %anonmail.temp = -
  if (%anonmail.temp != $null) { anonmail.read %anonmail.temp }
}
on *:SOCKCLOSE:anonmail: anonmail.w Closed.. | unset %anonmail.* | return